games-strategy/naev: add 0.9.4

Swapped virtual/opengl for libglvnd, but kept [X] because src/glad.c
looks for libGL.so.1 and uses GLX symbols (albeit this is known to
work on proper wayland, so it may be possible to do without).

Signed-off-by: Ionen Wolkens <ionen@gentoo.org>

2 files changed, 94 insertions, 0 deletions

diff --git a/games-strategy/naev/Manifest b/games-strategy/naev/Manifest
index 609d3dd7ae65..8bb1bc86a06f 100644
--- a/games-strategy/naev/Manifest
+++ b/games-strategy/naev/Manifest
@@ -1 +1,2 @@
 DIST naev-0.9.3-source.tar.xz 394876456 BLAKE2B 9648ee9a93a02ec5ace552b25033cae16c38a48a869763bc381050f2724445fd5cf08708053ad4c939cdc99a27244126819e9416bc61d8d6148078eeea26e50e SHA512 150091f10ce05cbd5b2c4c434abe83124db56618b80f727994c135d1331c594406c9e8f03596feddb5739061c866e19b115fd0a86a19ea306cc811bb3dd944aa
+DIST naev-0.9.4-source.tar.xz 395461576 BLAKE2B cbfdc443ecb8cb27694769d054f7162c3d1d2bcd8dc28045696d6891abfb46e4a3518ce265c97b55a96b8d000c9900e4bc49ae7b45a16db75f9de48ea0cb702b SHA512 e8efb115d8d623ea92d348854d98ee22e8863aaf6555efa058d6160210f000186ae39f054f5b4f0fa8d92949de83defa35d4acd8216398157a1a42886745ddab
diff --git a/games-strategy/naev/naev-0.9.4.ebuild b/games-strategy/naev/naev-0.9.4.ebuild
new file mode 100644
index 000000000000..737c5df6c89a
--- /dev/null
+++ b/games-strategy/naev/naev-0.9.4.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LUA_COMPAT=( lua5-1 luajit )
+PYTHON_COMPAT=( python3_{8..11} )
+inherit lua-single meson python-any-r1 virtualx xdg
+
+DESCRIPTION="2D space trading and combat game, in a similar vein to Escape Velocity"
+HOMEPAGE="https://naev.org/"
+SRC_URI="https://github.com/naev/naev/releases/download/v${PV}/${P}-source.tar.xz"
+
+LICENSE="
+	GPL-3+ BSD BSD-2 CC-BY-2.0 CC-BY-3.0 CC-BY-4.0 CC-BY-SA-2.0
+	CC-BY-SA-3.0 CC-BY-SA-4.0 CC0-1.0 MIT public-domain"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc"
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+
+RDEPEND="
+	${LUA_DEPS}
+	dev-games/physfs
+	dev-libs/libunibreak:=
+	dev-libs/libxml2
+	media-libs/freetype:2
+	media-libs/libglvnd[X]
+	media-libs/libsdl2[joystick,opengl,video]
+	media-libs/libvorbis
+	media-libs/openal
+	media-libs/sdl2-image[png,webp]
+	sci-libs/cholmod
+	sci-libs/cxsparse
+	sci-libs/openblas
+	sci-libs/suitesparse
+	sci-mathematics/glpk:=
+	virtual/libintl"
+DEPEND="
+	${RDEPEND}
+	test? (
+		dev-games/physfs[zip]
+		media-libs/libsdl2[X]
+		media-libs/mesa[llvm]
+	)"
+BDEPEND="
+	$(python_gen_any_dep 'dev-python/pyyaml[${PYTHON_USEDEP}]')
+	sys-devel/gettext
+	doc? (
+		app-doc/doxygen[dot]
+		dev-lua/ldoc
+	)"
+
+python_check_deps() {
+	python_has_version "dev-python/pyyaml[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	lua-single_pkg_setup
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	sed -i "s/'lua51'/'lua'/" meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature doc docs_c)
+		$(meson_feature doc docs_lua)
+		$(meson_feature lua_single_target_luajit luajit)
+	)
+
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test
+}
+
+src_install() {
+	local DOCS=( CHANGELOG Readme.md )
+	meson_src_install
+
+	if use doc; then
+		dodir /usr/share/doc/${PF}/html
+		mv "${ED}"/usr/{doc/naev/{c,lua},share/doc/${PF}/html} || die
+		rm -r "${ED}"/usr/doc || die
+	fi
+	rm -r "${ED}"/usr/share/doc/naev || die
+}