blob: 1986c5596e722ef118a2ebb3fbb83658fed62d59 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
|
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/kde-base/plasma-workspace/plasma-workspace-4.2.3.ebuild,v 1.1 2009/05/07 00:17:39 scarabeus Exp $
EAPI="2"
KMNAME="kdebase-workspace"
KMMODULE="plasma"
inherit python kde4-meta
DESCRIPTION="Plasma: KDE desktop framework"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~x86"
IUSE="debug doc google-gadgets python rss xcomposite xinerama"
COMMONDEPEND="
>=kde-base/kephal-${PV}:${SLOT}[kdeprefix=]
>=kde-base/ksysguard-${PV}:${SLOT}[kdeprefix=]
>=kde-base/libkworkspace-${PV}:${SLOT}[kdeprefix=]
>=kde-base/libplasmaclock-${PV}:${SLOT}[kdeprefix=]
>=kde-base/libtaskmanager-${PV}:${SLOT}[kdeprefix=]
>=kde-base/solid-${PV}:${SLOT}[kdeprefix=]
x11-libs/libXcomposite
x11-libs/libXdamage
x11-libs/libXfixes
x11-libs/libXrender
google-gadgets? ( >=x11-misc/google-gadgets-0.10.5[qt4] )
python? (
>=dev-python/PyQt4-4.4.0
>=dev-python/sip-4.7.1
>=kde-base/pykde4-${PV}:${SLOT}[kdeprefix=]
)
rss? ( >=kde-base/kdepimlibs-${PV}:${SLOT}[kdeprefix=] )
xinerama? ( x11-libs/libXinerama )
"
DEPEND="${COMMONDEPEND}
x11-proto/compositeproto
x11-proto/damageproto
x11-proto/fixesproto
x11-proto/renderproto
xinerama? ( x11-proto/xineramaproto )
"
RDEPEND="${COMMONDEPEND}
>=kde-base/kioclient-${PV}:${SLOT}[kdeprefix=]
>=kde-base/kde-menu-icons-${PV}:${SLOT}[kdeprefix=]
>=kde-base/soliduiserver-${PV}:${SLOT}[kdeprefix=]
"
KMEXTRA="
libs/nepomukquery/
libs/nepomukqueryclient/
"
KMEXTRACTONLY="
krunner/dbus/org.freedesktop.ScreenSaver.xml
krunner/dbus/org.kde.krunner.App.xml
ksmserver/org.kde.KSMServerInterface.xml
libs/kworkspace/
libs/taskmanager/
ksysguard/
"
KMLOADLIBS="libkworkspace libplasmaclock libtaskmanager"
src_prepare() {
kde4-meta_src_prepare
if ! use xcomposite; then
# Add David Nolder (zwabel) experimental fake transparency patch
echo
ewarn "Enabling experimental fake transparency support."
ewarn "There are known issues with certain versions of Qt."
ewarn "Do not report any bugs."
echo
epatch "${FILESDIR}/${PN}-fake-panel-transparency.patch"
fi
}
src_configure() {
mycmakeargs="${mycmakeargs}
$(cmake-utils_use_with google-gadgets Googlegadgets)
$(cmake-utils_use_with python SIP)
$(cmake-utils_use_with python PyQt4)
$(cmake-utils_use_with python PyKDE4)
$(cmake-utils_use_with rss KdepimLibs)
-DWITH_Xmms=OFF"
kde4-meta_src_configure
}
src_install() {
kde4-meta_src_install
python_version
rm -f \
"${D}/usr/$(get_libdir)/python${PYVER}"/site-packages/PyKDE4/*.py[co] \
"${D}${KDEDIR}"/share/apps/plasma_scriptengine_python/*.py[co]
}
pkg_postinst() {
kde4-meta_pkg_postinst
if use python; then
python_mod_optimize \
"/usr/$(get_libdir)/python${PYVER}"/site-packages/PyKDE4 \
"${KDEDIR}"/share/apps/plasma_scriptengine_python
fi
}
pkg_postrm() {
kde4-meta_pkg_postrm
if [[ -d "${KDEDIR}"/share/apps/plasma_scriptengine_python ]]; then
python_mod_cleanup \
"/usr/$(get_libdir)/python${PYVER}"/site-packages/PyKDE4 \
"${KDEDIR}"/share/apps/plasma_scriptengine_python
fi
}
|