Merge remote-tracking branch 'github/pr/753'.

Signed-off-by: Patrice Clement <monsieurp@gentoo.org>

3 files changed, 115 insertions, 8 deletions

diff --git a/media-sound/flacon/Manifest b/media-sound/flacon/Manifest
index 01230669937f..b746790f5b7e 100644
--- a/media-sound/flacon/Manifest
+++ b/media-sound/flacon/Manifest
@@ -1 +1,2 @@
 DIST flacon-1.2.0.tar.gz 283187 SHA256 2ebc83d733ea6d50f2bd4ad8c20c65368be5eaf351e0195c9b4d47a54957b8f8 SHA512 4cc64467350c941eed16299a562ddc3c6c83d785dddffe6825e3df50a988ce9494517b3ea862d90398110564ec3f828ef6760a6c02d24163f9247930330a3b6d WHIRLPOOL 918926069daaf5e9a16711d641c873a70d1dc97f04b05387f649f1d1d6e1d652f3e676f1100d5fe0d70d03fa9edb1d4e64fc67b489f5c5e74d21108a437f87ea
+DIST flacon-2.0.1.tar.gz 317356 SHA256 3408304e7ab524a2e8a621ea780579e1be7b3359fefe7d37a1b88f34d6120e02 SHA512 d095880f4aba0d528fb03a860aef6cb818af7fea52642db4a42ed26a1e5bf412d6fb8bff604e148a885ac661275fcc43966b3f56fea133e6acb3ccea15fe5f2c WHIRLPOOL e1c95430473616d79396fa42a7d9c8e4e6ac92ccd32e2c74e185e164607f61faeeb59743c052a93fb140a77e3a0b40738716bbe5e2efdae5ae6a99aae693ae9a
diff --git a/media-sound/flacon/flacon-2.0.1.ebuild b/media-sound/flacon/flacon-2.0.1.ebuild
new file mode 100644
index 000000000000..a070f628ea0c
--- /dev/null
+++ b/media-sound/flacon/flacon-2.0.1.ebuild
@@ -0,0 +1,95 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+# Ignore rudimentary et, uz@Latn, zh_TW translation(s)
+PLOCALES="cs_CZ cs de es_MX es fr gl hu it ja_JP lt nb pl_PL pl pt_BR pt_PT ro_RO ru sr tr uk zh_CN"
+
+inherit cmake-utils fdo-mime gnome2-utils l10n virtualx
+
+DESCRIPTION="Extracts audio tracks from an audio CD image to separate tracks"
+HOMEPAGE="https://flacon.github.io/"
+SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="aac flac mac mp3 opus qt4 qt5 replaygain test tta vorbis wavpack"
+
+COMMON_DEPEND="
+	dev-libs/uchardet
+	qt4? (
+		dev-qt/qtcore:4
+		dev-qt/qtgui:4
+	)
+	qt5? (
+		dev-qt/linguist-tools:5
+		dev-qt/qtnetwork:5
+		dev-qt/qtwidgets:5
+	)
+"
+RDEPEND="${COMMON_DEPEND}
+	media-sound/shntool[mac?]
+	aac? ( media-libs/faac )
+	flac? ( media-libs/flac )
+	mac? ( media-sound/mac )
+	mp3? ( media-sound/lame )
+	opus? ( media-sound/opus-tools )
+	replaygain? (
+		mp3? ( media-sound/mp3gain )
+		vorbis? ( media-sound/vorbisgain )
+	)
+	tta? ( media-sound/ttaenc )
+	vorbis? ( media-sound/vorbis-tools )
+	wavpack? ( media-sound/wavpack )
+"
+DEPEND="${COMMON_DEPEND}
+	virtual/pkgconfig
+"
+
+REQUIRED_USE="^^ ( qt4 qt5 )"
+
+src_prepare() {
+	# Ignore rudimentary et, uz@Latn, zh_TW translation(s)
+	rm "translations/${PN}_uz@Latn.desktop" || die
+	rm "translations/${PN}"_{et,zh_TW}.ts || die
+
+	remove_locale() {
+		rm "translations/${PN}_${1}".{ts,desktop} || die
+	}
+
+	l10n_find_plocales_changes 'translations' "${PN}_" '.ts'
+	l10n_for_each_disabled_locale_do remove_locale
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DUSE_QT4="$(usex qt4)"
+		-DUSE_QT5="$(usex qt5)"
+		-DTEST_DATA_DIR="${S}/tests/data/"
+		-DBUILD_TESTS="$(usex test 'Yes')"
+	)
+	cmake-utils_src_configure
+}
+
+src_test() {
+	virtx "${BUILD_DIR}/tests/${PN}_test"
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+	gnome2_icon_cache_update
+}
diff --git a/media-sound/flacon/flacon-9999.ebuild b/media-sound/flacon/flacon-9999.ebuild
index 82dbb725e273..62c6a2ae712c 100644
--- a/media-sound/flacon/flacon-9999.ebuild
+++ b/media-sound/flacon/flacon-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2015 Gentoo Foundation
+# Copyright 1999-2016 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 # $Id$
 
