1 files changed, 56 insertions, 0 deletions
diff --git a/dev-python/PyQt/PyQt-3.15.1.ebuild b/dev-python/PyQt/PyQt-3.15.1.ebuild
new file mode 100644
index 000000000000..f6f9c7a363c3
--- /dev/null
+++ b/dev-python/PyQt/PyQt-3.15.1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2005 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/PyQt/PyQt-3.15.1.ebuild,v 1.1 2005/12/09 22:07:41 carlo Exp $
+
+inherit distutils
+
+MY_P="PyQt-x11-gpl-${PV/*_pre/snapshot-}"
+S="${WORKDIR}/${MY_P}"
+
+DESCRIPTION="set of Python bindings for the QT 3.x Toolkit"
+HOMEPAGE="http://www.riverbankcomputing.co.uk/pyqt/"
+SRC_URI="mirror://gentoo/${MY_P}.tar.gz"
+#SRC_URI="http://www.river-bank.demon.co.uk/download/PyQt/${MY_P}.tar.gz"
+#SRC_URI="http://www.river-bank.demon.co.uk/download/snapshots/PyQt/${MY_P}.tar.gz"
+
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~x86 ~ppc ~sparc ~alpha ~amd64 ~ppc64"
+IUSE="debug doc examples"
+
+RDEPEND="=x11-libs/qt-3*
+	>=dev-python/sip-4.2
+	<dev-python/qscintilla-1.10"
+DEPEND="${RDEPEND}
+	sys-devel/libtool"
+
+
+src_unpack() {
+	unpack ${A}
+	sed -i -e "s:  check_license():# check_license():" ${S}/configure.py
+}
+
+src_compile() {
+	distutils_python_version
+	addpredict ${QTDIR}/etc/settings
+
+	local myconf="-d ${ROOT}/usr/$(get_libdir)/python${PYVER}/site-packages \
+			-b ${ROOT}/usr/bin \
+			-v ${ROOT}/usr/share/sip \
+			-n ${ROOT}/usr/include \
+			-o ${ROOT}/usr/$(get_libdir)"
+	use debug && myconf="${myconf} -u"
+
+	python configure.py ${myconf}
+	emake || die "emake failed"
+}
+
+src_install() {
+	make DESTDIR=${D} install || die "install failed"
+	dodoc ChangeLog LICENSE NEWS README README.Linux THANKS
+	use doc && dohtml doc/PyQt.html
+	if use examples ; then
+		dodir /usr/share/doc/${PF}/examples
+		cp -r examples3/* ${D}/usr/share/doc/${PF}/examples
+	fi
+}