dev-libs/mongo-c-driver: Bump to 1.24.4

Co-authored-by: EJ Agas <agas.ej09@gmail.com>
Signed-off-by: EJ Agas <agas.ej09@gmail.com>
Signed-off-by: Jaco Kroon <jaco@uls.co.za>
Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 97 insertions, 0 deletions

diff --git a/dev-libs/mongo-c-driver/Manifest b/dev-libs/mongo-c-driver/Manifest
index 57f1300f64fd..2e83e1e3a78a 100644
--- a/dev-libs/mongo-c-driver/Manifest
+++ b/dev-libs/mongo-c-driver/Manifest
@@ -1 +1,2 @@
 DIST mongo-c-driver-1.18.0.tar.gz 7246954 BLAKE2B 9418ab2e132f8a8c582bcbea8c7b090e9e45e34219845d8f6b7a99d4ebfb17ef2eec2223504e9a4ab7f51ca01e904a7f3bb04bf9f8bf20c010ab9f82894a728e SHA512 c970f347689916172a957fc431b307bab3cb63367d4b39c49745c75b9fa84f0035db934c551570a4141733fc1bc6b33b118911c3b69ecdea797f19312b213606
+DIST mongo-c-driver-1.24.4.tar.gz 7916661 BLAKE2B e361b52bf16eed7437428b0481d792ecf2f9cc283fdd6f23916d4a3ffb1b7d7c9ea7a7c4cf5f369e21fb6d4f564b91e07ac2ee44656855993218593dc4f1c166 SHA512 3563c061565d17a76581e188f6e184d7e41f2729812c8815afd34e03ebe6c1d25d7498a2cb1b599a09d24f6268c36473ef5113a14c7585a1532c9abf2e56e936
diff --git a/dev-libs/mongo-c-driver/mongo-c-driver-1.24.4.ebuild b/dev-libs/mongo-c-driver/mongo-c-driver-1.24.4.ebuild
new file mode 100644
index 000000000000..05faec798845
--- /dev/null
+++ b/dev-libs/mongo-c-driver/mongo-c-driver-1.24.4.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Client library written in C for MongoDB"
+HOMEPAGE="https://github.com/mongodb/mongo-c-driver"
+SRC_URI="https://github.com/mongodb/mongo-c-driver/releases/download/${PV}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~hppa ~riscv ~x86"
+IUSE="debug examples icu sasl ssl static-libs test"
+REQUIRED_USE="test? ( static-libs )"
+
+# No tests on x86 because tests require dev-db/mongodb which don't support
+# x86 anymore (bug #645994)
+RESTRICT="x86? ( test )
+	!test? ( test )"
+
+RDEPEND="app-arch/snappy:=
+	app-arch/zstd:=
+	>=dev-libs/libbson-${PV}[static-libs?]
+	dev-python/sphinx
+	sys-libs/zlib:=
+	icu? ( dev-libs/icu:= )
+	sasl? ( dev-libs/cyrus-sasl:= )
+	ssl? (
+		dev-libs/openssl:=
+	)"
+DEPEND="${RDEPEND}
+	test? (
+		dev-db/mongodb
+		dev-libs/libbson[static-libs]
+	)"
+
+src_prepare() {
+	cmake_src_prepare
+
+	# copy private headers for tests since we don't build libbson
+	if use test; then
+		mkdir -p src/libbson/tests/bson || die
+		cp src/libbson/src/bson/bson-*.h src/libbson/tests/bson/ || die
+	fi
+
+	# remove doc files
+	sed -i '/^\s*install\s*(FILES COPYING NEWS/,/^\s*)/{d}' CMakeLists.txt || die
+
+	# enable tests
+	sed -i '/message ("--   disabling test-libmongoc since using system libbson")/{d}' CMakeLists.txt || die
+	sed -i '/SET (ENABLE_TESTS OFF)/{d}' CMakeLists.txt || die
+	sed -i 's/message (FATAL_ERROR "System libbson built without static library target")/message (STATUS "System libbson built without static library target")/' CMakeLists.txt || die
+	sed -i 's#<bson/bson-private.h>#"bson/bson-private.h"#' src/libbson/tests/test-bson.c || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_SKIP_RPATH=ON # mongoc-stat insecure runpath
+		-DUSE_SYSTEM_LIBBSON=ON
+		-DENABLE_EXAMPLES=OFF
+		-DENABLE_ICU="$(usex icu ON OFF)"
+		-DENABLE_MAN_PAGES=ON
+		-DENABLE_MONGOC=ON
+		-DENABLE_SNAPPY=AUTO
+		-DENABLE_ZLIB=SYSTEM
+		-DENABLE_SASL="$(usex sasl CYRUS OFF)"
+		-DENABLE_SSL="$(usex ssl $(usex ssl OPENSSL) OFF)"
+		-DENABLE_STATIC="$(usex static-libs ON OFF)"
+		-DENABLE_TESTS="$(usex test ON OFF)"
+		-DENABLE_TRACING="$(usex debug ON OFF)"
+		-DENABLE_UNINSTALL=OFF
+		-DENABLE_ZSTD=ON
+	)
+
+	cmake_src_configure
+}
+
+# FEATURES="test -network-sandbox" USE="static-libs" emerge dev-libs/mongo-c-driver
+src_test() {
+	local PORT=27099
+	mongod --port ${PORT} --bind_ip 127.0.0.1 --nounixsocket --fork \
+		--dbpath="${T}" --logpath="${T}/mongod.log" || die
+	MONGOC_TEST_URI="mongodb://[127.0.0.1]:${PORT}" ../mongo-c-driver-${PV}_build/src/libmongoc/test-libmongoc || die
+	kill $(<"${T}/mongod.lock")
+}
+
+src_install() {
+	if use examples; then
+		docinto examples
+		dodoc src/libmongoc/examples/*.c
+	fi
+
+	cmake_src_install
+}