blob: 30e0fda31608a455f86da007106e614a01848950 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
# Copyright 2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit cmake xdg
DESCRIPTION="Set of libraries for building Wayland based shells"
HOMEPAGE="https://mir-server.io/"
SRC_URI="https://github.com/canonical/mir/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="|| ( GPL-2 GPL-3 ) || ( LGPL-2.1 LGPL-3 )"
SLOT="0"
KEYWORDS="~amd64"
IUSE="examples test"
RESTRICT="!test? ( test )"
RDEPEND="
dev-cpp/libxmlpp:2.6
dev-cpp/yaml-cpp:=
dev-libs/boost:=
dev-libs/glib:2
dev-libs/libinput:=
dev-libs/wayland
dev-util/lttng-ust:=
media-libs/freetype
media-libs/libepoxy
media-libs/libglvnd
media-libs/mesa
x11-libs/libdrm
x11-libs/libXcursor
x11-libs/libxcb:=
x11-libs/libxkbcommon
"
DEPEND="
${RDEPEND}
media-libs/glm
"
BDEPEND="
dev-util/gdbus-codegen
virtual/pkgconfig
examples? ( dev-util/wayland-scanner )
test? (
dev-cpp/gtest
dev-util/umockdev
x11-base/xwayland
)
"
src_prepare() {
cmake_src_prepare
use examples || cmake_comment_add_subdirectory examples/
}
src_configure() {
local mycmakeargs=(
# wlcs is not packaged
-DMIR_ENABLE_WLCS_TESTS=OFF
-DMIR_ENABLE_TESTS="$(usex test)"
)
use test && mycmakeargs+=(
# likely will not work in build environment
-DMIR_BUILD_PERFORMANCE_TESTS=OFF
-DMIR_BUILD_PLATFORM_TEST_HARNESS=OFF
-DMIR_BUILD_UNIT_TESTS=OFF
)
cmake_src_configure
}
src_install() {
cmake_src_install
if use test; then
# remove dummy libraries
rm -f "${ED}/usr/$(get_libdir)/mir/server-platform/"{graphics-dummy.so,input-stub.so} || die
fi
}
|
GitWeb