dev-util/vulkan-tools: Version bump

Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Nick Sarnie <sarnex@gentoo.org>

3 files changed, 89 insertions, 5 deletions

diff --git a/dev-util/vulkan-tools/Manifest b/dev-util/vulkan-tools/Manifest
index 0bed409c5a70..774d0440d398 100644
--- a/dev-util/vulkan-tools/Manifest
+++ b/dev-util/vulkan-tools/Manifest
@@ -1,2 +1,3 @@
 DIST vulkan-tools-1.2.182.tar.gz 847991 BLAKE2B 5ab9d73383338bcc3c54487f0f433466d9974269d3be2aa0d50281affeee8fb94414eb638fc94be6fd2dc059c0a2d3dca4e9a8caf3e2b8758c03c57373e2f73b SHA512 5cc9500923288641529556e82a708b88f7dc775c75166d10ae2a807562ce9dda3993aa01a261ff4f9c2cc31ea47423a12f21ec64d32e6aee66ef7c3fc2dc17fc
 DIST vulkan-tools-1.2.189.tar.gz 849041 BLAKE2B ae38aaca9789276bcb93c5c297c9113fcced4cd3417f0619c0e1fb539df5891e725a77785fbeca0c8957644af7245ff9f0a3981cf5f8726f4f231e39f05ddfbb SHA512 3ac4f79a6ba18690026d1933b7f3c45769f9759e25d19508bc34d431454dc548e1f738ae3d804db2864a97de3b8628f167bc00dcad4059eaeb1714e4fdd3507a
+DIST vulkan-tools-1.2.198.tar.gz 847429 BLAKE2B 8927740853eb45d495996a8be0bae3d40f84f14f12eb838474241745321d7337a6bae7e118bd626fbb15f8ffd42d574a04c93bd3aca0b3373976d7d976c05d2d SHA512 304ce76c47d4adef3a286439712ef4fd3f08ec8e47ed0e2a37162f9cac5e08af3c7b7fb449fddd4772080d678d84db9e238a5db4d98c7d4ee5f6d87a3f5c8f5f
diff --git a/dev-util/vulkan-tools/vulkan-tools-1.2.198.ebuild b/dev-util/vulkan-tools/vulkan-tools-1.2.198.ebuild
new file mode 100644
index 000000000000..183eec642b25
--- /dev/null
+++ b/dev-util/vulkan-tools/vulkan-tools-1.2.198.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_PN=Vulkan-Tools
+CMAKE_ECLASS="cmake"
+PYTHON_COMPAT=( python3_{8,9} )
+inherit cmake-multilib python-any-r1
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://github.com/KhronosGroup/${MY_PN}.git"
+	EGIT_SUBMODULES=()
+	inherit git-r3
+else
+	SRC_URI="https://github.com/KhronosGroup/${MY_PN}/archive/sdk-${PV}.0.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv"
+	S="${WORKDIR}"/${MY_PN}-sdk-${PV}.0
+fi
+
+DESCRIPTION="Official Vulkan Tools and Utilities for Windows, Linux, Android, and MacOS"
+HOMEPAGE="https://github.com/KhronosGroup/Vulkan-Tools"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="cube wayland +X"
+
+# Cube demo only supports one window system at a time
+REQUIRED_USE="cube? ( ^^ ( X wayland ) )"
+
+BDEPEND="${PYTHON_DEPS}
+	>=dev-util/cmake-3.10.2
+	cube? ( ~dev-util/glslang-${PV}:=[${MULTILIB_USEDEP}] )
+"
+RDEPEND="
+	~media-libs/vulkan-loader-${PV}:=[${MULTILIB_USEDEP},wayland?,X?]
+	wayland? ( dev-libs/wayland:=[${MULTILIB_USEDEP}] )
+	X? (
+		x11-libs/libX11:=[${MULTILIB_USEDEP}]
+		x11-libs/libXrandr:=[${MULTILIB_USEDEP}]
+	)
+"
+DEPEND="${RDEPEND}
+	~dev-util/vulkan-headers-${PV}
+"
+
+pkg_setup() {
+	MULTILIB_CHOST_TOOLS=(
+		/usr/bin/vulkaninfo
+	)
+
+	use cube && MULTILIB_CHOST_TOOLS+=(
+		/usr/bin/vkcube
+		/usr/bin/vkcubepp
+	)
+
+	python-any-r1_pkg_setup
+}
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_C_FLAGS="${CFLAGS} -DNDEBUG"
+		-DCMAKE_CXX_FLAGS="${CXXFLAGS} -DNDEBUG"
+		-DCMAKE_SKIP_RPATH=ON
+		-DBUILD_VULKANINFO=ON
+		-DBUILD_CUBE=$(usex cube)
+		-DBUILD_WSI_WAYLAND_SUPPORT=$(usex wayland)
+		-DBUILD_WSI_XCB_SUPPORT=$(usex X)
+		-DBUILD_WSI_XLIB_SUPPORT=$(usex X)
+		-DVULKAN_HEADERS_INSTALL_DIR="${ESYSROOT}/usr"
+	)
+
+	use cube && mycmakeargs+=(
+		-DGLSLANG_INSTALL_DIR="${ESYSROOT}/usr"
+		-DCUBE_WSI_SELECTION=$(usex X XCB WAYLAND)
+	)
+
+	cmake_src_configure
+}
+
+multilib_src_install() {
+	cmake_src_install
+}
diff --git a/dev-util/vulkan-tools/vulkan-tools-9999.ebuild b/dev-util/vulkan-tools/vulkan-tools-9999.ebuild
index db5266d48cdb..183eec642b25 100644
--- a/dev-util/vulkan-tools/vulkan-tools-9999.ebuild
+++ b/dev-util/vulkan-tools/vulkan-tools-9999.ebuild
@@ -13,9 +13,9 @@ if [[ ${PV} == *9999* ]]; then
 	EGIT_SUBMODULES=()
 	inherit git-r3
 else
-	SRC_URI="https://github.com/KhronosGroup/${MY_PN}/archive/sdk-${PV}.tar.gz -> ${P}.tar.gz"
+	SRC_URI="https://github.com/KhronosGroup/${MY_PN}/archive/sdk-${PV}.0.tar.gz -> ${P}.tar.gz"
 	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv"
-	S="${WORKDIR}"/${MY_PN}-sdk-${PV}
+	S="${WORKDIR}"/${MY_PN}-sdk-${PV}.0
 fi
 
 DESCRIPTION="Official Vulkan Tools and Utilities for Windows, Linux, Android, and MacOS"
@@ -30,10 +30,10 @@ REQUIRED_USE="cube? ( ^^ ( X wayland ) )"
 
 BDEPEND="${PYTHON_DEPS}
 	>=dev-util/cmake-3.10.2
-	cube? ( dev-util/glslang:=[${MULTILIB_USEDEP}] )
+	cube? ( ~dev-util/glslang-${PV}:=[${MULTILIB_USEDEP}] )
 "
 RDEPEND="
-	>=media-libs/vulkan-loader-${PV}:=[${MULTILIB_USEDEP},wayland?,X?]
+	~media-libs/vulkan-loader-${PV}:=[${MULTILIB_USEDEP},wayland?,X?]
 	wayland? ( dev-libs/wayland:=[${MULTILIB_USEDEP}] )
 	X? (
 		x11-libs/libX11:=[${MULTILIB_USEDEP}]
@@ -41,7 +41,7 @@ RDEPEND="
 	)
 "
 DEPEND="${RDEPEND}
-	>=dev-util/vulkan-headers-${PV}
+	~dev-util/vulkan-headers-${PV}
 "
 
 pkg_setup() {