dev-libs/libmpack: new package

This is the mpack C lib, which will be needed for a newer lua mpack
module version.

Package-Manager: Portage-3.0.9, Repoman-3.0.2
Signed-off-by: Conrad Kostecki <conikost@gentoo.org>

1 files changed, 52 insertions, 0 deletions

diff --git a/dev-libs/libmpack/libmpack-1.0.5.ebuild b/dev-libs/libmpack/libmpack-1.0.5.ebuild
new file mode 100644
index 000000000000..479c92bd7b29
--- /dev/null
+++ b/dev-libs/libmpack/libmpack-1.0.5.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+DESCRIPTION="Simple implementation of msgpack in C"
+HOMEPAGE="https://github.com/libmpack/libmpack"
+SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+DEPEND=""
+RDEPEND="${DEPEND}"
+BDEPEND=""
+
+src_prepare() {
+	default
+
+	# Make compiling verbose
+	sed -e 's/@$(LIBTOOL)/$(LIBTOOL)/g' -i Makefile || die
+
+	# Respect users CFLAGS
+	sed -e 's/-ggdb//g' -i Makefile || die
+	sed -e 's/-O3//g' -i .config/release.mk || die
+}
+
+src_compile() {
+	local myemakeargs=(
+		"CC=$(tc-getCC)"
+		"config=release"
+		"LIBDIR=/usr/$(get_libdir)"
+	)
+
+	emake "${myemakeargs[@]}" lib-bin
+}
+
+src_install() {
+	local myemakeargs=(
+		"PREFIX=/usr"
+		"DESTDIR=${ED}"
+		"LIBDIR=/usr/$(get_libdir)"
+		"XLDFLAGS=-shared"
+	)
+
+	emake "${myemakeargs[@]}" install
+
+	find "${ED}" -name '*.la' -delete || die
+}