dev-python/setuptools: Bump to 61.3.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 132 insertions, 0 deletions

diff --git a/dev-python/setuptools/Manifest b/dev-python/setuptools/Manifest
index 1d663b3f7520..8da4881d2c84 100644
--- a/dev-python/setuptools/Manifest
+++ b/dev-python/setuptools/Manifest
@@ -2,3 +2,4 @@ DIST python-gentoo-patches-3.10.0_p1.tar.xz 10068 BLAKE2B 1c9817b449831559f0a0b7
 DIST setuptools-60.10.0.tar.gz 2420706 BLAKE2B 66d7f3b648b1e3222736ddf46ff97441bc9ed4dc528e0d4ee32ef18c99b2d3488e7525a1598a18df4f2cbdac409a4096a40539807c343d99707068a15003111d SHA512 e679bd84d31cb68f92899e0b25d5a6bf85cf63d9c8e1dfbfe974d7bf819cb36f451596b8715000be6a93656b972dc6c4d90a8a8534a6c88874a0be8140f2f091
 DIST setuptools-60.5.0.tar.gz 2292478 BLAKE2B e41b2717b34d454b3959ee5b6f4fdc70dfec13d97fe6962bd1c1ea2296be8ee2d27bb14ed2cc5e6fb9a757661a0415984b3cf7cf1665347c62a50965f651f9d4 SHA512 b2cf7d99e60d0c862a7a4fd8e806019db52502de48ff77556df26ce39a8620f476de767e2e8be8aa260366f54d1429db8a42d538345ec2cd2cfd5286e62e770d
 DIST setuptools-60.9.2.tar.gz 2425956 BLAKE2B 09baded7eef555ebd76db1672d69cd06cf6bcfc1126ba0fb0143b038d6599998f53460afc914f761d44ff25710802f6f371a793dca60040240cc328da0a3ea92 SHA512 be99bee951797632a68d08b94e0b604763662c13f58cecc872615081036081b3d72c5c468af47649449d6f7422f52ee99cf2f87fa9c840d10f98cd0217c0cff2
