app-office/texmacs: add 2.1, drop 1.99.11

Mind you, this version STILL requires guile-1.8 so it remains masked.

For the record, upstream Web site does support HTTPS but as of
2021-07-21, their Let's Encrypt host certificate is signed by the old
root CA which is no longer accepted by wget.

Signed-off-by: Marek Szuba <marecki@gentoo.org>

1 files changed, 59 insertions, 0 deletions

diff --git a/app-office/texmacs/texmacs-2.1.ebuild b/app-office/texmacs/texmacs-2.1.ebuild
new file mode 100644
index 000000000000..e0775e242482
--- /dev/null
+++ b/app-office/texmacs/texmacs-2.1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake xdg-utils
+
+MY_P=${P/tex/TeX}-src
+
+DESCRIPTION="Wysiwyg text processor with high-quality maths"
+HOMEPAGE="http://www.texmacs.org/"
+SRC_URI="http://www.texmacs.org/Download/ftp/tmftp/source/${MY_P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="debug jpeg netpbm sqlite svg spell"
+KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	app-text/ghostscript-gpl
+	<dev-scheme/guile-1.9[debug?,deprecated]
+	media-libs/freetype
+	x11-apps/xmodmap
+	x11-libs/libXext
+	virtual/latex-base
+	>=dev-qt/qtcore-5.9.1:5
+	>=dev-qt/qtgui-5.9.1:5
+	>=dev-qt/qtwidgets-5.9.1:5
+	>=dev-qt/qtprintsupport-5.9.1:5
+	sqlite? ( dev-db/sqlite )
+	jpeg? ( || ( media-gfx/imagemagick media-gfx/jpeg2ps ) )
+	netpbm? ( media-libs/netpbm )
+	spell? ( app-text/aspell )
+	svg? ( || ( media-gfx/inkscape gnome-base/librsvg:2 ) )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="x11-base/xorg-proto"
+
+S="${WORKDIR}/${MY_P}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DUSE_SQLITE3=$(usex sqlite 1 0)
+		-DDEBUG_ASSERT=$(usex debug 1 0)
+	)
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+	xdg_icon_cache_update
+}