dev-python/django: Bump to 3.2.22

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 111 insertions, 0 deletions

diff --git a/dev-python/django/Manifest b/dev-python/django/Manifest
index e664a72c46d9..bebdf4f40bd4 100644
--- a/dev-python/django/Manifest
+++ b/dev-python/django/Manifest
@@ -1,5 +1,7 @@
 DIST Django-3.2.21.checksum.txt 2564 BLAKE2B a075e02b5b4d939a511848894ccea8eeb2c101f0f1369996c3c1f11acf34c26474e3f0596e44dc2da91e1ff3f3ad75e0d27227abbb41c7fd530e18bfdea6a349 SHA512 37ae3b2a804374b56c9fcfe2a18dea8f3fd49d605893c861965be35b21155fa98950fd8970607003be9738bfbcc38e50e2bdd4971dfdaa97e149d3ebb20edcdc
 DIST Django-3.2.21.tar.gz 9836824 BLAKE2B f91f1b26454f4e3f19033fca4b34bb2a59abd8a7ac7716512fb791732d447b79b825d63496d8615827d7e8ae07c1d2e80d76876153fc1a29b775782d63324cb8 SHA512 614d5e79c323f43d893ca235d81f1cb06287ead56aa5b7baf9930b9a99446d77ec111c65675a864cbf7cf2b9dfceaa0ffab389855da9d7a5c6e36067ab42e5dd
+DIST Django-3.2.22.checksum.txt 2582 BLAKE2B bb9fe0f9e8af1142a1dae1b5c53422ddeb186d8c13389cbdbeaa9585be519d3c1604e8af797be1cf75261041799f4e213dfb5764559f0c4765d8e33580acd614 SHA512 6b30f0caed55b966c1a1c83b1f733f7d2098f33d5e84670f2cf3729e584e6b15c6439589bbe26670aa2a6e286f938305bc5457bc4fbc5ba86a128938afcab076
+DIST Django-3.2.22.tar.gz 9827193 BLAKE2B 164d766ee16c92c7f47a45c3a426d54a8bc0007a9387594d61fda77d143f51142389ecc4817f2fcadeaaa55ac3bcf381331cb9ca2305d0915bef1e10101dcd16 SHA512 a2c81dc63609be521aa1a74c85be93e3263380d533c0d6888b4ba20f5a12f0d99c329286c99896734fc9a9b111d873934e4f553d18f246911cbfd65feea73b46
 DIST Django-4.1.11.checksum.txt 2564 BLAKE2B 55021666213384900c1871d939594bcb38b288870ff3337553d76eb2e0797c6394ec268f0c27768ceddfe9fa83027126de9de5d89ec314b2b6d6e3e7273f6534 SHA512 f36f1fb5fbdc1bee86512316e54dee4d70b535cc87b69d583a7d1b8ca1beeb7cf487484f189436e5116bb7220a18f1b627fe886dd40a11bd1ac29c12222f6321
 DIST Django-4.1.11.tar.gz 10511539 BLAKE2B 9c4c5d6d1d56f064737dc38fe6e8ace77ca166790471806c701040afb4b05034104d4f70a177ee65aab3f41b7e52418b254148cb72e9db61a77c97fb57808ce0 SHA512 00e546c26f5a5f5f3d15b1524922a9d25d04b1b5291ee669369462831ba0c9027ca1369ac1a442b6f2216c453b89acade777513ac1a93ca3274b7e9291bf9d60
 DIST Django-4.1.12.checksum.txt 2582 BLAKE2B 67b101ef7b11fe1ad47872b9bbb26851b20db304145cebbf3f836bcd7505aa5282b54d8541a468871fa0489445ce282dc030f83241db3a1824e5e2d3949257b9 SHA512 d226527d67c98b1641ea63899c93e3be21855f7be3270ab98e2ad1580d38edf1ab209d92964a8b0ba5b15a2466af96fe1838914b0aaa0953fbc46f21a25587fb
diff --git a/dev-python/django/django-3.2.22.ebuild b/dev-python/django/django-3.2.22.ebuild
new file mode 100644
index 000000000000..ca46ed4c7d3b
--- /dev/null
+++ b/dev-python/django/django-3.2.22.ebuild
@@ -0,0 +1,109 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+PYTHON_REQ_USE='sqlite?,threads(+)'
+
+inherit bash-completion-r1 distutils-r1 optfeature verify-sig
+
+DESCRIPTION="High-level Python web framework"
+HOMEPAGE="
+	https://www.djangoproject.com/
+	https://github.com/django/django/
+	https://pypi.org/project/Django/
+"
+SRC_URI="
+	https://media.djangoproject.com/releases/$(ver_cut 1-2)/${P^}.tar.gz
+	verify-sig? ( https://media.djangoproject.com/pgp/${P^}.checksum.txt )
+"
+S="${WORKDIR}/${P^}"
+
+LICENSE="BSD"
+# admin fonts: Roboto (media-fonts/roboto)
+LICENSE+=" Apache-2.0"
+# admin icons, jquery, xregexp.js
+LICENSE+=" MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~x64-macos"
+IUSE="doc sqlite test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/asgiref-3.3.4[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	>=dev-python/sqlparse-0.2.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		$(python_gen_impl_dep sqlite)
+		${RDEPEND}
+		dev-python/docutils[${PYTHON_USEDEP}]
+		dev-python/jinja[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pillow[webp,${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		dev-python/selenium[${PYTHON_USEDEP}]
+		dev-python/tblib[${PYTHON_USEDEP}]
+		sys-devel/gettext
+	)
+	verify-sig? ( >=sec-keys/openpgp-keys-django-20201201 )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-3.1-bashcomp.patch
+	"${FILESDIR}"/django-3.2.19-py311.patch
+	# needed for Python 3.11
+	"${FILESDIR}"/django-3.2.20-urlsplit.patch
+)
+
+distutils_enable_sphinx docs --no-autodoc
+
+VERIFY_SIG_OPENPGP_KEY_PATH=${BROOT}/usr/share/openpgp-keys/django.asc
+
+src_unpack() {
+	if use verify-sig; then
+		cd "${DISTDIR}" || die
+		verify-sig_verify_signed_checksums \
+			"${P^}.checksum.txt" sha256 "${P^}.tar.gz"
+		cd "${WORKDIR}" || die
+	fi
+
+	default
+}
+
+python_prepare_all() {
+	# Fails because of warnings
+	sed -i 's/test_dumpdata_proxy_with_concrete/_&/' tests/fixtures/tests.py || die
+	# TODO: this suddenly started failing
+	sed -i -e 's:test_custom_fields:_&:' tests/inspectdb/tests.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	# Tests have non-standard assumptions about PYTHONPATH,
+	# and don't work with ${BUILD_DIR}/lib.
+	PYTHONPATH=. "${EPYTHON}" tests/runtests.py --settings=test_sqlite -v2 ||
+		die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	newbashcomp extras/django_bash_completion ${PN}-admin
+	bashcomp_alias ${PN}-admin django-admin.py
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature_header "Additional Backend support can be enabled via:"
+	optfeature "MySQL backend support" dev-python/mysqlclient
+	optfeature "PostgreSQL backend support" dev-python/psycopg:2
+	optfeature_header
+	optfeature "GEO Django" "sci-libs/gdal[geos]"
+	optfeature "Memcached support" dev-python/pylibmc dev-python/python-memcached
+	optfeature "ImageField Support" dev-python/pillow
+	optfeature "Password encryption" dev-python/bcrypt
+}