dev-util/vulkan-tools: add 1.3.275

Signed-off-by: Nick Sarnie <sarnex@gentoo.org>

3 files changed, 84 insertions, 3 deletions

diff --git a/dev-util/vulkan-tools/Manifest b/dev-util/vulkan-tools/Manifest
index 75768fbd3a5b..428dbbff3f02 100644
--- a/dev-util/vulkan-tools/Manifest
+++ b/dev-util/vulkan-tools/Manifest
@@ -1,2 +1,3 @@
 DIST vulkan-tools-1.3.261.tar.gz 801309 BLAKE2B be85d035157312c423c6f574519825facc7e9d5313126171b0b50a1605478fe271370faa55bc6732857189668f3e102ad429e4191a12e7be5e2113c1a712dcad SHA512 8bc30ead031ad6bceb7e54a1b70f26048847a30147d86638ced9d621b11ef64b1e97f41394b068458f5c8ad6e30216aba6e14765e971fa9e6a49773a47593fe5
 DIST vulkan-tools-1.3.268.tar.gz 778556 BLAKE2B a406a110894e9cc95d0b16f5cf4e11fbcce1d31d1c6378172eb955e014ee2381a12a1625288bd5b5308b702824c2ba1e854e6df88e42976ae1dc39fac5076498 SHA512 9359e9528bfe507870bd83f9e8860b3d82555c0d8a6a19284f150dd2288b204f2c9dc9b3f62be4efbbb5e2983862459b2131de126a603cc5531ef8df72f4458f
+DIST vulkan-tools-1.3.275.tar.gz 755289 BLAKE2B 2366a0c55982ef9ef13495ac62d958d0055fcbbbd7cdaab9530ebf15af9369a71bf3b8d3d6479f3a0ee02d44ace027e0fd57b2b93d6a9a373781c60529a48663 SHA512 5d70498341b8d2447128cd5ab3fd081b706830f5f85d9f7e752dfca9c74fa4c1567207eef6e34e9bf99ff65ec2855b835eb30362fd544e1cf61ecc7a7119df06
diff --git a/dev-util/vulkan-tools/vulkan-tools-1.3.275.ebuild b/dev-util/vulkan-tools/vulkan-tools-1.3.275.ebuild
new file mode 100644
index 000000000000..8d845199e0ab
--- /dev/null
+++ b/dev-util/vulkan-tools/vulkan-tools-1.3.275.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN=Vulkan-Tools
+PYTHON_COMPAT=( python3_{9..12} )
+inherit cmake-multilib python-any-r1
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://github.com/KhronosGroup/${MY_PN}.git"
+	EGIT_SUBMODULES=()
+	inherit git-r3
+else
+	SRC_URI="https://github.com/KhronosGroup/${MY_PN}/archive/vulkan-sdk-${PV}.0.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+	S="${WORKDIR}"/${MY_PN}-vulkan-sdk-${PV}.0
+fi
+
+DESCRIPTION="Official Vulkan Tools and Utilities for Windows, Linux, Android, and MacOS"
+HOMEPAGE="https://github.com/KhronosGroup/Vulkan-Tools"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="cube wayland +X"
+
+REQUIRED_USE="cube? ( || ( X wayland ) )"
+
+BDEPEND="${PYTHON_DEPS}
+	cube? ( ~dev-util/glslang-${PV}:=[${MULTILIB_USEDEP}] )
+"
+RDEPEND="
+	~media-libs/vulkan-loader-${PV}:=[${MULTILIB_USEDEP},wayland?,X?]
+	wayland? ( dev-libs/wayland:=[${MULTILIB_USEDEP}] )
+	X? (
+		x11-libs/libX11:=[${MULTILIB_USEDEP}]
+		x11-libs/libXrandr:=[${MULTILIB_USEDEP}]
+	)
+"
+DEPEND="${RDEPEND}
+	cube? ( ~dev-util/volk-${PV} )
+	~dev-util/vulkan-headers-${PV}
+"
+
+pkg_setup() {
+	MULTILIB_CHOST_TOOLS=(
+		/usr/bin/vulkaninfo
+	)
+
+	use cube && MULTILIB_CHOST_TOOLS+=(
+		/usr/bin/vkcube
+		/usr/bin/vkcubepp
+	)
+	use cube && use wayland && MULTILIB_CHOST_TOOLS+=(
+		/usr/bin/vkcube-wayland
+	)
+
+	python-any-r1_pkg_setup
+}
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_C_FLAGS="${CFLAGS} -DNDEBUG"
+		-DCMAKE_CXX_FLAGS="${CXXFLAGS} -DNDEBUG"
+		-DCMAKE_SKIP_RPATH=ON
+		-DBUILD_VULKANINFO=ON
+		-DBUILD_CUBE=$(usex cube)
+		-DBUILD_WERROR=OFF
+		-DBUILD_WSI_WAYLAND_SUPPORT=$(usex wayland)
+		-DBUILD_WSI_XCB_SUPPORT=$(usex X)
+		-DBUILD_WSI_XLIB_SUPPORT=$(usex X)
+		-DVULKAN_HEADERS_INSTALL_DIR="${ESYSROOT}/usr"
+	)
+
+	use cube && mycmakeargs+=(
+		-DCUBE_WSI_SELECTION=$(usex X XCB WAYLAND)
+	)
+
+	cmake_src_configure
+}
diff --git a/dev-util/vulkan-tools/vulkan-tools-9999.ebuild b/dev-util/vulkan-tools/vulkan-tools-9999.ebuild
index aeda890581ac..c4b73fa5b459 100644
--- a/dev-util/vulkan-tools/vulkan-tools-9999.ebuild
+++ b/dev-util/vulkan-tools/vulkan-tools-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2023 Gentoo Authors
+# Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -13,7 +13,7 @@ if [[ ${PV} == *9999* ]]; then
 	inherit git-r3
 else
 	SRC_URI="https://github.com/KhronosGroup/${MY_PN}/archive/sdk-${PV}.0.tar.gz -> ${P}.tar.gz"
-	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv"
+	KEYWORDS="~amd64"
 	S="${WORKDIR}"/${MY_PN}-sdk-${PV}.0
 fi
 
@@ -38,6 +38,7 @@ RDEPEND="
 	)
 "
 DEPEND="${RDEPEND}
+	cube? ( ~dev-util/volk-${PV} )
 	~dev-util/vulkan-headers-${PV}
 "
 
@@ -72,7 +73,6 @@ multilib_src_configure() {
 	)
 
 	use cube && mycmakeargs+=(
-		-DGLSLANG_INSTALL_DIR="${ESYSROOT}/usr"
 		-DCUBE_WSI_SELECTION=$(usex X XCB WAYLAND)
 	)