x11-wm/metacity/metacity-2.12.2.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-wm/metacity/metacity-2.12.2.ebuild,v 1.2 2005/12/13 22:45:02 dang Exp $

inherit eutils gnome2

DESCRIPTION="Gnome default windowmanager"
HOMEPAGE="http://www.gnome.org/"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
IUSE="xinerama"

# not parallel-safe; see bug #14405
MAKEOPTS="${MAKEOPTS} -j1"

RDEPEND="|| ( (
			x11-libs/libICE
			x11-libs/libSM
			xinerama? ( x11-libs/libXinerama ) )
		virtual/x11 )
	>=x11-libs/gtk+-2.6
	>=x11-libs/pango-1.2
	>=gnome-base/gconf-2
	>=dev-libs/glib-2.6
	>=x11-libs/startup-notification-0.7
	!x11-misc/expocity"

# Needed for compositor
#			x11-libs/libXdamage
#			x11-libs/libXcomposite
DEPEND="${RDEPEND}
	xinerama? ( || ( x11-proto/xineramaproto virtual/x11 ) )
	sys-devel/gettext
	>=dev-util/pkgconfig-0.9
	>=dev-util/intltool-0.28"

USE_DESTDIR="1"
DOCS="AUTHORS ChangeLog HACKING NEWS README *.txt doc/*.txt"


pkg_setup() {
	# Compositor is too unreliable
	G2CONF="$(use_enable xinerama) \
		--disable-compositor"
}

src_unpack() {
	unpack "${A}"
	cd "${S}"

	# Fix the logout shortcut problems, by moving the keybindings
	# into here, from control-center, fixes bug #52034
	epatch "${FILESDIR}"/${PN}-2-logout.patch
}

pkg_postinst() {
	gnome2_pkg_postinst

	einfo "Metacity & Xorg X11 with composite enabled may cause unwanted"
	einfo "border effects"
}