dev-games/clanlib: Version bump to 4.0.0

* EAPI=6

Package-Manager: Portage-2.3.3, Repoman-2.3.1

1 files changed, 77 insertions, 0 deletions

diff --git a/dev-games/clanlib/clanlib-4.0.0.ebuild b/dev-games/clanlib/clanlib-4.0.0.ebuild
new file mode 100644
index 000000000000..7fa5f2d115c5
--- /dev/null
+++ b/dev-games/clanlib/clanlib-4.0.0.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit autotools
+
+MY_PN=ClanLib
+
+DESCRIPTION="Multi-platform game development library"
+HOMEPAGE="https://github.com/sphair/ClanLib"
+SRC_URI="https://github.com/sphair/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="ZLIB"
+SLOT="4.0"
+KEYWORDS="~amd64 ~x86" #not big endian safe #82779
+IUSE="cpu_flags_x86_sse2 doc examples ipv6 opengl sound static-libs X"
+REQUIRED_USE="opengl? ( X )"
+
+RDEPEND="
+	sys-libs/zlib
+	X? (
+		media-libs/freetype:2
+		media-libs/fontconfig
+		x11-libs/libX11
+		opengl? (
+			virtual/opengl
+			x11-libs/libXrender
+		)
+	)
+	sound? ( media-libs/alsa-lib )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	doc? (
+		app-doc/doxygen
+		dev-lang/perl
+		media-gfx/graphviz
+	)"
+
+S=${WORKDIR}/${MY_PN}-${PV}
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-4.0.0-fix-build-system.patch
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable doc docs) \
+		$(use_enable cpu_flags_x86_sse2 sse2) \
+		$(use_enable opengl clanGL) \
+		$(use_enable opengl clanUI) \
+		$(use_enable X clanDisplay) \
+		$(use_enable sound clanSound) \
+		$(use_enable ipv6 getaddr) \
+		$(use_enable static-libs static)
+}
+
+src_compile() {
+	default
+	use doc && emake html
+}
+
+src_install() {
+	default
+
+	use doc && emake DESTDIR="${D}" install-html
+	use examples && dodoc -r Examples Resources
+
+	# package provides .pc files
+	find "${D}" -name '*.la' -delete || die
+}