@@ -7,7 +7,7 @@ EAPI=5
 # Ignore rudimentary et, uz@Latn, zh_TW translation(s)
 PLOCALES="cs_CZ cs de es_MX es fr gl hu it ja_JP lt nb pl_PL pl pt_BR pt_PT ro_RO ru sr tr uk zh_CN"
 
-inherit cmake-utils fdo-mime gnome2-utils l10n git-r3
+inherit cmake-utils fdo-mime gnome2-utils l10n virtualx git-r3
 
 DESCRIPTION="Extracts audio tracks from an audio CD image to separate tracks"
 HOMEPAGE="https://flacon.github.io/"
@@ -16,9 +16,9 @@ EGIT_REPO_URI="git://github.com/${PN}/${PN}.git"
 LICENSE="LGPL-2.1"
 SLOT="0"
 KEYWORDS=""
-IUSE="aac flac mac mp3 opus qt4 qt5 replaygain tta vorbis wavpack"
+IUSE="aac flac mac mp3 opus qt4 qt5 replaygain test tta vorbis wavpack"
 
-DEPEND="
+COMMON_DEPEND="
 	dev-libs/uchardet
 	qt4? (
 		dev-qt/qtcore:4
@@ -30,7 +30,7 @@ DEPEND="
 		dev-qt/qtwidgets:5
 	)
 "
-RDEPEND="${DEPEND}
+RDEPEND="${COMMON_DEPEND}
 	media-sound/shntool[mac?]
 	aac? ( media-libs/faac )
 	flac? ( media-libs/flac )
@@ -45,6 +45,9 @@ RDEPEND="${DEPEND}
 	vorbis? ( media-sound/vorbis-tools )
 	wavpack? ( media-sound/wavpack )
 "
+DEPEND="${COMMON_DEPEND}
+	virtual/pkgconfig
+"
 
 REQUIRED_USE="^^ ( qt4 qt5 )"
 
@@ -54,21 +57,29 @@ src_prepare() {
 	rm "translations/${PN}"_{et,zh_TW}.ts || die
 
 	remove_locale() {
-		rm "translations/${PN}_${1}."{ts,desktop} || die
+		rm "translations/${PN}_${1}".{ts,desktop} || die
 	}
 
 	l10n_find_plocales_changes 'translations' "${PN}_" '.ts'
 	l10n_for_each_disabled_locale_do remove_locale
+
+	cmake-utils_src_prepare
 }
 
 src_configure() {
 	local mycmakeargs=(
-		$(cmake-utils_use_use qt4 QT4)
-		$(cmake-utils_use_use qt5 QT5)
+		-DUSE_QT4="$(usex qt4)"
+		-DUSE_QT5="$(usex qt5)"
+		-DTEST_DATA_DIR="${S}/tests/data/"
+		-DBUILD_TESTS="$(usex test 'Yes')"
 	)
 	cmake-utils_src_configure
 }
 
+src_test() {
+	virtx "${BUILD_DIR}/tests/${PN}_test"
+}
+
 pkg_preinst() {
 	gnome2_icon_savelist
 }