Applying patch from Davide Pesavento in bug 265770 that fixes several issues

Package-Manager: portage-2.2_rc28/cvs/Linux x86_64

3 files changed, 112 insertions, 2 deletions

diff --git a/media-video/smplayer/ChangeLog b/media-video/smplayer/ChangeLog
index 9d59cf78b349..2722d0aacf39 100644
--- a/media-video/smplayer/ChangeLog
+++ b/media-video/smplayer/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for media-video/smplayer
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/smplayer/ChangeLog,v 1.68 2009/03/19 14:04:21 ranger Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/smplayer/ChangeLog,v 1.69 2009/05/08 17:04:09 yngwin Exp $
+
+*smplayer-0.6.7_p2872-r2 (08 May 2009)
+
+  08 May 2009; Ben de Groot <yngwin@gentoo.org>
+  +smplayer-0.6.7_p2872-r2.ebuild:
+  Applying patch from Davide Pesavento in bug 265770 that fixes several
+  issues
 
   19 Mar 2009; Brent Baude <ranger@gentoo.org> smplayer-0.6.6.ebuild:
   Marking smplayer-0.6.6 ppc for bug 257852
diff --git a/media-video/smplayer/Manifest b/media-video/smplayer/Manifest
index 08bde5be55c3..97dc7242c671 100644
--- a/media-video/smplayer/Manifest
+++ b/media-video/smplayer/Manifest
@@ -12,5 +12,6 @@ EBUILD smplayer-0.6.5.1.ebuild 2488 RMD160 0f2ce62f4097f17c89bdafcbe420db1857b3c
 EBUILD smplayer-0.6.6.ebuild 2460 RMD160 e1cce44a5e191e55904b35d96968b1f548aec0c0 SHA1 8721824e0778be7ceda50d789a34adcb175983ac SHA256 f55e4dc10ffc2f02ba11fe4a032250f589cbdf37db080f60ab746a1d6c16eca9
 EBUILD smplayer-0.6.6_p2776.ebuild 2220 RMD160 e00a7ed136b48d2ccf5761be659430351b162478 SHA1 e5fb6d785a7df3b10b5fe882cad3d2e3be33944b SHA256 db6e849be3dd7883303dbda05c5392584d3a1cf1ce51a1056cee90f62386b46b
 EBUILD smplayer-0.6.7_p2872-r1.ebuild 2435 RMD160 4c2abb0be16c0cfab508f3544c6d2b0e668bdf06 SHA1 d00062cfd298e846d454bdd5b3a52db68c1de116 SHA256 4fddbbf14ec86b14a77b7c21fa2f100a0318972bb27d1500bd273c29851c63ca
-MISC ChangeLog 9622 RMD160 443a6d3b7bed33b2ddeb0469de2f073b292efceb SHA1 af9c7d87a4580ca5bbb8c4cf9028516f026b5b4c SHA256 652d5464ffff2291c8b57e7c0b0953f513e70d1b97e0a0f2a34e7a50e9b523ae
+EBUILD smplayer-0.6.7_p2872-r2.ebuild 2644 RMD160 ab0b7cca2eaab03bee91daf323b80b05372ab3b0 SHA1 ab41a4191a36c0f21430c8454c83348aded40fbf SHA256 e3059fed5d2a2c848c3b1ff80d2920a7dc6c94180bd5ad5a467d293d6290959e
+MISC ChangeLog 9827 RMD160 abc8b4f56a898ce8804e6930c78347e65eb4684f SHA1 6a4404f07c5d118e3dcd56b4b698c78824b655cc SHA256 7aa4cc681a132a7fe9ea6d8fcb1671ba19f4005e0438a98e1f47e717e256c84a
 MISC metadata.xml 248 RMD160 3dd3ed866d9de9b9e1e757a75ad74cd04a179a0a SHA1 ee402648473a449107fdc483b2452b655887f15c SHA256 319bbc38f5d834b6230f477c4330ff29d94c9447f563551c977e5c3b038aecaf
