dev-util/protobuf-cucumber: fix dependencies

Declare runtime dependencies as such, and add missing
test dependencies.

Closes: https://bugs.gentoo.org/743091
Package-Manager: Portage-3.0.20, Repoman-3.0.2
Signed-off-by: Hans de Graaff <graaff@gentoo.org>

1 files changed, 39 insertions, 0 deletions

diff --git a/dev-util/protobuf-cucumber/protobuf-cucumber-3.10.8-r1.ebuild b/dev-util/protobuf-cucumber/protobuf-cucumber-3.10.8-r1.ebuild
new file mode 100644
index 000000000000..ee30208714d1
--- /dev/null
+++ b/dev-util/protobuf-cucumber/protobuf-cucumber-3.10.8-r1.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+USE_RUBY="ruby26 ruby27"
+
+RUBY_FAKEGEM_EXTRADOC="README.md"
+
+RUBY_FAKEGEM_RECIPE_TEST="rspec3"
+
+inherit ruby-fakegem
+
+DESCRIPTION="Google Protocol Buffers serialization and RPC implementation for Ruby"
+HOMEPAGE="https://github.com/ruby-protobuf/protobuf"
+
+LICENSE="MIT"
+SLOT="$(ver_cut 1)"
+KEYWORDS="~amd64 ~arm"
+IUSE=""
+
+ruby_add_rdepend "
+	>=dev-ruby/activesupport-3.2:*
+	dev-ruby/middleware
+	dev-ruby/thor:*
+	dev-ruby/thread_safe
+"
+
+ruby_add_bdepend "test? (
+	dev-ruby/timecop
+)"
+
+all_ruby_prepare() {
+	sed -i -e '/\(bundler\|pry\)/I s:^:#:' Rakefile spec/spec_helper.rb || die
+
+	# Avoid unpackaged optional dependency
+	rm -f spec/lib/protobuf/rpc/connectors/{ping,zmq}_spec.rb spec/functional/zmq_server_spec.rb || die
+	rm -rf spec/lib/protobuf/rpc/servers/zmq || die
+	sed -i -e '/context .zmq/,/^      end/ s:^:#:' spec/lib/protobuf/cli_spec.rb || die
+}