dev-python/keystoneauth: add 4.5.0

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

2 files changed, 63 insertions, 0 deletions

diff --git a/dev-python/keystoneauth/Manifest b/dev-python/keystoneauth/Manifest
index c8d6357e3a33..d8eefc9934a5 100644
--- a/dev-python/keystoneauth/Manifest
+++ b/dev-python/keystoneauth/Manifest
@@ -1 +1,2 @@
 DIST keystoneauth1-4.4.0.tar.gz 266308 BLAKE2B 471b6662c27b5cc36dfde76e17f6855d5e840280a05c5c23bbda97b2e75b8fbc44e815994de514a475424476ed4d627930f993ed5fc7109fa3a2a99acf42dde2 SHA512 208b02c8df8a5cbdad1ca66c665d547b375eac2fa0d3aeb6dea3f9ed7ba0e799568e4407b8771df5a362d4275fb6a9b2fe2e3a9287b3817da43463356bc593a3
+DIST keystoneauth1-4.5.0.tar.gz 266418 BLAKE2B cd56e6d62e185ded667b2e9a53478e65fdea7eea203e3598193b34137297a5b75e315433882a08d16f360936208eb55c6d4e5c80e64161f1ce00db2633e59d7a SHA512 eebf9f15624d4544351b26e80af4023dab3a60ad2848b14c1cf6ab4deab50d2c9812747f3e737aacd9e49eacaff3960d8cb1432067d2648d7d2552fdad907457
diff --git a/dev-python/keystoneauth/keystoneauth-4.5.0.ebuild b/dev-python/keystoneauth/keystoneauth-4.5.0.ebuild
new file mode 100644
index 000000000000..3be77a24f5f4
--- /dev/null
+++ b/dev-python/keystoneauth/keystoneauth-4.5.0.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1
+
+DESCRIPTION="This package contains tools for authenticating to an OpenStack-based cloud"
+HOMEPAGE="https://github.com/openstack/keystoneauth"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}1/${PN}1-${PV}.tar.gz"
+S="${WORKDIR}/${PN}1-${PV}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+CDEPEND="
+	>dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+"
+RDEPEND="
+	${CDEPEND}
+	>=dev-python/iso8601-0.1.11[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.14.2[${PYTHON_USEDEP}]
+	>=dev-python/six-1.10.0[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-1.20.0[${PYTHON_USEDEP}]
+	>=dev-python/os-service-types-1.2.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${CDEPEND}
+	test? (
+		>=dev-python/betamax-0.7.0[${PYTHON_USEDEP}]
+		>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/lxml-4.2.0[${PYTHON_USEDEP}]
+		>=dev-python/oauthlib-0.6.2[${PYTHON_USEDEP}]
+		>=dev-python/oslo-config-5.2.0[${PYTHON_USEDEP}]
+		>=dev-python/oslo-utils-3.33.0[${PYTHON_USEDEP}]
+		>=dev-python/oslotest-3.2.0[${PYTHON_USEDEP}]
+		>=dev-python/pyyaml-3.12[${PYTHON_USEDEP}]
+		>=dev-python/requests-kerberos-0.8.0[${PYTHON_USEDEP}]
+		>=dev-python/requests-mock-1.2.0[${PYTHON_USEDEP}]
+		>=dev-python/testresources-2.0.0[${PYTHON_USEDEP}]
+		>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# relies on specific test runner name
+	sed -i -e 's:run\.py:unittest_or_fail.py:' \
+		keystoneauth1/tests/unit/test_session.py || die
+	# remove the test that requires hacking
+	rm keystoneauth1/tests/unit/test_hacking_checks.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	eunittest -b
+}