app-benchmarks/filebench: eapi bump, add new use flag, fix dependencies

The following changes have been made:
- eapi bump to EAPI 6
- drop unused inherit eutils
- remove unsued dependency on libaio: the program uses the aio functions
  defined in libc. libaio is not referenced in the source code.
- remove the automagic dependency on dev-libs/libtecla: filebench
  provides tab-completion support using libtecla. However, there's no
  way to explicitly control it. Patch the sources to add a configure
  option for '--with-libtecla' and add a corresponding USE flag called
  'auto-completion'.
- drop parallel compilation workaround: the package compiles with
  different values of '-j' successfully. Most likely a carry-over from
  the initial ebuild.

Package-Manager: portage-2.2.26

1 files changed, 35 insertions, 0 deletions

diff --git a/app-benchmarks/filebench/filebench-1.4.9.1-r1.ebuild b/app-benchmarks/filebench/filebench-1.4.9.1-r1.ebuild
new file mode 100644
index 000000000000..f3ba307cd34a
--- /dev/null
+++ b/app-benchmarks/filebench/filebench-1.4.9.1-r1.ebuild
@@ -0,0 +1,35 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit autotools
+
+DESCRIPTION="Filebench - A Model Based File System Workload Generator"
+HOMEPAGE="http://sourceforge.net/projects/filebench/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="CDDL"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="auto-completion"
+
+RDEPEND="
+	auto-completion? ( dev-libs/libtecla )
+"
+DEPEND="${RDEPEND}
+	sys-devel/flex
+	sys-devel/bison
+"
+
+PATCHES=( "${FILESDIR}"/${PN}-fix-automagic-libtecla-dependency.patch )
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf $(use_with auto-completion libtecla)
+}