dev-python/cython: Bump to 0.29.5

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 87 insertions, 0 deletions

diff --git a/dev-python/cython/Manifest b/dev-python/cython/Manifest
index 6e8e87204a09..52c320b853a9 100644
--- a/dev-python/cython/Manifest
+++ b/dev-python/cython/Manifest
@@ -4,3 +4,4 @@ DIST Cython-0.28.4.tar.gz 1880943 BLAKE2B a97314147294c95fa0bd6d3fa1a1315d81f8ab
 DIST Cython-0.29.2.tar.gz 2041500 BLAKE2B 9edf4297e55b5de438fb79bdbfb4b1468af8b72e5556b38b9349b84fd9b917a56bc295b11e2c8938984fbd47099d4938450fac225c94687c1b3dab2749f72232 SHA512 d553dbb35b0841ca64d03fae3157e3a46248f16f14a1b75bbae979ca74a5fa89f85fa254a442a34314fe385d0aef7afa8c75b7f82662b37f7eeccd82e1404603
 DIST Cython-0.29.3.tar.gz 2042466 BLAKE2B 6ea5b59d99875c65afb041b8ea091d7d5b191504bcbe247eb770d5696607b69df6c3565235fdb523824629011058eec22417ea0c0a1031c30876170559add4d7 SHA512 b23a8a1a05f40ad69c740b93d5372e920ab69f586d5109b119d9c4d72a3d95fa4f9ecb13a4f18bc93b474d385b5c8db002dd1ffe03e5b040612958556283a940
 DIST Cython-0.29.4.tar.gz 2044382 BLAKE2B b36d27706a3270805f66190a4cf2735eaf20b1b932365b324a433c0e58e63e860ce1500333233c3539ae697886ac0adc361a2c158d5d064a3ea05843debc3f26 SHA512 8f115e36975aaf64eda4df8b0a85378d0c80b3292dbd162be826b939def03bdc9f3eb937676e2367003c2944b570d97f50d7880becfdb2fdc5144077b4a722dc
+DIST Cython-0.29.5.tar.gz 2045488 BLAKE2B ca809728115865b7d28100943b358d8f5236382e5ae5a43d557620c3bd856407a9f52b756fc910564a6c041d64b1439d60776c90c6970614f74ee2d03f94665f SHA512 4bbf54b248b9a08b9118d751a6bb5dbb81ae7a8238c8a3124d94bf7be67f15b68820e6ce5470903fb5d5ff5c3c213e1580f1c57a8cda33b356263f9ab46e8851
diff --git a/dev-python/cython/cython-0.29.5.ebuild b/dev-python/cython/cython-0.29.5.ebuild
new file mode 100644
index 000000000000..dac33af59699
--- /dev/null
+++ b/dev-python/cython/cython-0.29.5.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6,7} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 toolchain-funcs elisp-common
+
+MY_PN="Cython"
+MY_P="${MY_PN}-${PV/_/}"
+
+DESCRIPTION="A Python to C compiler"
+HOMEPAGE="http://cython.org https://pypi.org/project/Cython/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris ~x86-solaris"
+
+IUSE="doc emacs test"
+
+RDEPEND="
+	emacs? ( virtual/emacs )
+"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( dev-python/numpy[${PYTHON_USEDEP}] )"
+
+SITEFILE=50cython-gentoo.el
+S="${WORKDIR}/${MY_PN}-${PV%_*}"
+
+python_prepare_all() {
+	# tests behavior that is illegal in Python 3.7+
+	# https://github.com/cython/cython/issues/2454
+	sed -i -e '/with_outer_raising/,/return/d' tests/run/generators_py.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile() {
+	if ! python_is_python3; then
+		local CFLAGS="${CFLAGS} -fno-strict-aliasing"
+		local CXXFLAGS="${CXXFLAGS} -fno-strict-aliasing"
+	fi
+
+	# Python gets confused when it is in sys.path before build.
+	local -x PYTHONPATH=
+
+	distutils-r1_python_compile
+}
+
+python_compile_all() {
+	use emacs && elisp-compile Tools/cython-mode.el
+
+	use doc && emake -C docs html
+}
+
+python_test() {
+	tc-export CC
+	# https://github.com/cython/cython/issues/1911
+	local -x CFLAGS="${CFLAGS} -fno-strict-overflow"
+	"${PYTHON}" runtests.py -vv --work-dir "${BUILD_DIR}"/tests \
+		|| die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	local DOCS=( CHANGES.rst README.rst ToDo.txt USAGE.txt )
+	use doc && local HTML_DOCS=( docs/build/html/. )
+	distutils-r1_python_install_all
+
+	if use emacs; then
+		elisp-install ${PN} Tools/cython-mode.*
+		elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+	fi
+}
+
+pkg_postinst() {
+	use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}