games-emulation/gnuboy: EAPI 7->8, tidy, actually add [joystick]

Also [sound,video] as it uses both, and libX11

Fixes: 91aff97f2dac6a7897dff1da831d3d9243955307
Closes: https://bugs.gentoo.org/809020
Signed-off-by: Ionen Wolkens <ionen@gentoo.org>

1 files changed, 58 insertions, 0 deletions

diff --git a/games-emulation/gnuboy/gnuboy-1.0.3-r4.ebuild b/games-emulation/gnuboy/gnuboy-1.0.3-r4.ebuild
new file mode 100644
index 000000000000..6fcd97ea2826
--- /dev/null
+++ b/games-emulation/gnuboy/gnuboy-1.0.3-r4.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="Gameboy emulator with multiple renderers"
+HOMEPAGE="https://sourceforge.net/projects/gnuboy/"
+SRC_URI="mirror://gentoo/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="X +sdl"
+REQUIRED_USE="!X? ( sdl )"
+
+RDEPEND="
+	X? (
+		x11-libs/libX11
+		x11-libs/libXext
+	)
+	sdl? ( media-libs/libsdl[joystick,sound,video] )"
+DEPEND="
+	${RDEPEND}
+	X? ( x11-base/xorg-proto )"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-exec-stack.patch
+	"${FILESDIR}"/${P}-linux-headers.patch
+	"${FILESDIR}"/${P}-include.patch
+	"${FILESDIR}"/${P}-fix-implicit-decl-sprintf.patch
+)
+
+src_prepare() {
+	default
+
+	eautoreconf
+}
+
+src_configure() {
+	local econfargs=(
+		$(use_with X x)
+		$(use_with sdl)
+		$(use_enable x86 asm)
+		--disable-arch
+		--disable-optimize
+	)
+
+	econf "${econfargs[@]}"
+}
+
+src_install() {
+	use X && dobin xgnuboy
+	use sdl && dobin sdlgnuboy
+
+	dodoc README docs/{CHANGES,CONFIG,CREDITS,FAQ,HACKING,WHATSNEW}
+}