media-libs/vulkan-layers: Version bump to 1.3.280.0

Signed-off-by: Matt Turner <mattst88@gentoo.org>

2 files changed, 61 insertions, 0 deletions

diff --git a/media-libs/vulkan-layers/Manifest b/media-libs/vulkan-layers/Manifest
index c8c1a8ecdbb7..0b9f67d89451 100644
--- a/media-libs/vulkan-layers/Manifest
+++ b/media-libs/vulkan-layers/Manifest
@@ -1 +1,2 @@
 DIST vulkan-layers-1.3.275.tar.gz 5280585 BLAKE2B a9707dc18c4802b1f6fd851ec7b16201035c1809c7e42fcd2d3f08dd7de162a18ee240f9269e233a67c93b49bd69f3babda73265bb9ac343e2924b19fa6288dd SHA512 755bdde7e7129b7a3ed06a4bebdaf11212288802119e0dc224aab63491de30c9b1c25972bdafd4fedbfea43bf6c29cdbc409374e57fbf0331798530a8ae94a70
+DIST vulkan-layers-1.3.280.0.tar.gz 5465068 BLAKE2B c0b568b59cb8a17bea7dd1c1522c0a72279ad6a07f2f11383bc069f141fbb179529dd4ccd34b2a7a9a9a4af0e173ebbc49541a42c2b32ea8b54d90302f7ee449 SHA512 b397d4aa5406e25eb241a72f006fb05554d8ec96eec4c31ed08ef34d0b362f8e544a2e8bcf044112bdbb2733f2a9f50bf8b63aff64e143e450fa01298dc7838a
diff --git a/media-libs/vulkan-layers/vulkan-layers-1.3.280.0.ebuild b/media-libs/vulkan-layers/vulkan-layers-1.3.280.0.ebuild
new file mode 100644
index 000000000000..8e97234b84e0
--- /dev/null
+++ b/media-libs/vulkan-layers/vulkan-layers-1.3.280.0.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN=Vulkan-ValidationLayers
+PYTHON_COMPAT=( python3_{10..12} )
+inherit cmake-multilib python-any-r1
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://github.com/KhronosGroup/${MY_PN}.git"
+	EGIT_SUBMODULES=()
+	inherit git-r3
+else
+	SRC_URI="https://github.com/KhronosGroup/${MY_PN}/archive/vulkan-sdk-${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+	S="${WORKDIR}"/${MY_PN}-vulkan-sdk-${PV}
+fi
+
+DESCRIPTION="Vulkan Validation Layers"
+HOMEPAGE="https://github.com/KhronosGroup/Vulkan-ValidationLayers"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="wayland X"
+
+RDEPEND="~dev-util/spirv-tools-${PV}:=[${MULTILIB_USEDEP}]"
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+	>=dev-cpp/robin-hood-hashing-3.11.5
+	~dev-util/glslang-${PV}:=[${MULTILIB_USEDEP}]
+	~dev-util/spirv-headers-${PV}
+	~dev-util/vulkan-headers-${PV}
+	~dev-util/vulkan-utility-libraries-${PV}:=[${MULTILIB_USEDEP}]
+	wayland? ( dev-libs/wayland:=[${MULTILIB_USEDEP}] )
+	X? (
+		x11-libs/libX11:=[${MULTILIB_USEDEP}]
+		x11-libs/libXrandr:=[${MULTILIB_USEDEP}]
+	)
+"
+
+QA_SONAME="/usr/lib[^/]*/libVkLayer_khronos_validation.so"
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_C_FLAGS="${CFLAGS} -DNDEBUG"
+		-DCMAKE_CXX_FLAGS="${CXXFLAGS} -DNDEBUG"
+		-DCMAKE_SKIP_RPATH=ON
+		-DBUILD_WERROR=OFF
+		-DBUILD_WSI_WAYLAND_SUPPORT=$(usex wayland)
+		-DBUILD_WSI_XCB_SUPPORT=$(usex X)
+		-DBUILD_WSI_XLIB_SUPPORT=$(usex X)
+		-DBUILD_TESTS=OFF
+	)
+	cmake_src_configure
+}
+
+multilib_src_install_all() {
+	find "${ED}" -type f -name \*.a -delete || die
+}