dev-python/PyQt5-sip: Revert "Remove redundant versions"

Reverts: 7dc25e7317f8f75a5dff95613d72a2b15f474a05
Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 91 insertions, 0 deletions

diff --git a/dev-python/PyQt5-sip/Manifest b/dev-python/PyQt5-sip/Manifest
index 22b9d1454a5d..19581414f6a1 100644
--- a/dev-python/PyQt5-sip/Manifest
+++ b/dev-python/PyQt5-sip/Manifest
@@ -1,2 +1,3 @@
 DIST sip-4.19.22.tar.gz 1050805 BLAKE2B 7382fdf74c5bb8b55bcedae74acdcb7b81ef06a64d129a9e6f11a5eb293900e37df513f1c4290f2299f49a5bd97e2a6b3c6bc32ddbf2eaf848bd5e5c5dc25edc SHA512 4d366e589945e589f69a3caf979076ef37e319ac0efdd8ec3cee4869da89e112832462215ca2e235036bacfade7efc4d530aa93e7492c283dc1b2503e08feea5
+DIST sip-4.19.23.tar.gz 1053640 BLAKE2B 316c972a5cf7dd6464a418702e7d91192202330cf89a78d6ef480034ac8fc2f3f4cfedb85e6bc7d3d018bfe3d29ea767133db008dbfa521312e3aea2b96cff74 SHA512 a50c6202ebb6a5d1c98b6fc79925fa5d82236a944003854b057be9e2f7340d5cd689ba0e08f46f521736f3574c4089768c869bb8921e66b23944a31a832770f1
 DIST sip-4.19.24.tar.gz 1055461 BLAKE2B 6990b127a83fa57bc084eb9a1097f73c384b4fcf3d181479557fe2ffc66cde254bfbb5aef26f5ddd84dca346f54184952e7a111adf3b665f68571853e63b6575 SHA512 c9acf8c66da6ff24ffaeed254c11deabbc587cea0eb50164f2016199af30b85980f96a2d754ae5e7fe080f9076673b1abc82e2a6a41ff2ac442fb2b326fca1c0
diff --git a/dev-python/PyQt5-sip/PyQt5-sip-4.19.23-r1.ebuild b/dev-python/PyQt5-sip/PyQt5-sip-4.19.23-r1.ebuild
new file mode 100644
index 000000000000..c61529a6f32a
--- /dev/null
+++ b/dev-python/PyQt5-sip/PyQt5-sip-4.19.23-r1.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9} )
+inherit python-r1 toolchain-funcs
+
+DESCRIPTION="Private sip module for PyQt5"
+HOMEPAGE="https://www.riverbankcomputing.com/software/sip/intro"
+
+MY_PN=sip
+MY_P=${MY_PN}-${PV/_pre/.dev}
+if [[ ${PV} == *_pre* ]]; then
+	SRC_URI="https://dev.gentoo.org/~pesa/distfiles/${MY_P}.tar.gz"
+else
+	SRC_URI="https://www.riverbankcomputing.com/static/Downloads/${MY_PN}/${PV}/${MY_P}.tar.gz"
+fi
+
+# Sub-slot based on SIP_API_MAJOR_NR from siplib/sip.h
+SLOT="0/12"
+LICENSE="|| ( GPL-2 GPL-3 SIP )"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+IUSE=""
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="${PYTHON_DEPS}"
+RDEPEND="${DEPEND}
+	!<dev-python/PyQt5-5.12.2
+"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	# Sub-slot sanity check
+	local sub_slot=${SLOT#*/}
+	local sip_api_major_nr=$(sed -nre 's:^#define SIP_API_MAJOR_NR\s+([0-9]+):\1:p' siplib/sip.h || die)
+	if [[ ${sub_slot} != ${sip_api_major_nr} ]]; then
+		eerror
+		eerror "Ebuild sub-slot (${sub_slot}) does not match SIP_API_MAJOR_NR (${sip_api_major_nr})"
+		eerror "Please update SLOT variable as follows:"
+		eerror "    SLOT=\"${SLOT%%/*}/${sip_api_major_nr}\""
+		eerror
+		die "sub-slot sanity check failed"
+	fi
+
+	default
+}
+
+src_configure() {
+	configuration() {
+		local myconf=(
+			"${PYTHON}"
+			"${S}"/configure.py
+			--sip-module PyQt5.sip
+			--sysroot="${ESYSROOT}/usr"
+			--no-tools
+			AR="$(tc-getAR) cqs"
+			CC="$(tc-getCC)"
+			CFLAGS="${CFLAGS}"
+			CFLAGS_RELEASE=
+			CXX="$(tc-getCXX)"
+			CXXFLAGS="${CXXFLAGS}"
+			CXXFLAGS_RELEASE=
+			LINK="$(tc-getCXX)"
+			LINK_SHLIB="$(tc-getCXX)"
+			LFLAGS="${LDFLAGS}"
+			LFLAGS_RELEASE=
+			RANLIB=
+			STRIP=
+		)
+		echo "${myconf[@]}"
+		"${myconf[@]}" || die
+	}
+	python_foreach_impl run_in_build_dir configuration
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir default
+}
+
+src_install() {
+	installation() {
+		emake DESTDIR="${D}" install
+	}
+	python_foreach_impl run_in_build_dir installation
+
+	einstalldocs
+}