app-misc/pax-utils: bump up to 1.2.9

Three new fixes:
- security.c: allow faccessat2 syscall in seccomt filters
- scanmacho: add support for dumping UUIDs
- {,pax}macho: add support for arm64 arch

Reported-by: Cănărău Constantin
Closes: https://bugs.gentoo.org/768435
Signed-off-by: Sergei Trofimovich <slyfox@gentoo.org>
Package-Manager: Portage-3.0.14, Repoman-3.0.2
Package-Manager: Portage-3.0.14, Repoman-3.0.2
Signed-off-by: Sergei Trofimovich <slyfox@gentoo.org>

2 files changed, 79 insertions, 0 deletions

diff --git a/app-misc/pax-utils/Manifest b/app-misc/pax-utils/Manifest
index 28a9b53391f4..0c437c32da0a 100644
--- a/app-misc/pax-utils/Manifest
+++ b/app-misc/pax-utils/Manifest
@@ -1,2 +1,3 @@
 DIST pax-utils-1.2.6.tar.xz 680696 BLAKE2B b271e19ed5ec1024d7c6e5723c12464c6ab07646dfbfd4738bfe0250629205051642421425d7c7c5f540b1ac3d100c13d1beca398d9766f7f477830ab128eef2 SHA512 59fe16c5573414aa2952a99c5b85c16cf10dbbee76943f263d31d5b1aa8818a9b00fa78c8b6dadbe02216de54fc32b26d80303a17e2d854de6bb9dd8b431f617
 DIST pax-utils-1.2.8.tar.xz 704804 BLAKE2B b64b50f985320618e10528aaddbeee9a2c86b05724d8564342fc78fd8bd31a84f3cfe5e6051b3b8a1a882bb0b3da586ca351b6fdda0fd6168930e8e4a44806cb SHA512 c211defb72921a6dfa950173bef7ef6bc5ac059dbb394a82d2b2455d082843fc7722a6819f37aa39033bd37a5a77880f193f8be550020320e87ce5becfa6e5bf
+DIST pax-utils-1.2.9.tar.xz 705188 BLAKE2B 9eb9309f0317683dd06e491e6647ba20986f2cb248432fad0ed0eb277711e8d38c5b5148bc0b44e6dbc3d5d3d0093bccd4d10c057090801c49246a63f3bc0899 SHA512 47271cd75818728342e2a074fa05da24fce51ef0eeedb28237138525d7c86c207ca2b5d206fd02cb34529590340b726a14c54b205c65204539a51fb78ac55d41
diff --git a/app-misc/pax-utils/pax-utils-1.2.9.ebuild b/app-misc/pax-utils/pax-utils-1.2.9.ebuild
new file mode 100644
index 000000000000..e7a257126c0c
--- /dev/null
+++ b/app-misc/pax-utils/pax-utils-1.2.9.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8,9} )
+
+inherit eutils python-single-r1 toolchain-funcs
+
+DESCRIPTION="ELF utils that can check files for security relevant properties"
+HOMEPAGE="https://wiki.gentoo.org/index.php?title=Project:Hardened/PaX_Utilities"
+SRC_URI="mirror://gentoo/${P}.tar.xz
+	https://dev.gentoo.org/~slyfox/distfiles/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="caps debug kernel_linux python seccomp"
+
+RDEPEND="caps? ( >=sys-libs/libcap-2.24 )
+	python? (
+		${PYTHON_DEPS}
+		$(python_gen_cond_dep '
+			dev-python/pyelftools[${PYTHON_MULTI_USEDEP}]
+		')
+	)
+	seccomp? ( sys-libs/libseccomp )
+"
+# >=linux-headers-4.11 to pick linux headers with statx, bug #737094
+DEPEND="
+	${RDEPEND}
+	kernel_linux? ( !prefix-guest? ( >=sys-kernel/linux-headers-4.11 ) )
+"
+BDEPEND="
+	caps? ( virtual/pkgconfig )
+	seccomp? ( virtual/pkgconfig )
+"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+_emake() {
+	emake \
+		USE_CAP=$(usex caps) \
+		USE_DEBUG=$(usex debug) \
+		USE_PYTHON=$(usex python) \
+		USE_SECCOMP=$(usex seccomp) \
+		"$@"
+}
+
+pkg_setup() {
+	if use python; then
+		python-single-r1_pkg_setup
+	fi
+}
+
+src_configure() {
+	# Avoid slow configure+gnulib+make if on an up-to-date Linux system
+	if use prefix || ! use kernel_linux ||
+		has_version '<sys-libs/glibc-2.10'
+	then
+		econf $(use_with caps) $(use_with debug) $(use_with python) $(use_with seccomp)
+	else
+		tc-export CC PKG_CONFIG
+	fi
+}
+
+src_compile() {
+	_emake
+}
+
+src_test() {
+	_emake check
+}
+
+src_install() {
+	_emake DESTDIR="${D}" PKGDOCDIR='$(DOCDIR)'/${PF} install
+
+	use python && python_fix_shebang "${ED}"/usr/bin/lddtree
+}