app-editors/ted: bump to EAPI 7

Fix unrecognized configure option --with-GTK in some directories
Adjust dependencies
Don't compress man page
Bugday 2021-04-03

Closes: https://bugs.gentoo.org/470652
Closes: https://bugs.gentoo.org/733734
Package-Manager: Portage-3.0.18, Repoman-3.0.3
Signed-off-by: Bernd Waibel <waebbl-gentoo@posteo.net>
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

1 files changed, 90 insertions, 0 deletions

diff --git a/app-editors/ted/ted-2.23-r1.ebuild b/app-editors/ted/ted-2.23-r1.ebuild
new file mode 100644
index 000000000000..d223c7a9fcd0
--- /dev/null
+++ b/app-editors/ted/ted-2.23-r1.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit toolchain-funcs xdg-utils
+
+DESCRIPTION="X-based rich text editor"
+HOMEPAGE="https://www.nllgg.nl/Ted/"
+SRC_URI="ftp://ftp.nluug.nl/pub/editors/ted/${P}.src.tar.gz"
+S="${WORKDIR}/Ted-${PV}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+
+RDEPEND="
+	app-text/libpaper
+	dev-libs/libpcre2
+	media-libs/fontconfig
+	media-libs/freetype
+	media-libs/libpng:=
+	media-libs/tiff:=
+	sys-libs/zlib
+	virtual/jpeg
+	virtual/libiconv
+	x11-libs/gtk+:2
+	x11-libs/libXft
+	x11-libs/libXpm
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	sys-apps/lsb-release
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-0001-pass-MAKE-to-subdir.patch
+	"${FILESDIR}"/${P}-0002-fix-unrecognized-option-with-GTK.patch
+	"${FILESDIR}"/${P}-0003-avoid-compressing-man-page.patch
+	"${FILESDIR}"/${P}-freetype261.patch
+)
+
+src_prepare() {
+	default
+
+	sed -i -e 's|/Ted/|/share/Ted/|' \
+		"${S}"/appFrame/appFrameConfig.h.in \
+		"${S}"/Ted/tedConfig.h.in || die
+
+	# bug #461256
+	find . -name makefile.in -exec sed -i -e '/ar r/s/ar/$(AR)/' {} \; || die
+
+	# force to build dynamic binary, do not strip it
+	sed -i \
+		-e 's/.static//g' \
+		-e '/strip/d' \
+		tedPackage/makefile.in || die 'sed failed on tedPackage/makefile.in'
+
+	# Fix build with freetype-2.5
+	sed -i "s|^\(#[ \t]*include[ \t]*<\)freetype/|\1|" appFrame/appFontConfig.c || die
+
+	mkdir lib || die
+}
+
+src_configure() {
+	tc-export AR CC RANLIB
+
+	local dir
+	for dir in appFrame appUtil bitmap docBuf ind Ted tedPackage; do
+		cd "${S}"/${dir}
+		econf --cache-file=../config.cache
+	done
+}
+
+src_compile() {
+	emake package.shared
+}
+
+src_install() {
+	default
+	dosym ../share/Ted/examples/rtf2pdf.sh /usr/bin/rtf2pdf.sh
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+}