+DIST setuptools-61.3.0.gh.tar.gz 2643769 BLAKE2B 4ede87e7a597a6916dc089c311b0e4d098b08debbd1c4a9cb97078730e9cdc8dbcacd4236ca98a42e3cfafdf66d8f39bb64bc9135291335224b1c3b0bf79deff SHA512 35e2b848cf79e577b8c469562cb68a80b27d42d2d9c1c94f84fea9beb85e2db0796ed64d414add67a404d801c4f4e6cd489a72153de4dc8ed8b45fab24c28fd9
diff --git a/dev-python/setuptools/setuptools-61.3.0.ebuild b/dev-python/setuptools/setuptools-61.3.0.ebuild
new file mode 100644
index 000000000000..f9320a151d3b
--- /dev/null
+++ b/dev-python/setuptools/setuptools-61.3.0.ebuild
@@ -0,0 +1,131 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 7 -- sys-apps/portage dep
+EAPI=7
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{8..10} pypy3 )
+PYTHON_REQ_USE="xml(+)"
+
+inherit distutils-r1 multiprocessing
+
+CPY_PATCHSET="python-gentoo-patches-3.10.0_p1"
+DESCRIPTION="Collection of extensions to Distutils"
+HOMEPAGE="
+	https://github.com/pypa/setuptools/
+	https://pypi.org/project/setuptools/
+"
+SRC_URI="
+	https://github.com/pypa/setuptools/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+	https://dev.gentoo.org/~floppym/python/${CPY_PATCHSET}.tar.xz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/appdirs-1.4.4-r2[${PYTHON_USEDEP}]
+	>=dev-python/jaraco-text-3.7.0-r1[${PYTHON_USEDEP}]
+	>=dev-python/more-itertools-8.12.0-r1[${PYTHON_USEDEP}]
+	dev-python/nspektr[${PYTHON_USEDEP}]
+	>=dev-python/ordered-set-4.0.2-r1[${PYTHON_USEDEP}]
+	>=dev-python/packaging-21.3-r2[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/importlib_metadata-4.10.1-r1[${PYTHON_USEDEP}]
+	' 3.8 3.9)
+	$(python_gen_cond_dep '
+		>=dev-python/importlib_resources-5.4.0-r3[${PYTHON_USEDEP}]
+	' 3.8)
+"
+BDEPEND="
+	${RDEPEND}
+	>=dev-python/wheel-0.37.1-r1[${PYTHON_USEDEP}]
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/build[${PYTHON_USEDEP}]
+			>=dev-python/ini2toml-0.9[${PYTHON_USEDEP}]
+			>=dev-python/filelock-3.4.0[${PYTHON_USEDEP}]
+			>=dev-python/jaraco-envs-2.2[${PYTHON_USEDEP}]
+			>=dev-python/jaraco-path-3.2.0[${PYTHON_USEDEP}]
+			dev-python/mock[${PYTHON_USEDEP}]
+			dev-python/pip[${PYTHON_USEDEP}]
+			dev-python/pip-run[${PYTHON_USEDEP}]
+			dev-python/sphinx[${PYTHON_USEDEP}]
+			dev-python/pytest[${PYTHON_USEDEP}]
+			dev-python/pytest-fixture-config[${PYTHON_USEDEP}]
+			dev-python/pytest-virtualenv[${PYTHON_USEDEP}]
+			dev-python/pytest-xdist[${PYTHON_USEDEP}]
+			dev-python/tomli[${PYTHON_USEDEP}]
+			>=dev-python/tomli-w-1.0.0[${PYTHON_USEDEP}]
+			>=dev-python/virtualenv-20[${PYTHON_USEDEP}]
+			dev-python/wheel[${PYTHON_USEDEP}]
+		' python3_{8..10} pypy3)
+	)
+"
+PDEPEND="
+	>=dev-python/certifi-2016.9.26[${PYTHON_USEDEP}]
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+"
+
+DOCS=( {CHANGES,README}.rst )
+
+src_prepare() {
+	# remove bundled dependencies, setuptools will switch to system deps
+	# automatically
+	rm -r */_vendor || die
+
+	# remove the ugly */extern hack that breaks on unvendored deps
+	rm -r */extern || die
+	find -name '*.py' -exec sed \
+		-e 's:from \w*[.]\+extern ::' -e 's:\w*[.]\+extern[.]::' \
+		-i {} + || die
+
+	# apply distutils patches to the bundled distutils
+	pushd setuptools/_distutils >/dev/null || die
+	# TODO: distutils C++ patch?
+	eapply -p3 "${WORKDIR}/${CPY_PATCHSET}/0006-distutils-make-OO-enable-both-opt-1-and-opt-2-optimi.patch"
+	popd >/dev/null || die
+
+	distutils-r1_src_prepare
+
+	export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+}
+
+python_test() {
+	local -x SETUPTOOLS_USE_DISTUTILS=stdlib
+
+	# keep in sync with python_gen_cond_dep above!
+	has "${EPYTHON}" python3.{8..10} pypy3 || continue
+
+	local EPYTEST_DESELECT=(
+		# network
+		# TODO: see if PRE_BUILT_SETUPTOOLS_* helps
+		setuptools/tests/integration/test_pip_install_sdist.py::test_install_sdist
+		setuptools/tests/test_distutils_adoption.py
+		setuptools/tests/test_virtualenv.py::test_clean_env_install
+		setuptools/tests/test_virtualenv.py::test_no_missing_dependencies
+		'setuptools/tests/test_virtualenv.py::test_pip_upgrade_from_source[None]'
+		setuptools/tests/test_virtualenv.py::test_test_command_install_requirements
+		setuptools/tests/test_setuptools.py::test_its_own_wheel_does_not_contain_tests
+		setuptools/tests/config/test_apply_pyprojecttoml.py::test_apply_pyproject_equivalent_to_setupcfg
+		# unhappy with pytest-xdist?
+		setuptools/tests/test_easy_install.py::TestUserInstallTest::test_local_index
+		# TODO
+		setuptools/tests/test_easy_install.py::TestSetupRequires::test_setup_requires_with_allow_hosts
+		setuptools/tests/test_test.py::test_tests_are_run_once
+		setuptools/tests/config/test_setupcfg.py::TestConfigurationReader::test_basic
+		setuptools/tests/config/test_setupcfg.py::TestConfigurationReader::test_ignore_errors
+		# expects bundled deps in virtualenv
+		setuptools/tests/test_editable_install.py::test_editable_with_pyproject
+	)
+
+	# test_easy_install raises a SandboxViolation due to ${HOME}/.pydistutils.cfg
+	# It tries to sandbox the test in a tempdir
+	HOME="${PWD}" epytest \
+		-n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")" setuptools
+}