app-admin/cancd: migrate to GLEP 81

Also updated to EAPI 7.

Closes: https://bugs.gentoo.org/781194
Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Conrad Kostecki <conikost@gentoo.org>

1 files changed, 39 insertions, 0 deletions

diff --git a/app-admin/cancd/cancd-0.1.0-r5.ebuild b/app-admin/cancd/cancd-0.1.0-r5.ebuild
new file mode 100644
index 000000000000..e821470d9562
--- /dev/null
+++ b/app-admin/cancd/cancd-0.1.0-r5.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="CA NetConsole Daemon receives output from the Linux netconsole driver"
+HOMEPAGE="http://oss.oracle.com/projects/cancd/"
+SRC_URI="http://oss.oracle.com/projects/cancd/dist/files/source/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+PATCHES=(
+	"${FILESDIR}/${P}-build-r1.patch"
+	"${FILESDIR}/${P}-c-cleanup.patch"
+)
+
+RDEPEND="acct-user/cancd"
+
+src_prepare() {
+	default
+
+	# slight makefile cleanup
+	sed \
+		-e '/^CFLAGS/s,-g,,' \
+		-e '/^CFLAGS/s,-O2,-Wall -W -Wextra -Wundef -Wendif-labels -Wshadow -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Wconversion -Wsign-compare -Waggregate-return -Wstrict-prototypes -Wredundant-decls -Wunreachable-code -Wlong-long,' \
+		-e '/rm cancd cancd.o/s,rm,rm -f,' \
+		-i Makefile || die
+}
+
+src_install() {
+	dosbin cancd
+
+	newinitd "${FILESDIR}"/cancd-init.d-r1 cancd
+	newconfd "${FILESDIR}"/cancd-conf.d-r1 cancd
+	newinitd "${FILESDIR}"/netconsole-init.d netconsole
+	newconfd "${FILESDIR}"/netconsole-conf.d netconsole
+}