net-im/telegram-desktop: bump to 1.9.9

make installable with old QT

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Georgy Yakovlev <gyakovlev@gentoo.org>

2 files changed, 148 insertions, 0 deletions

diff --git a/net-im/telegram-desktop/Manifest b/net-im/telegram-desktop/Manifest
index 33d52dd8916e..bc46d2599993 100644
--- a/net-im/telegram-desktop/Manifest
+++ b/net-im/telegram-desktop/Manifest
@@ -1 +1,2 @@
 DIST tdesktop-1.9.8-full.tar.gz 25225784 BLAKE2B d938dc5d82740f93c575f621697e4bae430dc045c18437957bead6cc949ad0643b0422d8fd2a1695af921ea7f259ca323094a4a7821855d842edfaf4f328c840 SHA512 5562eb99812a8faec74fe073323d6e04e36311c1e4ce984035212ecfed8bd5d12df92cd0f0022401201136315fb5556971b267b4bf47edf4eeddc9926c7969dc
+DIST tdesktop-1.9.9-full.tar.gz 25221934 BLAKE2B c8f6252fd6e72785a39c92f04e5dadf322775fc1a178f2c6dac9e38cb654b9eb924c16cffcf9dc47e2e309e4f27a13ea07235146e7d7960b6bd0a342a3645e03 SHA512 ba6400e6f5eec5bda6e8a54b43846e695b2cce731cb6b39f17407cc39e3e9b8078d977253d29962671f30e33dbe012f8e40f340f781fd8ca73487e5f2d42e3de
diff --git a/net-im/telegram-desktop/telegram-desktop-1.9.9.ebuild b/net-im/telegram-desktop/telegram-desktop-1.9.9.ebuild
new file mode 100644
index 000000000000..df6aae216740
--- /dev/null
+++ b/net-im/telegram-desktop/telegram-desktop-1.9.9.ebuild
@@ -0,0 +1,147 @@
+# Copyright 2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7} )
+
+inherit cmake desktop flag-o-matic python-any-r1 xdg-utils
+
+MY_P="tdesktop-${PV}-full"
+
+DESCRIPTION="Official desktop client for Telegram"
+HOMEPAGE="https://desktop.telegram.org"
+SRC_URI="https://github.com/telegramdesktop/tdesktop/releases/download/v${PV}/${MY_P}.tar.gz"
+
+LICENSE="GPL-3-with-openssl-exception Unlicense"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64"
+IUSE="dbus gtk3 libressl spell"
+
+RDEPEND="!net-im/telegram-desktop-bin
+	app-arch/lz4
+	app-arch/xz-utils
+	!libressl? ( dev-libs/openssl:0= )
+	libressl? ( dev-libs/libressl:0= )
+	dev-libs/range-v3
+	dev-libs/xxhash
+	dev-qt/qtcore:5
+	dev-qt/qtimageformats:5
+	dev-qt/qtnetwork:5
+	media-libs/openal[pulseaudio]
+	media-libs/opus
+	media-sound/pulseaudio
+	sys-libs/zlib[minizip]
+	virtual/ffmpeg
+	x11-libs/libva[X,drm]
+	x11-libs/libX11
+	|| (
+		dev-qt/qtgui:5[png,X(-)]
+		dev-qt/qtgui:5[png,xcb(-)]
+	)
+	|| (
+		dev-qt/qtwidgets:5[png,X(-)]
+		dev-qt/qtwidgets:5[png,xcb(-)]
+	)
+	dbus? ( dev-qt/qtdbus:5 )
+	gtk3? (
+		dev-libs/libappindicator:3
+		x11-libs/gtk+:3
+	)
+	spell? ( app-text/enchant )
+"
+
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}"
+
+BDEPEND="
+	>=dev-util/cmake-3.16
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	"${FILESDIR}/0002-PPC-big-endian.patch"
+	"${FILESDIR}/0003-PPC-config.patch"
+	"${FILESDIR}/musl.patch"
+)
+
+S="${WORKDIR}/${MY_P}"
+
+src_configure() {
+	local mycxxflags=(
+		-Wno-deprecated-declarations
+		-Wno-error=deprecated-declarations
+		-Wno-switch
+	)
+
+	append-cxxflags "${mycxxflags[@]}"
+
+	local mycmakeargs=(
+		-Ddisable_autoupdate=1
+		-DDESKTOP_APP_DISABLE_CRASH_REPORTS=ON
+		-DDESKTOP_APP_USE_GLIBC_WRAPS=OFF
+		-DDESKTOP_APP_USE_PACKAGED=ON
+		-DDESKTOP_APP_USE_PACKAGED_RLOTTIE=OFF
+		-DTDESKTOP_DISABLE_DESKTOP_FILE_GENERATION=ON
+		-DTDESKTOP_LAUNCHER_BASENAME="${PN}"
+		-DTDESKTOP_USE_PACKAGED_TGVOIP=OFF
+		-DDESKTOP_APP_DISABLE_SPELLCHECK="$(usex spell OFF ON)"
+		-DTDESKTOP_DISABLE_GTK_INTEGRATION="$(usex gtk3 OFF ON)"
+		-DTDESKTOP_DISABLE_DBUS_INTEGRATION="$(usex dbus OFF ON)"
+		-DTDESKTOP_FORCE_GTK_FILE_DIALOG="$(usex gtk3)"
+	)
+
+	if [[ -n ${MY_TDESKTOP_API_ID} && -n ${MY_TDESKTOP_API_HASH} ]]; then
+		einfo "Found custom API credentials"
+		mycmakeargs+=(
+			-DTDESKTOP_API_ID="${MY_TDESKTOP_API_ID}"
+			-DTDESKTOP_API_HASH="${MY_TDESKTOP_API_HASH}"
+		)
+	else
+		mycmakeargs+=( -DTDESKTOP_API_TEST=ON )
+		ewarn
+		ewarn "Building ${PN} with test API credentials."
+		ewarn "Connectivity to API servers will be throttled."
+		ewarn "To build ${PN} custom API credentials cancel build now and obtain"
+		ewarn "credentials here: https://github.com/telegramdesktop/tdesktop/blob/dev/docs/api_credentials.md"
+		ewarn "After getting credentials you can export variables:"
+		ewarn "export MY_TDESKTOP_API_ID=\"17349\""
+		ewarn "export MY_TDESKTOP_API_HASH=\"344583e45741c457fe1862106095a5eb\""
+		ewarn "and restart the build"
+		ewarn "you can save variables in /etc/portage/env/${CATEGORY}/${PN}"
+		ewarn "portage will use the file every build automatically"
+		ewarn
+	fi
+
+	cmake_src_configure
+}
+
+src_install() {
+	dobin "${BUILD_DIR}/bin/${PN}"
+
+	newmenu lib/xdg/telegramdesktop.desktop "${PN}.desktop"
+
+	local icon_size
+	for icon_size in 16 32 48 64 128 256 512
+	do
+		newicon -s ${icon_size} \
+			Telegram/Resources/art/icon${icon_size}.png telegram.png
+	done
+
+	insinto /usr/share/appdata
+	doins lib/xdg/telegramdesktop.appdata.xml
+
+	einstalldocs
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+}