dev-python/google-auth: Bump to 2.23.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

3 files changed, 68 insertions, 7 deletions

diff --git a/dev-python/google-auth/Manifest b/dev-python/google-auth/Manifest
index c78cdde58d00..26dd217125ce 100644
--- a/dev-python/google-auth/Manifest
+++ b/dev-python/google-auth/Manifest
@@ -1 +1,2 @@
 DIST google-auth-2.22.0.tar.gz 231433 BLAKE2B 07b813209ce3f5ff429c4f9417141fa85029ff3eedb116664d6effdf508497ce6b6552fa4c3b6f9f1e7f1ffe9b9ae8ce72c8c727d277662bb9f8214ccd152b66 SHA512 c2c04e9ad367dd96bf00af7b19c7d897dd9fe3f8e9318b7436ec85a5c146b29c273cc718932956e97b2e4a1e2f12d0d10e835b6cf0f4e46ee19f6aaeed492b5e
+DIST google-auth-2.23.0.tar.gz 231512 BLAKE2B fd7594fb28114d07773e2f0bf2da475cb1d771ef27f67765e9235883cd312b88cda092c5bcbb7a1468ded44da4e5cd121c58850058b023232725a9829969b8c3 SHA512 d5c4967478c2a2846f2297b8449cd1a9de9796f3e1a5075ac7a3c2c35a30468fe93bf5c37b7bb4305925fe5097a57fddbddc482be4446e4364a78709eec1d8cd
diff --git a/dev-python/google-auth/files/google-auth-2.20.0-urllib3-2.patch b/dev-python/google-auth/files/google-auth-2.20.0-urllib3-2.patch
index 791edeed09cf..dcaf88d1a288 100644
--- a/dev-python/google-auth/files/google-auth-2.20.0-urllib3-2.patch
+++ b/dev-python/google-auth/files/google-auth-2.20.0-urllib3-2.patch
@@ -57,12 +57,6 @@ diff --git a/setup.py b/setup.py
 index e45512a02..cfb3b504f 100644
 --- a/setup.py
 +++ b/setup.py
-@@ -29,7 +29,7 @@
-     # install enum34 to support 2.7. enum34 only works up to python version 3.3.
-     'enum34>=1.1.10; python_version < "3.4"',
-     "six>=1.9.0",
+@@ -32,1 +32,1 @@
 -    "urllib3<2.0",
 +    "urllib3>=2.0",
- )
- 
- extras = {
diff --git a/dev-python/google-auth/google-auth-2.23.0.ebuild b/dev-python/google-auth/google-auth-2.23.0.ebuild
new file mode 100644
index 000000000000..4fb5afb4df60
--- /dev/null
+++ b/dev-python/google-auth/google-auth-2.23.0.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Google Authentication Library"
+HOMEPAGE="
+	https://github.com/googleapis/google-auth-library-python/
+	https://pypi.org/project/google-auth/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+	<dev-python/cachetools-6.0.0[${PYTHON_USEDEP}]
+	>=dev-python/pyasn1-0.1.7[${PYTHON_USEDEP}]
+	>=dev-python/pyasn1-modules-0.2.1[${PYTHON_USEDEP}]
+	>=dev-python/rsa-3.1.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/cryptography[${PYTHON_USEDEP}]
+		dev-python/flask[${PYTHON_USEDEP}]
+		dev-python/freezegun[${PYTHON_USEDEP}]
+		dev-python/grpcio[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/moto[${PYTHON_USEDEP}]
+		dev-python/pyopenssl[${PYTHON_USEDEP}]
+		dev-python/pytest-localserver[${PYTHON_USEDEP}]
+		dev-python/pyu2f[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/responses[${PYTHON_USEDEP}]
+		>=dev-python/urllib3-2[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+PATCHES=(
+	# https://github.com/googleapis/google-auth-library-python/pull/1290
+	"${FILESDIR}"/google-auth-2.20.0-urllib3-2.patch
+)
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		# these are compatibility tests with oauth2client
+		# disable them to unblock removal of that package
+		tests/test__oauth2client.py
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	find "${BUILD_DIR}" -name '*.pth' -delete || die
+}