app-crypt/acme-tiny: Urgent version bump 4.1.0

LetsEncrypt will be ending support for all versions older than 4.1.0 on
Nov 1st 2020.

Any server that has been using acme-tiny to automatically renew certificates
will fail to issue new certificates in 3 days.

https://community.letsencrypt.org/t/acme-v2-scheduled-deprecation-of-unauthenticated-resource-gets/74380

Package-Manager: Portage-3.0.8, Repoman-3.0.1
Signed-off-by: Anthony Ryan <anthonyryan1@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/18061
Signed-off-by: Adam Feldman <NP-Hardass@gentoo.org>

1 files changed, 47 insertions, 0 deletions

diff --git a/app-crypt/acme-tiny/acme-tiny-4.1.0.ebuild b/app-crypt/acme-tiny/acme-tiny-4.1.0.ebuild
new file mode 100644
index 000000000000..a1911edadfdc
--- /dev/null
+++ b/app-crypt/acme-tiny/acme-tiny-4.1.0.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python{3_6,3_7,3_8,3_9} )
+inherit distutils-r1
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/diafygi/${PN}.git"
+else
+	SRC_URI="https://github.com/diafygi/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="A tiny, auditable script for Let's Encrypt's ACME Protocol"
+HOMEPAGE="https://github.com/diafygi/acme-tiny"
+
+LICENSE="MIT"
+SLOT="0"
+IUSE=""
+
+DEPEND="dev-python/setuptools_scm[${PYTHON_USEDEP}]"
+RDEPEND="dev-libs/openssl:0"
+
+pkg_setup() {
+	if [[ ${PV} != 9999 ]]; then
+		export SETUPTOOLS_SCM_PRETEND_VERSION="${PV}"
+	fi
+}
+
+src_prepare() {
+	sed -i 's|#!/usr/bin/sh|#!/bin/sh|g' README.md || die
+
+	distutils-r1_src_prepare
+}
+
+pkg_postinst() {
+	for v in ${REPLACING_VERSIONS}; do
+		if ver_test "$v" "-lt" "4.0.3" || ver_test "$v" "-ge" "9999"; then
+			einfo "The --account-email flag has been changed to --contact and"
+			einfo "has different syntax."
+			einfo "Please update your scripts accordingly"
+		fi
+	done
+}