diff --git a/media-video/smplayer/smplayer-0.6.7_p2872-r2.ebuild b/media-video/smplayer/smplayer-0.6.7_p2872-r2.ebuild
new file mode 100644
index 000000000000..66369843ab42
--- /dev/null
+++ b/media-video/smplayer/smplayer-0.6.7_p2872-r2.ebuild
@@ -0,0 +1,102 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/smplayer/smplayer-0.6.7_p2872-r2.ebuild,v 1.1 2009/05/08 17:04:09 yngwin Exp $
+
+EAPI=2
+inherit eutils qt4
+
+MY_PV=${PV##*_p}
+if [[ "${MY_PV}" != "${PV}" ]]; then
+	# svn snapshot
+	MY_PV=r${MY_PV}
+	MY_P=${PN}-${MY_PV}
+	S="${WORKDIR}/${MY_P}"
+	SRC_URI="mirror://gentoo/${MY_P}.tar.bz2"
+else
+	# regular upstream release
+	SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
+fi
+
+DESCRIPTION="Great Qt4 GUI front-end for mplayer"
+HOMEPAGE="http://smplayer.sourceforge.net"
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="debug"
+
+DEPEND="x11-libs/qt-gui:4"
+RDEPEND="${DEPEND}
+	media-video/mplayer[ass,png]"
+
+LANGS="bg ca cs de en_US es eu fi fr gl hu it ja ka ko ku mk nl pl pt_BR pt_PT sk sr sv tr zh_CN zh_TW"
+NOLONGLANGS="ar_SY el_GR ro_RO ru_RU sl_SI uk_UA"
+for X in ${LANGS}; do
+	IUSE="${IUSE} linguas_${X}"
+done
+for X in ${NOLONGLANGS}; do
+	IUSE="${IUSE} linguas_${X%_*}"
+done
+
+src_prepare() {
+	# Upstream Makefile sucks
+	sed -i -e "/^PREFIX=/s:/usr/local:/usr:" \
+		-e "/^DOC_PATH=/s:packages/smplayer:${PF}:" \
+		-e '/\.\/get_svn_revision\.sh/,+2c\
+	cd src && $(DEFS) $(MAKE)' \
+		"${S}"/Makefile || die "sed failed"
+
+	# Turn debug message flooding off
+	if ! use debug ; then
+		sed -i 's:#\(DEFINES += NO_DEBUG_ON_CONSOLE\):\1:' \
+			"${S}"/src/smplayer.pro || die "sed failed"
+	fi
+}
+
+src_configure() {
+	cd "${S}"/src
+	echo "#define SVN_REVISION \"SVN-${MY_PV} (Gentoo)\"" > svn_revision.h
+	eqmake4
+}
+
+gen_translation() {
+	ebegin "Generating $1 translation"
+	lrelease ${PN}_${1}.ts
+	eend $? || die "failed to generate $1 translation"
+}
+
+src_compile() {
+	emake || die "emake failed"
+
+	# Generate translations
+	cd "${S}"/src/translations
+	local lang= nolangs= x=
+	for lang in ${LINGUAS}; do
+		if has ${lang} ${LANGS}; then
+			gen_translation ${lang}
+			continue
+		elif [[ " ${NOLONGLANGS} " == *" ${lang}_"* ]]; then
+			for x in ${NOLONGLANGS}; do
+				if [[ "${lang}" == "${x%_*}" ]]; then
+					gen_translation ${x}
+					continue 2
+				fi
+			done
+		fi
+		nolangs="${nolangs} ${lang}"
+	done
+	[[ -n ${nolangs} ]] && ewarn "Sorry, but ${PN} does not support the LINGUAS:" ${nolangs}
+	# install fails when no translation is present (bug 244370)
+	[[ -z $(ls *.qm 2>/dev/null) ]] && gen_translation en_US
+}
+
+src_install() {
+	# remove unneeded copies of GPL
+	rm -f Copying.txt docs/{cs,en,ja,ru}/gpl.html
+	rm -rf docs/{de,es,nl,ro}
+
+	# remove windows-only files
+	rm "${S}"/*.bat
+
+	emake DESTDIR="${D}" install || die "emake install failed"
+	prepalldocs
+}