gnome-base/gnome-keyring: bump to 3.20.1

Package-Manager: Portage-2.3.5, Repoman-2.3.2

2 files changed, 79 insertions, 0 deletions

diff --git a/gnome-base/gnome-keyring/Manifest b/gnome-base/gnome-keyring/Manifest
index 151b42b87a3b..c5ab81bd3499 100644
--- a/gnome-base/gnome-keyring/Manifest
+++ b/gnome-base/gnome-keyring/Manifest
@@ -1 +1,2 @@
 DIST gnome-keyring-3.20.0.tar.xz 1215324 SHA256 bc17cecd748a0e46e302171d11c3ae3d76bba5258c441fabec3786f418e7ec99 SHA512 f7e6195b4be52edaee3bc3181f006ec31ebd54f8000c98220520f4158f66580b60950e4f55247aefae6aa9320f6589c8a09c1e32853165915ae5ff1b40627c5b WHIRLPOOL 63ceaf842b4f9661eb732fbddec6f26dda7ae157e405eb0d0b377ff07dd01c0e0ae3b3c0dd07d2434199edb3730994231da936aaf472054ee5cb76f089439fb8
+DIST gnome-keyring-3.20.1.tar.xz 1219800 SHA256 97964e723f454be509c956ed5e38b5c2fd7363f43bd3f153b94a4a63eb888c8c SHA512 a60d8a4b17a9c6d8c581578881abaf7d79de43045a314b401e3bfd3974edb4ab94117dd430203b721058f432b24bf6296e0b7c4fba1e66cccd2c2e9441787177 WHIRLPOOL e05ccedf325cafdd3faa70c6873345b4febbf0dc9e45e611165b58b78e99659fd238dbddc5a24e470663cf6d8772eb0a07677257d1a4b35c5333f6cc872403af
diff --git a/gnome-base/gnome-keyring/gnome-keyring-3.20.1.ebuild b/gnome-base/gnome-keyring/gnome-keyring-3.20.1.ebuild
new file mode 100644
index 000000000000..0311d3962d21
--- /dev/null
+++ b/gnome-base/gnome-keyring/gnome-keyring-3.20.1.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+PYTHON_COMPAT=( python2_7 )
+
+inherit fcaps gnome2 pam python-any-r1 versionator virtualx
+
+DESCRIPTION="Password and keyring managing daemon"
+HOMEPAGE="https://wiki.gnome.org/Projects/GnomeKeyring"
+
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="0"
+IUSE="+caps pam selinux +ssh-agent test"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~sparc-solaris ~x86-solaris"
+
+# Replace gkd gpg-agent with pinentry[gnome-keyring] one, bug #547456
+RDEPEND="
+	>=app-crypt/gcr-3.5.3:=[gtk]
+	>=dev-libs/glib-2.38:2
+	app-misc/ca-certificates
+	>=dev-libs/libgcrypt-1.2.2:0=
+	caps? ( sys-libs/libcap-ng )
+	pam? ( virtual/pam )
+	selinux? ( sec-policy/selinux-gnome )
+	>=app-crypt/gnupg-2.0.28:=
+"
+DEPEND="${RDEPEND}
+	>=app-eselect/eselect-pinentry-0.5
+	app-text/docbook-xml-dtd:4.3
+	dev-libs/libxslt
+	>=dev-util/intltool-0.35
+	sys-devel/gettext
+	virtual/pkgconfig
+	test? ( ${PYTHON_DEPS} )
+"
+PDEPEND="app-crypt/pinentry[gnome-keyring]" #570512
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	# Disable stupid CFLAGS with debug enabled
+	sed -e 's/CFLAGS="$CFLAGS -g"//' \
+		-e 's/CFLAGS="$CFLAGS -O0"//' \
+		-i configure.ac configure || die
+
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		$(use_with caps libcap-ng) \
+		$(use_enable pam) \
+		$(use_with pam pam-dir $(getpam_mod_dir)) \
+		$(use_enable selinux) \
+		$(use_enable ssh-agent) \
+		--enable-doc
+}
+
+src_test() {
+	 "${EROOT}${GLIB_COMPILE_SCHEMAS}" --allow-any-name "${S}/schema" || die
+	 GSETTINGS_SCHEMA_DIR="${S}/schema" virtx emake check
+}
+
+pkg_postinst() {
+	# cap_ipc_lock only needed if building --with-libcap-ng
+	# Never install as suid root, this breaks dbus activation, see bug #513870
+	use caps && fcaps -m 755 cap_ipc_lock usr/bin/gnome-keyring-daemon
+	gnome2_pkg_postinst
+
+	if ! [[ $(eselect pinentry show | grep "pinentry-gnome3") ]] ; then
+		ewarn "Please select pinentry-gnome3 as default pinentry provider:"
+		ewarn " # eselect pinentry set pinentry-gnome3"
+	fi
+}