1 files changed, 61 insertions, 0 deletions
diff --git a/sys-apps/more/more-2.12r.ebuild b/sys-apps/more/more-2.12r.ebuild
new file mode 100644
index 000000000000..4d867fbd2dc8
--- /dev/null
+++ b/sys-apps/more/more-2.12r.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/more/more-2.12r.ebuild,v 1.1 2007/06/15 23:54:44 lavajoe Exp $
+
+inherit eutils flag-o-matic
+
+DESCRIPTION="Primitive text file viewer"
+HOMEPAGE="http://www.kernel.org/pub/linux/utils/util-linux/"
+SRC_URI="mirror://kernel/linux/utils/util-linux/util-linux-${PV}.tar.bz2"
+S=${WORKDIR}/util-linux-${PV}
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~x86-fbsd"
+IUSE="static nls selinux"
+
+RDEPEND=">=sys-libs/ncurses-5.2-r2
+	selinux? ( sys-libs/libselinux )
+	!sys-apps/util-linux"
+DEPEND="${RDEPEND}
+	nls? ( sys-devel/gettext )"
+PROVIDE="virtual/pager"
+
+yesno() { useq $1 && echo yes || echo no; }
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+
+	epatch "${FILESDIR}"/${P}-freebsd.patch
+
+	# Enable random features
+	local mconfigs="MCONFIG"
+	sed -i \
+		-e "/^HAVE_SELINUX=/s:no:$(yesno selinux):" \
+		-e "/^DISABLE_NLS=/s:no:$(yesno !nls):" \
+		-e "/^HAVE_KILL=/s:no:yes:" \
+		-e "/^HAVE_SLN=/s:no:yes:" \
+		-e "/^HAVE_TSORT/s:no:yes:" \
+		-e "s:-pipe -O2 \$(CPUOPT) -fomit-frame-pointer:${CFLAGS}:" \
+		-e "s:CPU=.*:CPU=${CHOST%%-*}:" \
+		-e "s:SUIDMODE=.*4755:SUIDMODE=4711:" \
+		${mconfigs} || die "MCONFIG sed"
+}
+
+src_compile() {
+	append-ldflags $(bindnow-flags)
+	use static && append-ldflags -static
+	export CC="$(tc-getCC)"
+
+	econf || die "configure failed"
+	emake -C lib xstrncpy.o || die "emake xstrncpy.o failed"
+	emake -C text-utils more || die "emake more failed"
+}
+
+src_install() {
+	exeinto /bin
+	doexe text-utils/more || die
+	doman text-utils/more.1 || die
+	dodoc HISTORY MAINTAINER README VERSION
+}