1 files changed, 60 insertions, 0 deletions
diff --git a/dev-python/flask/flask-0.6.1.ebuild b/dev-python/flask/flask-0.6.1.ebuild
new file mode 100644
index 000000000000..38f86c02013b
--- /dev/null
+++ b/dev-python/flask/flask-0.6.1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/flask/flask-0.6.1.ebuild,v 1.1 2010/12/31 22:31:02 arfrever Exp $
+
+EAPI="3"
+PYTHON_DEPEND="2"
+SUPPORT_PYTHON_ABIS="1"
+RESTRICT_PYTHON_ABIS="3.*"
+
+inherit distutils
+
+MY_PN="Flask"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="A microframework based on Werkzeug, Jinja2 and good intentions"
+HOMEPAGE="http://pypi.python.org/pypi/Flask"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc examples test"
+
+RDEPEND=">=dev-python/jinja-2.4
+	dev-python/setuptools
+	>=dev-python/werkzeug-0.6.1"
+DEPEND="${RDEPEND}
+	doc? ( >=dev-python/sphinx-0.6 )"
+
+S="${WORKDIR}/${MY_P}"
+
+src_compile() {
+	distutils_src_compile
+
+	if use doc; then
+		einfo "Generation of documentation"
+		cd docs
+		PYTHONPATH=".." emake html || die "Generation of documentation failed"
+	fi
+}
+
+src_test() {
+	testing() {
+		PYTHONPATH="." "$(PYTHON)" tests/flask_tests.py
+	}
+	python_execute_function testing
+}
+
+src_install() {
+	distutils_src_install
+
+	if use doc; then
+		dohtml -r docs/_build/html/* || die "Installation of documentation failed"
+	fi
+
+	if use examples; then
+		insinto "/usr/share/doc/${PF}"
+		doins -r examples || die "Installation of examples failed"
+	fi
+}