dev-libs/libwacom: 0.33 version bump

Package-Manager: Portage-2.3.71, Repoman-2.3.17
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

1 files changed, 50 insertions, 0 deletions

diff --git a/dev-libs/libwacom/libwacom-0.33.ebuild b/dev-libs/libwacom/libwacom-0.33.ebuild
new file mode 100644
index 000000000000..0b1c33cddfbf
--- /dev/null
+++ b/dev-libs/libwacom/libwacom-0.33.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools udev
+
+DESCRIPTION="Library for identifying Wacom tablets and their model-specific features"
+HOMEPAGE="https://github.com/linuxwacom/libwacom"
+SRC_URI="https://github.com/linuxwacom/${PN}/releases/download/${P}/${P}.tar.bz2"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="doc static-libs"
+
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+"
+RDEPEND="
+	dev-libs/glib:2
+	virtual/libgudev:=
+"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+	if ! use doc; then
+		sed -e 's:^\(SUBDIRS = .* \)doc:\1:' -i Makefile.am || die
+	fi
+	eautoreconf
+}
+
+src_configure() {
+	econf $(use_enable static-libs static)
+}
+
+src_install() {
+	use doc && HTML_DOCS=( doc/html/. )
+	default
+	local udevdir="$(get_udevdir)"
+	dodir "${udevdir}/rules.d"
+	# generate-udev-rules must be run from inside tools directory
+	pushd tools > /dev/null || die
+	./generate-udev-rules > "${ED}/${udevdir}/rules.d/65-libwacom.rules" || \
+		die "generating udev rules failed"
+	popd > /dev/null || die
+	find "${D}" -name '*.la' -type f -delete || die
+}