games-arcade/xjump: port to EAPI 7, games.eclass--

Signed-off-by: Sam James <sam@gentoo.org>

3 files changed, 65 insertions, 57 deletions

diff --git a/games-arcade/xjump/files/xjump-2.7.5-ldflags.patch b/games-arcade/xjump/files/xjump-2.7.5-ldflags.patch
index a30736811318..7cff45c60653 100644
--- a/games-arcade/xjump/files/xjump-2.7.5-ldflags.patch
+++ b/games-arcade/xjump/files/xjump-2.7.5-ldflags.patch
@@ -1,5 +1,5 @@
---- Makefile.old	2010-10-01 07:05:03.000000000 +0200
-+++ Makefile	2010-10-01 07:05:39.000000000 +0200
+--- a/Makefile
++++ b/Makefile
 @@ -28,7 +28,7 @@
  ##########################################################
  
diff --git a/games-arcade/xjump/xjump-2.7.5-r1.ebuild b/games-arcade/xjump/xjump-2.7.5-r1.ebuild
new file mode 100644
index 000000000000..5e3328386b46
--- /dev/null
+++ b/games-arcade/xjump/xjump-2.7.5-r1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+DEBIAN_PATCH="6.1"
+DESCRIPTION="An X game where one tries to jump up as many levels as possible"
+HOMEPAGE="http://packages.debian.org/stable/games/xjump"
+SRC_URI="mirror://debian/pool/main/x/${PN}/${PN}_${PV}.orig.tar.gz
+	mirror://debian/pool/main/x/${PN}/${PN}_${PV}-${DEBIAN_PATCH}.debian.tar.gz"
+S="${WORKDIR}"/${P}.orig
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="x11-libs/libX11
+	x11-libs/libXaw
+	x11-libs/libXpm
+	x11-libs/libXt"
+DEPEND="${RDEPEND}
+	x11-base/xorg-proto"
+
+RDEPEND+=" acct-group/gamestat"
+
+PATCHES=(
+	"${WORKDIR}"/debian/patches/01_overflow.patch
+	"${WORKDIR}"/debian/patches/02_fix_repeat.patch
+	"${WORKDIR}"/debian/patches/03_source_warnings.patch
+	"${WORKDIR}"/debian/patches/04_makefile_respect_cflags.patch
+	"${WORKDIR}"/debian/patches/05_unneded_deps.patch
+	"${FILESDIR}"/${P}-ldflags.patch
+)
+
+src_prepare() {
+	default
+
+	# set up where we will keep the highscores file:
+	sed -i \
+		-e "/^CC/d" \
+		-e "/^CFLAGS/d" \
+		-e "s,/record,/xjump.hiscores," \
+		Makefile || die
+}
+
+src_configure() {
+	tc-export CC
+}
+
+src_install() {
+	dobin xjump
+	dodoc README.euc
+
+	# Set up the hiscores file
+	dodir /var/games/${PN}
+	touch "${ED}"/var/games/${PN}/xjump.hiscores || die
+
+	fperms -R 660 /var/games/${PN}
+	fowners -R root:gamestat /var/games/${PN}
+	fperms g+s /usr/bin/xjump
+}
diff --git a/games-arcade/xjump/xjump-2.7.5.ebuild b/games-arcade/xjump/xjump-2.7.5.ebuild
deleted file mode 100644
index 58d403ffe1bd..000000000000
--- a/games-arcade/xjump/xjump-2.7.5.ebuild
+++ /dev/null
@@ -1,55 +0,0 @@
-# Copyright 1999-2018 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=5
-inherit eutils games
-
-DEBIAN_PATCH="6.1"
-DESCRIPTION="An X game where one tries to jump up as many levels as possible"
-HOMEPAGE="http://packages.debian.org/stable/games/xjump"
-SRC_URI="mirror://debian/pool/main/x/${PN}/${PN}_${PV}.orig.tar.gz
-	mirror://debian/pool/main/x/${PN}/${PN}_${PV}-${DEBIAN_PATCH}.debian.tar.gz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE=""
-
-RDEPEND="x11-libs/libX11
-	x11-libs/libXaw
-	x11-libs/libXpm
-	x11-libs/libXt"
-
-DEPEND="${RDEPEND}
-	x11-base/xorg-proto"
-
-S=${WORKDIR}/${P}.orig
-
-src_prepare() {
-	# Where we will keep the highscore file:
-	HISCORE_FILENAME=xjump.hiscores
-	HISCORE_FILE="${GAMES_STATEDIR}/${HISCORE_FILENAME}"
-
-	epatch \
-		"${WORKDIR}"/debian/patches/0*.patch \
-		"${FILESDIR}"/${P}-ldflags.patch
-
-	# set up where we will keep the highscores file:
-	sed -i \
-		-e "/^CC/d" \
-		-e "/^CFLAGS/d" \
-		-e "s,/var/games/xjump,${GAMES_STATEDIR}," \
-		-e "s,/record,/${HISCORE_FILENAME}," \
-		Makefile || die
-}
-
-src_install() {
-	dogamesbin xjump
-	dodoc README.euc
-
-	# Set up the hiscores file:
-	dodir "${GAMES_STATEDIR}"
-	touch "${D}/${HISCORE_FILE}"
-	fperms 660 "${HISCORE_FILE}"
-	prepgamesdirs
-}