dev-python/tox: Bump to 3.24.4

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 70 insertions, 0 deletions

diff --git a/dev-python/tox/Manifest b/dev-python/tox/Manifest
index 1241576d5aa7..b714e7647ac0 100644
--- a/dev-python/tox/Manifest
+++ b/dev-python/tox/Manifest
@@ -1,3 +1,4 @@
 DIST tox-3.24.1.tar.gz 305886 BLAKE2B fcedf8054a19a79045b2edead599fb11b7942986fa4bbc184140603e3bc6700eada452e661f4a576d029804ab2a9282df0cf9198eee9b483c2c6c68b086ee156 SHA512 e4bfb3dab15887ce6432a91b88a7387179cbf2a5ab5fa608b3f1f7349be4122d76ce01d396ae9b1515c211f2905d110a8414e254cc72bcf8a74542db98ea52de
 DIST tox-3.24.2.tar.gz 305924 BLAKE2B f91af9fdb4de94eb9ecf65774619234f1e52827c7c6e3ce75ca8161564f8cdc8af210f229ae07f5d381f7964cbbc936f47d4242848513c9bf1c8989a73fe0420 SHA512 e33a1126440ac53cf07cd7dbe695ea1307ebad92e0ed4d6e6c738affa059104f1b5bfc360883283ddd59e5156f7bb00c52d2d2ddd2294b6664f22a2abaaf66c3
 DIST tox-3.24.3.tar.gz 306285 BLAKE2B 368eaf959533f62b08d6e44929ae327ff25ea6eca25a3f47c7b9945428821bf80ab7e0ab4daea8821b55b9a7a009f30c3d5641812fd444a86577ea0ae83adb7d SHA512 de1c1ccc3a277c617521e77806d1d993a5c19f811016bebc442bfea12c3d40a22bf80b7d11b11744a5ddf705c6e8955f2811f149d413ea8522d94c985ed1f715
+DIST tox-3.24.4.tar.gz 306760 BLAKE2B 332c99d021bc3c25549fd95d051baaa1f0dc3aaf776928320826bb7e6bce6444fd5a993e1dbff3a4ebbde9dbb59e30d07eae4b04096294b3a186b130b8312587 SHA512 49e2cb74f119b5cc049d2a64479e56307cea1f36a5586840cca12cb8f4ce8a2ba991cc6142bef7f095a7d32b44f7513f89cce56d89deaff0e12194ceb3da6249
diff --git a/dev-python/tox/tox-3.24.4.ebuild b/dev-python/tox/tox-3.24.4.ebuild
new file mode 100644
index 000000000000..c0eac290ef6e
--- /dev/null
+++ b/dev-python/tox/tox-3.24.4.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} pypy3 )
+inherit distutils-r1
+
+DESCRIPTION="virtualenv-based automation of test activities"
+HOMEPAGE="https://tox.readthedocs.io https://github.com/tox-dev/tox https://pypi.org/project/tox/"
+SRC_URI="https://github.com/tox-dev/tox/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+# doc disabled because of missing deps in tree
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/filelock[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/importlib_metadata-1.1[${PYTHON_USEDEP}]
+	' pypy3)
+	dev-python/packaging[${PYTHON_USEDEP}]
+	>=dev-python/pluggy-0.12[${PYTHON_USEDEP}]
+	dev-python/pip[${PYTHON_USEDEP}]
+	dev-python/py[${PYTHON_USEDEP}]
+	>=dev-python/six-1.14[${PYTHON_USEDEP}]
+	dev-python/toml[${PYTHON_USEDEP}]
+	>=dev-python/virtualenv-16.0.0[${PYTHON_USEDEP}]"
+# TODO: figure out how to make tests work without the package being
+# installed first.
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		>=dev-python/flaky-3.4.0[${PYTHON_USEDEP}]
+		>=dev-python/freezegun-0.3.11[${PYTHON_USEDEP}]
+		>=dev-python/pytest-4.0.0[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+	)"
+
+src_configure() {
+	export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# broken without Internet
+		tests/unit/session/test_provision.py::test_provision_non_canonical_dep
+		tests/integration/test_provision_int.py::test_provision_interrupt_child
+
+		# expects python2 to exist
+		tests/unit/interpreters/test_interpreters.py::test_tox_get_python_executable
+	)
+
+	[[ ${EPYTHON} != pypy3 ]] && EPYTEST_DESELECT+=(
+		# TODO?
+		tests/unit/interpreters/test_interpreters.py::test_find_alias_on_path
+
+		# broken without tox installed first
+		# TODO: why it can't import itself?
+		tests/integration/test_parallel_interrupt.py::test_parallel_interrupt
+	)
+
+	distutils_install_for_testing --via-venv
+	epytest --no-network
+}