dev-libs/libflatarray: Add current version

This is needed as dependency for the current sci-libs/libgeodecomp version.

Package-Manager: Portage-2.3.89, Repoman-2.3.20
Signed-off-by: Kurt Kanzenbach <kurt@kmk-computers.de>
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

1 files changed, 52 insertions, 0 deletions

diff --git a/dev-libs/libflatarray/libflatarray-0.4.0_pre20200314.ebuild b/dev-libs/libflatarray/libflatarray-0.4.0_pre20200314.ebuild
new file mode 100644
index 000000000000..95122803d1b1
--- /dev/null
+++ b/dev-libs/libflatarray/libflatarray-0.4.0_pre20200314.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake cuda
+
+MY_COMMIT="c5d90fb37ef52dbe56f611979fbe120fa1303284"
+
+DESCRIPTION="Struct of arrays library with object oriented interface for C++"
+HOMEPAGE="
+	http://www.libgeodecomp.org/libflatarray.html
+	https://github.com/STEllAR-GROUP/libflatarray"
+SRC_URI="https://github.com/STEllAR-GROUP/libflatarray/archive/${MY_COMMIT}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Boost-1.0"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="cuda examples test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	cuda? ( dev-util/nvidia-cuda-toolkit )"
+
+S="${WORKDIR}/libflatarray-${MY_COMMIT}"
+
+src_prepare() {
+	cmake_src_prepare
+	use cuda && cuda_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_CUDA=$(usex cuda)
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	if use examples; then
+		docompress -x /usr/share/doc/${PF}
+		dodoc -r examples/
+		dodoc -r "${WORKDIR}"/${P}_build/examples/
+		find "${ED}"/usr/share/doc/${PF} -iname "*cmake*" -exec rm -r {} + || die
+	fi
+}
+
+src_test() {
+	cmake_build check
+}