dev-libs/folks: Bump to 0.15.4

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Pacho Ramos <pacho@gentoo.org>

2 files changed, 97 insertions, 0 deletions

diff --git a/dev-libs/folks/Manifest b/dev-libs/folks/Manifest
index f6317c87b245..6d69ee3bf2b3 100644
--- a/dev-libs/folks/Manifest
+++ b/dev-libs/folks/Manifest
@@ -1 +1,2 @@
 DIST folks-0.15.3.tar.xz 491432 BLAKE2B f11123a2c41c4a36c002b26f3c3616d62e4a74bbddbde84643143404497c8e3c31d8cafc8bff0ba4714606259aaa6f7adf352ba4bb98a20c75a181ee68bfda3a SHA512 dd54aef470990974bfc9b22fb83c868ca9674608ccfddeea1bb7507dfc77d7d12a43d43462957b0bb99bf249c13868ba7326f7fd7e38de8802a3ba54e33d8d58
+DIST folks-0.15.4.tar.xz 493004 BLAKE2B 0e067a39b4e89e8fa41b20f37c774e56fcb1e0c8de23798ced647177b0d9329509ae3c03ff85a00464887deb4ce275c96b2fcf50aa2dd44af02e20b6ee45fe65 SHA512 4dbd0bb82d56a8cb179ab8148ce531817ccd55bd40f8b562eb0d77555b264e5190669b356ff009c81a963fdcacaabc02fe871bf0c3c668a648f2c820da76f25c
diff --git a/dev-libs/folks/folks-0.15.4.ebuild b/dev-libs/folks/folks-0.15.4.ebuild
new file mode 100644
index 000000000000..7d90012d5b65
--- /dev/null
+++ b/dev-libs/folks/folks-0.15.4.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+VALA_USE_DEPEND="vapigen"
+VALA_MIN_API_VERSION="0.48"
+PYTHON_COMPAT=( python3_{7..10} )
+
+inherit gnome.org gnome2-utils meson python-any-r1 vala xdg
+
+DESCRIPTION="Library for aggregating people from multiple sources"
+HOMEPAGE="https://wiki.gnome.org/Projects/Folks https://gitlab.gnome.org/GNOME/folks"
+
+LICENSE="LGPL-2.1+"
+SLOT="0/26" # subslot = libfolks soname version
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~x86-linux"
+
+IUSE="bluetooth eds +telepathy test utils"
+REQUIRED_USE="bluetooth? ( eds )"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	>=dev-libs/glib-2.58:2
+	>=dev-libs/libgee-0.10:0.8[introspection]
+	>=dev-libs/gobject-introspection-1.54:=
+	telepathy? (
+		>=net-libs/telepathy-glib-0.19.9
+		dev-libs/dbus-glib
+	)
+	eds? ( >=gnome-extra/evolution-data-server-3.38:= )
+	dev-libs/libxml2:2
+	utils? ( sys-libs/readline:0= )
+"
+# telepathy-mission-control needed at runtime; it is used by the telepathy
+# backend via telepathy-glib's AccountManager binding.
+RDEPEND="${DEPEND}
+	bluetooth? ( >=net-wireless/bluez-5[obex] )
+	telepathy? ( net-im/telepathy-mission-control )
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	$(vala_depend)
+	telepathy? ( net-libs/telepathy-glib[vala] )
+	eds? ( gnome-extra/evolution-data-server[vala] )
+	test? (
+		sys-apps/dbus
+		bluetooth? (
+			$(python_gen_any_dep '
+				dev-python/python-dbusmock[${PYTHON_USEDEP}]
+			')
+		)
+	)
+"
+
+python_check_deps() {
+	if use test && use bluetooth; then
+		has_version "dev-python/python-dbusmock[${PYTHON_USEDEP}]"
+	fi
+}
+
+src_prepare() {
+	vala_src_prepare
+	xdg_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use bluetooth bluez_backend)
+		$(meson_use eds eds_backend)
+		$(meson_use eds ofono_backend)
+		$(meson_use telepathy telepathy_backend)
+		-Dzeitgeist=false # last rited package
+		-Dimport_tool=true
+		$(meson_use utils inspect_tool)
+		$(meson_use test tests)
+		-Dinstalled_tests=false
+		-Ddocs=false # Needs find_program sedding to specific version; only dev docs, don't bother
+	)
+	meson_src_configure
+}
+
+src_test() {
+	dbus-run-session meson test -C "${BUILD_DIR}" -t 5
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}