dev-util/redo: Update PYTHON_COMPAT

Package-Manager: Portage-2.3.82, Repoman-2.3.20
Signed-off-by: Jeroen Roovers <jer@gentoo.org>

1 files changed, 48 insertions, 0 deletions

diff --git a/dev-util/redo/redo-0.42-r1.ebuild b/dev-util/redo/redo-0.42-r1.ebuild
new file mode 100644
index 000000000000..e31dd3b2e368
--- /dev/null
+++ b/dev-util/redo/redo-0.42-r1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 2018-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python{2_7,3_{5,6,7}} )
+PYTHON_REQ_USE="sqlite"
+inherit multilib multiprocessing python-single-r1
+
+DESCRIPTION="Smaller, easier, more powerful, and more reliable than make"
+HOMEPAGE="https://github.com/apenwarr/redo"
+SRC_URI="${HOMEPAGE}/archive/${P}.tar.gz"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~x86"
+REQUIRED_USE=${PYTHON_REQUIRED_USE}
+
+BDEPEND="
+	dev-python/beautifulsoup[${PYTHON_USEDEP}]
+	dev-python/markdown[${PYTHON_USEDEP}]
+	${PYTHON_DEPS}
+"
+RDEPEND="
+	${BDEPEND}
+"
+S=${WORKDIR}/${PN}-${P}
+
+src_compile() {
+	./do -j$(makeopts_jobs) build || die
+}
+
+src_test() {
+	./do -j$(makeopts_jobs) test || die
+}
+
+src_install() {
+	DESTDIR="${D}" \
+	DOCDIR="${D}/usr/share/doc/${PF}" \
+	LIBDIR="${D}/usr/$(get_libdir)/${PN}" \
+	./do -j$(makeopts_jobs) \
+		install || die
+
+	python_fix_shebang --force "${D}"
+
+	sed -i \
+		-e 's|/lib/|/'"$(get_libdir)"'/|g' \
+		"${D}"/usr/bin/* || die
+}