1 files changed, 0 insertions, 92 deletions
diff --git a/sys-devel/gettext/gettext-0.18.ebuild b/sys-devel/gettext/gettext-0.18.ebuild
deleted file mode 100644
index b1eb425c1ae5..000000000000
--- a/sys-devel/gettext/gettext-0.18.ebuild
+++ /dev/null
@@ -1,92 +0,0 @@
-# Copyright 1999-2010 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-devel/gettext/gettext-0.18.ebuild,v 1.1 2010/05/24 02:07:29 vapier Exp $
-
-EAPI="2"
-
-inherit flag-o-matic eutils multilib toolchain-funcs mono libtool
-
-DESCRIPTION="GNU locale utilities"
-HOMEPAGE="http://www.gnu.org/software/gettext/"
-SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
-
-LICENSE="GPL-3 LGPL-2"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
-IUSE="acl doc emacs nls nocxx openmp elibc_glibc"
-
-DEPEND="virtual/libiconv
-	dev-libs/libxml2
-	sys-libs/ncurses
-	dev-libs/expat
-	acl? ( virtual/acl )"
-PDEPEND="emacs? ( app-emacs/po-mode )"
-
-src_prepare() {
-	epunt_cxx
-}
-
-src_configure() {
-	local myconf=""
-	# Build with --without-included-gettext (on glibc systems)
-	if use elibc_glibc ; then
-		myconf="${myconf} --without-included-gettext $(use_enable nls)"
-	else
-		myconf="${myconf} --with-included-gettext --enable-nls"
-	fi
-	use nocxx && export CXX=$(tc-getCC)
-
-	# --without-emacs: Emacs support is now in a separate package
-	# --with-included-glib: glib depends on us so avoid circular deps
-	# --with-included-libcroco: libcroco depends on glib which ... ^^^
-	econf \
-		--docdir="/usr/share/doc/${PF}" \
-		--without-emacs \
-		--disable-java \
-		--with-included-glib \
-		--with-included-libcroco \
-		$(use_enable acl) \
-		$(use_enable openmp)
-}
-
-src_install() {
-	emake install DESTDIR="${D}" || die "install failed"
-	use nls || rm -r "${D}"/usr/share/locale
-	dosym msgfmt /usr/bin/gmsgfmt #43435
-	dobin gettext-tools/misc/gettextize || die "gettextize"
-
-	# remove stuff that glibc handles
-	if use elibc_glibc ; then
-		rm -f "${D}"/usr/include/libintl.h
-		rm -f "${D}"/usr/$(get_libdir)/libintl.*
-	fi
-	rm -f "${D}"/usr/share/locale/locale.alias "${D}"/usr/lib/charset.alias
-
-	if [[ ${USERLAND} == "BSD" ]] ; then
-		libname="libintl$(get_libname)"
-		# Move dynamic libs and creates ldscripts into /usr/lib
-		dodir /$(get_libdir)
-		mv "${D}"/usr/$(get_libdir)/${libname}* "${D}"/$(get_libdir)/
-		gen_usr_ldscript ${libname}
-	fi
-
-	if use doc ; then
-		dohtml "${D}"/usr/share/doc/${PF}/*.html
-	else
-		rm -rf "${D}"/usr/share/doc/${PF}/{csharpdoc,examples,javadoc2,javadoc1}
-	fi
-	rm -f "${D}"/usr/share/doc/${PF}/*.html
-
-	dodoc AUTHORS ChangeLog NEWS README THANKS
-}
-
-pkg_preinst() {
-	# older gettext's sometimes installed libintl ...
-	# need to keep the linked version or the system
-	# could die (things like sed link against it :/)
-	preserve_old_lib /{,usr/}$(get_libdir)/libintl$(get_libname 7)
-}
-
-pkg_postinst() {
-	preserve_old_lib_notify /{,usr/}$(get_libdir)/libintl$(get_libname 7)
-}