app-text/komikku: add 1.38.1

Signed-off-by: Takuya Wakazono <pastalian46@gmail.com>

2 files changed, 95 insertions, 0 deletions

diff --git a/app-text/komikku/Manifest b/app-text/komikku/Manifest
index e0b54da25..b33cd0ea3 100644
--- a/app-text/komikku/Manifest
+++ b/app-text/komikku/Manifest
@@ -1 +1,2 @@
 DIST komikku-1.37.1.tar.gz 3837412 BLAKE2B f89eb63842808e6cfe7c02f7b3053669754cff7aedba709d51917f19baff8473af7464460d587b90574a459c3bf99533ccf5d08d6227ee17847a9fd6450d36fe SHA512 72b7352e2d57c0e68f0203a6aa98aa355346c75f6278bac22e16ecad1631fcc64338441865428d36438698d384dbd7cd1aeaab5257466ccc5fbde9ea73e336dd
+DIST komikku-1.38.1.tar.gz 3687317 BLAKE2B 2a99f57c82b8d348fc6c5c67adbab59974635d41f843edf1060d68a3a2e81ec95db8e41140039eb57346a8fd9256904ebf20010c772530bf31f4ced4042cb7b5 SHA512 c229948bad4d2b070c94e8ad3b137a465752399f86cb8927e29f06a41e2509bde613326b6d586b7c883afee5d0a4c20b99697a558c980fa5ebd3f28cfc136294
diff --git a/app-text/komikku/komikku-1.38.1.ebuild b/app-text/komikku/komikku-1.38.1.ebuild
new file mode 100644
index 000000000..35c06d295
--- /dev/null
+++ b/app-text/komikku/komikku-1.38.1.ebuild
@@ -0,0 +1,94 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+PYTHON_REQ_USE="sqlite(+),ssl(+)"
+DISTUTILS_USE_PEP517=no
+DISTUTILS_SINGLE_IMPL=1
+inherit distutils-r1 meson gnome2-utils xdg
+
+DESCRIPTION="Manga reader for GNOME"
+HOMEPAGE="https://apps.gnome.org/Komikku/"
+SRC_URI="https://codeberg.org/valos/Komikku/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}"
+
+KEYWORDS="~amd64"
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE="test"
+
+RESTRICT="test"
+# Depend on a random server that may or may not be accessible at all times.
+#PROPERTIES="test_network"
+
+DEPEND="
+	dev-libs/glib:2
+	dev-libs/gobject-introspection
+	>=gui-libs/gtk-4.12.1:4
+	>=gui-libs/libadwaita-1.4:1[introspection]
+	net-libs/webkit-gtk:6[introspection]
+"
+RDEPEND="
+	${DEPEND}
+	x11-libs/libnotify[introspection]
+	$(python_gen_cond_dep '
+		app-arch/brotli[python,${PYTHON_USEDEP}]
+		dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+		dev-python/colorthief[${PYTHON_USEDEP}]
+		dev-python/cryptography[${PYTHON_USEDEP}]
+		dev-python/dateparser[${PYTHON_USEDEP}]
+		dev-python/emoji[${PYTHON_USEDEP}]
+		dev-python/keyring[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/natsort[${PYTHON_USEDEP}]
+		dev-python/piexif[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/pure-protobuf[${PYTHON_USEDEP}]
+		dev-python/pygobject[${PYTHON_USEDEP}]
+		dev-python/python-magic[${PYTHON_USEDEP}]
+		dev-python/rarfile[compressed,${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/unidecode[${PYTHON_USEDEP}]
+	')
+"
+BDEPEND="
+	dev-util/blueprint-compiler
+	sys-devel/gettext
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/pytest-steps[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# fix broken shebang
+	sed "s|py_installation.full_path()|'${PYTHON}'|" -i bin/meson.build || die
+}
+
+src_test() {
+	emake setup
+	emake develop
+	emake test
+}
+
+src_install() {
+	meson_src_install
+	python_optimize
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+	xdg_pkg_postinst
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+	xdg_pkg_postrm
+}