x11-themes/qtcurve/qtcurve-1.8.14.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-themes/qtcurve/qtcurve-1.8.14.ebuild,v 1.1 2013/11/04 04:51:58 yngwin Exp $

EAPI=4
KDE_REQUIRED="optional"
inherit cmake-utils kde4-base

MY_P="${P/qtcurve/QtCurve-KDE4}"

DESCRIPTION="A set of widget styles for Qt4 based apps, also available for GTK2"
HOMEPAGE="http://www.kde-look.org/content/show.php?content=40492"
SRC_URI="http://craigd.wikispaces.com/file/view/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="alpha amd64 hppa ppc ~ppc64 sparc x86"
IUSE="kde windeco"
REQUIRED_USE="windeco? ( kde )"

DEPEND="dev-qt/qtdbus:4
	dev-qt/qtgui:4
	dev-qt/qtsvg:4
	kde? (
		$(add_kdebase_dep systemsettings)
		windeco? ( $(add_kdebase_dep kwin) )
	)"
RDEPEND="${DEPEND}"

S=${WORKDIR}/${MY_P}

DOCS=( ChangeLog README TODO )
PATCHES=( "${FILESDIR}/${PN}_kwin_automagic_fix.patch" )

pkg_setup() {
	use kde && kde4-base_pkg_setup
}

src_configure() {
	local mycmakeargs
	if use kde; then
		mycmakeargs=(
			$(cmake-utils_use windeco QTC_KWIN)
		)
		kde4-base_src_configure
	else
		mycmakeargs=(
			"-DQTC_QT_ONLY=true"
		)
		cmake-utils_src_configure
	fi
}