media-sound/mserv/mserv-0.35.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108

# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/mserv/mserv-0.35.ebuild,v 1.7 2004/07/19 20:07:52 eradicator Exp $

inherit webapp-apache eutils

DESCRIPTION="Jukebox-style music server"
HOMEPAGE="http://www.mserv.org"
SRC_URI="mirror://sourceforge/mserv/${P}.tar.gz"
RESTRICT="nomirror"
LICENSE="mserv"

SLOT="0"
KEYWORDS="x86 ~sparc ~amd64"
IUSE="oggvorbis"

DEPEND="virtual/libc"
RDEPEND=">=dev-lang/perl-5.6.1
	 virtual/mpg123
	 media-sound/sox
	 net-www/apache
	 oggvorbis? ( media-sound/vorbis-tools )"

pkg_setup() {
	enewgroup mserv > /dev/null || die
	enewuser mserv -1 /bin/false /dev/null mserv -G audio > /dev/null || die
}

src_unpack() {
	unpack ${P}.tar.gz
	cd ${S}

	# Adjust paths to match Gentoo
	epatch ${FILESDIR}/${P}-paths.patch || die
	# Mservplay uses stricmp - should be strcasecmp
	epatch ${FILESDIR}/${P}-mservplay.patch || die
}

src_compile() {
	webapp-detect

	econf || die
	emake || die

	# Optional suid wrapper
	cd ${S}/support
	gcc -I.. -I../mserv ${CFLAGS} mservplay.c -o mservplay || die
}

src_install() {
	webapp-detect

	make DESTDIR=${D} install || die

	dobin support/mservedit support/mservripcd support/mservplay
	dodoc AUTHORS COPYING ChangeLog docs/quick-start.txt

	# Web client
	exeinto ${HTTPD_CGIBIN}/mserv
	doexe webclient/*.cgi
	insinto ${HTTPD_ROOT}/mserv
	doins webclient/*.gif webclient/index.html

	# Configuration files
	insopts -o mserv -g mserv -m0644
	insinto /etc/mserv
	fowners mserv:mserv /etc/mserv
	newins ${FILESDIR}/${P}-config config
	newins ${FILESDIR}/${P}-webacl webacl
	newins ${FILESDIR}/${P}-acl acl
	fperms 0600 /etc/mserv/acl

	exeinto /etc/init.d
	newexe ${FILESDIR}/${P}-initd ${PN}

	insinto /etc/conf.d
	newins ${FILESDIR}/${P}-confd ${PN}

	# Log file
	dodir /var/log
	touch ${D}var/log/mserv.log
	fowners mserv:mserv /var/log/mserv.log

	# Track and album info
	keepdir /var/lib/mserv/trackinfo
	fowners mserv:mserv /var/lib/mserv/trackinfo

	# Current track output
	dodir /var/spool/mserv
	touch ${D}var/spool/mserv/player.out
	fowners mserv:mserv /var/spool/mserv /var/spool/mserv/player.out
}

pkg_postinst() {
	webapp-detect

	einfo
	einfo "The wrapper program 'mservplay' is disabled for"
	einfo "security reasons.  If you wish to use mservplay"
	einfo "to pass a 'nice' value to mpg123, you must make"
	einfo "/usr/bin/mservplay suid root."
	einfo
	einfo "The web client has been installed in"
	einfo "${HTTPD_ROOT}/mserv."
	ewarn
	ewarn "Please edit /etc/mserv/config and set path_tracks"
	ewarn "to the location of your music files."
}