dev-php/PEAR-Text_Highlighter: new revision sans the php-pear-r1 eclass.

This new revision drops php-pear-r1.eclass, and in the process fixes a
few bugs. We no longer install all of the development junk, which
eliminates the /usr/bin/generate executable (used to generate the PHP
classes), and avoids a file collision with app-accessibility/julius.
We also now store the documentation in the correct location.

One extraneous dependency was removed, and another undocumented one
added.

Gentoo-Bug: 544514

Package-Manager: portage-2.3.0

2 files changed, 34 insertions, 16 deletions

diff --git a/dev-php/PEAR-Text_Highlighter/PEAR-Text_Highlighter-0.7.3-r1.ebuild b/dev-php/PEAR-Text_Highlighter/PEAR-Text_Highlighter-0.7.3-r1.ebuild
new file mode 100644
index 000000000000..d510d70cd99c
--- /dev/null
+++ b/dev-php/PEAR-Text_Highlighter/PEAR-Text_Highlighter-0.7.3-r1.ebuild
@@ -0,0 +1,34 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+MY_PN="${PN/PEAR-/}"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="A package for syntax highlighting"
+HOMEPAGE="http://pear.php.net/package/${MY_PN}"
+SRC_URI="http://download.pear.php.net/package/${MY_P}.tgz"
+LICENSE="PHP-3.01"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+# There is a documented dependency on XML_Parser, but that's only needed
+# for development -- if you want to *generate* the PHP class files. The
+# ones in the release are already pre-generated. The dependency on the
+# XML_Serializer, on the other hand, is not documented but is requird
+# by the XML output renderer.
+RDEPEND="dev-lang/php
+	dev-php/PEAR-PEAR
+	dev-php/PEAR-XML_Serializer"
+
+S="${WORKDIR}/${MY_P}"
+
+src_install() {
+	dodoc README TODO
+
+	insinto /usr/share/php
+	doins -r Text
+}
diff --git a/dev-php/PEAR-Text_Highlighter/PEAR-Text_Highlighter-0.7.3.ebuild b/dev-php/PEAR-Text_Highlighter/PEAR-Text_Highlighter-0.7.3.ebuild
deleted file mode 100644
index 1ac7a8c4cd1b..000000000000
--- a/dev-php/PEAR-Text_Highlighter/PEAR-Text_Highlighter-0.7.3.ebuild
+++ /dev/null
@@ -1,16 +0,0 @@
-# Copyright 1999-2014 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Id$
-
-EAPI=5
-
-inherit php-pear-r1
-
-DESCRIPTION="A package for syntax highlighting"
-LICENSE="PHP-3"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE=""
-
-RDEPEND="dev-php/PEAR-XML_Parser
-	dev-php/PEAR-Console_Getopt"