1 files changed, 56 insertions, 0 deletions
diff --git a/app-arch/unrar/unrar-5.0.13.ebuild b/app-arch/unrar/unrar-5.0.13.ebuild
new file mode 100644
index 000000000000..e34866d23fcd
--- /dev/null
+++ b/app-arch/unrar/unrar-5.0.13.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-arch/unrar/unrar-5.0.13.ebuild,v 1.1 2013/11/17 15:11:37 ssuominen Exp $
+
+EAPI=5
+inherit eutils flag-o-matic multilib toolchain-funcs
+
+MY_PN=${PN}src
+
+DESCRIPTION="Uncompress rar files"
+HOMEPAGE="http://www.rarlab.com/rar_add.htm"
+SRC_URI="http://www.rarlab.com/rar/${MY_PN}-${PV}.tar.gz"
+
+LICENSE="unRAR"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~arm-linux ~x86-linux"
+IUSE=""
+
+RDEPEND="!<=app-arch/unrar-gpl-0.0.1_p20080417"
+
+S=${WORKDIR}/unrar
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-5.0.2-build.patch
+	sed -i \
+		-e "/libunrar/s:.so:$(get_libname ${PV%.*.*}):" \
+		-e "s:-shared:& -Wl,-soname -Wl,libunrar$(get_libname ${PV%.*.*}):" \
+		makefile || die
+}
+
+src_compile() {
+	unrar_make() {
+		emake CXX="$(tc-getCXX)" CXXFLAGS="${CXXFLAGS}" STRIP=true "$@"
+	}
+
+	unrar_make CXXFLAGS+=" -fPIC" lib
+	ln -s libunrar$(get_libname ${PV%.*.*}) libunrar$(get_libname)
+	ln -s libunrar$(get_libname ${PV%.*.*}) libunrar$(get_libname ${PV})
+
+	# The stupid code compiles a lot of objects differently if
+	# they're going into a lib (-DRARDLL) or into the main app.
+	# So for now, we can't link the main app against the lib.
+	unrar_make clean
+	unrar_make
+}
+
+src_install() {
+	dobin unrar
+	dodoc readme.txt
+
+	dolib.so libunrar*
+
+	insinto /usr/include/libunrar${PV%.*.*}
+	doins *.hpp
+	dosym libunrar${PV%.*.*} /usr/include/libunrar
+}