1 files changed, 61 insertions, 0 deletions
diff --git a/app-i18n/ibus-anthy/ibus-anthy-1.2.6.ebuild b/app-i18n/ibus-anthy/ibus-anthy-1.2.6.ebuild
new file mode 100644
index 000000000000..f64bb49f5c4b
--- /dev/null
+++ b/app-i18n/ibus-anthy/ibus-anthy-1.2.6.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-i18n/ibus-anthy/ibus-anthy-1.2.6.ebuild,v 1.1 2011/05/18 23:31:03 naota Exp $
+
+EAPI=3
+PYTHON_DEPEND="2:2.5"
+inherit eutils python
+
+DESCRIPTION="Japanese input method Anthy IMEngine for IBus Framework"
+HOMEPAGE="http://code.google.com/p/ibus/"
+SRC_URI="http://ibus.googlecode.com/files/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="nls"
+
+RDEPEND=">=app-i18n/ibus-1.2.0.20100111
+	app-i18n/anthy
+	>=dev-python/pygtk-2.15.2
+	nls? ( virtual/libintl )"
+DEPEND="${RDEPEND}
+	dev-lang/swig
+	dev-util/pkgconfig
+	nls? ( >=sys-devel/gettext-0.16.1 )"
+
+pkg_setup() {
+	python_set_active_version 2
+	python_pkg_setup
+}
+
+src_prepare() {
+	mv py-compile py-compile.orig || die
+	ln -s "$(type -P true)" py-compile || die
+	sed -i -e "s/python/python2/" \
+		engine/ibus-engine-anthy.in setup/ibus-setup-anthy.in || die
+}
+
+src_configure() {
+	econf $(use_enable nls)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+
+	dodoc AUTHORS ChangeLog NEWS README || die
+}
+
+pkg_postinst() {
+	elog
+	elog "app-dicts/kasumi is not required but probably useful for you."
+	elog
+	elog "# emerge app-dicts/kasumi"
+	elog
+
+	python_mod_optimize /usr/share/${PN}
+}
+
+pkg_postrm() {
+	python_mod_cleanup /usr/share/${PN}
+}