app-doc/devmanual: New snapshot.

Package-Manager: Portage-2.3.85, Repoman-2.3.20
Signed-off-by: Ulrich Müller <ulm@gentoo.org>

3 files changed, 69 insertions, 1 deletions

diff --git a/app-doc/devmanual/Manifest b/app-doc/devmanual/Manifest
index 5c578f998d9f..e42a05bf9fc5 100644
--- a/app-doc/devmanual/Manifest
+++ b/app-doc/devmanual/Manifest
@@ -1 +1,2 @@
 DIST devmanual-0_pre20141116.tar.gz 169936 BLAKE2B 9b01004750b9fce226fa6a965292d3ffaff0923f877da611743e39ee19077ea7fe0d21ff138853d3f79e4d4941026c30fcabf63c8903572ed7ba5d50d32c8dd5 SHA512 6af3f9a262bdb2ceb61ab195691dff4a850b22e8d1226e20ae3257c566b6cc913f756c8b90a40e8aa78b1242e78d24c4209a1d9cdb0706ae9b64c653544a028f
+DIST devmanual-0_pre20200203.tar.xz 163740 BLAKE2B 39d8173bc524213e7a6e81def4f1631ea0d2503540551982d07ef58f414b8a052e8a3a0d2426b5864e06fb24f1745af4dea57e418fcc5e52c558dc1da9ff4530 SHA512 f3fce9ba557515b89c5a875dc1e4e968eb3097776842026403e41ebe972c2e4e764303c729c5835466faaa2675fa361fe7e0512d7a8222d7d8b1202a9049f98e
diff --git a/app-doc/devmanual/devmanual-0_pre20200203.ebuild b/app-doc/devmanual/devmanual-0_pre20200203.ebuild
new file mode 100644
index 000000000000..267f21183744
--- /dev/null
+++ b/app-doc/devmanual/devmanual-0_pre20200203.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit readme.gentoo-r1
+
+DESCRIPTION="The Gentoo Development Guide"
+HOMEPAGE="https://devmanual.gentoo.org/"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/devmanual.git"
+else
+	SRC_URI="https://dev.gentoo.org/~ulm/distfiles/${P}.tar.xz"
+	S="${WORKDIR}/${PN}"
+	KEYWORDS="~amd64 ~arm ~hppa ~m68k ~mips ~s390 ~sh ~sparc ~x86 ~x64-macos"
+fi
+
+LICENSE="CC-BY-SA-4.0"
+SLOT="0"
+IUSE="+offline"
+
+BDEPEND="dev-libs/libxml2
+	dev-libs/libxslt
+	gnome-base/librsvg
+	media-fonts/open-sans"
+
+PATCHES=( "${FILESDIR}"/${PN}-eclasses.patch )
+
+src_compile() {
+	emake build OFFLINE=$(usex offline 1 0)
+	use offline || emake documents.js
+}
+
+src_install() {
+	# clean out XML/XSL before installing
+	find . \( \
+		-iname '*.xml' -o \
+		-iname '*.dtd' -o \
+		-iname '*.xsl' -o \
+		-iname '*.svg' \) -delete || die
+	rm -r bin xsl .git* LICENSE Makefile README.md || die
+
+	local HTML_DOCS=( . )
+	einstalldocs
+
+	einfo "Creating symlink from ${PF} to ${PN} for preserving bookmarks"
+	dosym ${PF} /usr/share/doc/${PN}
+
+	local DOC_CONTENTS="In order to browse the Gentoo Development Guide in
+		offline mode, point your browser to the following url:
+		file://${EPREFIX}/usr/share/doc/${PN}/html/index.html"
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
+	if ! has_version app-doc/eclass-manpages; then
+		elog "The offline version of the devmanual does not include the"
+		elog "documentation for the eclasses. If you need it, then emerge"
+		elog "the following package:"
+		elog
+		elog "app-doc/eclass-manpages"
+	fi
+}
diff --git a/app-doc/devmanual/devmanual-9999.ebuild b/app-doc/devmanual/devmanual-9999.ebuild
index bb8f0ecfc78d..5c7bbf8ec0a4 100644
--- a/app-doc/devmanual/devmanual-9999.ebuild
+++ b/app-doc/devmanual/devmanual-9999.ebuild
@@ -12,7 +12,8 @@ if [[ ${PV} == *9999 ]]; then
 	inherit git-r3
 	EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/devmanual.git"
 else
-	SRC_URI="https://dev.gentoo.org/~hwoarang/distfiles/${P}.tar.gz"
+	SRC_URI="https://dev.gentoo.org/~ulm/distfiles/${P}.tar.xz"
+	S="${WORKDIR}/${PN}"
 	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x64-macos"
 fi