Add today's ffmpeg svn snapshot.

Package-Manager: portage-2.2_rc40/cvs/Linux x86_64

3 files changed, 259 insertions, 5 deletions

diff --git a/media-video/ffmpeg/ChangeLog b/media-video/ffmpeg/ChangeLog
index 910dd97e46f3..ca54b6da7d3a 100644
--- a/media-video/ffmpeg/ChangeLog
+++ b/media-video/ffmpeg/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-video/ffmpeg
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/ffmpeg/ChangeLog,v 1.307 2009/09/06 10:10:29 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/ffmpeg/ChangeLog,v 1.308 2009/09/06 12:12:13 aballier Exp $
+
+*ffmpeg-0.5_p19787 (06 Sep 2009)
+
+  06 Sep 2009; Alexis Ballier <aballier@gentoo.org>
+  +ffmpeg-0.5_p19787.ebuild:
+  Add today's ffmpeg svn snapshot.
 
   06 Sep 2009; Alexis Ballier <aballier@gentoo.org> ffmpeg-9999-r1.ebuild:
   Use ffmpeg.org svn repo and add PV conditionals so that we can make
diff --git a/media-video/ffmpeg/Manifest b/media-video/ffmpeg/Manifest
index 78389c0b3fed..192bb927ec80 100644
--- a/media-video/ffmpeg/Manifest
+++ b/media-video/ffmpeg/Manifest
@@ -2,14 +2,16 @@
 Hash: SHA1
 
 DIST ffmpeg-0.5.tar.bz2 2744768 RMD160 23b4a591c422f98b634eba0ba82817ad27a4ff07 SHA1 f930971bc0ac3d11a4ffbb1af439425c24f6f5b1 SHA256 16de61d7426b1df7aee54b48c16aa728de1ed82f95db5fc4d8886d5d2702d90a
+DIST ffmpeg-0.5_p19787.tar.bz2 3058617 RMD160 521fbaeb8cf332fb255688b106ab6e3a030f19c3 SHA1 2117cd07423dc54eca15bc54b31fa67d6c926ea6 SHA256 7610ee7a13586ce087a2fa2c8f7345914f5bed7aec4ad213ca004f45791a66d2
 EBUILD ffmpeg-0.5-r1.ebuild 6549 RMD160 7d3dc6f710b1944022c6a607737ea8be4e0b7385 SHA1 23b88211d4e61f9b49c7b8a3a1f85ed1616cf1b8 SHA256 83d0453256174cd98f8d7fbc0c8fca48f1b0ddd681e5345a796af1c0350668d9
+EBUILD ffmpeg-0.5_p19787.ebuild 7524 RMD160 e719f15aa8a5dcafd50b820cb5e36b91d12461ff SHA1 6d8765427ee85eb0746581036f034033be0d7953 SHA256 3e2f9f3bdd2ddbfdc5e6885708fabcfe1a3593e62f788333b4c09b8d04e4e994
 EBUILD ffmpeg-9999-r1.ebuild 7458 RMD160 d48c5d5f4af5e8aaac42e84d5f384005e05030ca SHA1 9af3ba5b92e77e5d4d02689198ba4e7ac9103f74 SHA256 31bb4259ab87afc69dc20f04e737b2e6f916cda1bfd8e0dc909af49edc494661
-MISC ChangeLog 46804 RMD160 358bdd3ae6d4b5b8dd3c3add7f11c99869c98de8 SHA1 7dfa0d4d67cdf1315066e0325a74ce0d99c9b114 SHA256 b21728e741cff61e19ea556c7741516c182e55063f26c21072102917c97f36ff
+MISC ChangeLog 46955 RMD160 049d28d7f75546133458d7e9c2c2238054e55eae SHA1 85bf324aa5dab66018137d3ec2e53e5d94cb2950 SHA256 72172ccd87015b7bd8e93a82858c6d9fa0bc6fd6dcbddf2993c66f85ab467abc
 MISC metadata.xml 1789 RMD160 84a7ab72fdc26957a4040bf7d6b1f7a823b38e17 SHA1 8c8db893db07715bec78bd1b36c385c85b4fe3a0 SHA256 f250a28df71c2fb2b067cd6b274c4f36d4df33fee77ebb2a35d1e57fcf38a1ca
 -----BEGIN PGP SIGNATURE-----
 Version: GnuPG v2.0.11 (GNU/Linux)
 
-iEYEARECAAYFAkqjipsACgkQvFcC4BYPU0pPPgCggaCBaplLe0SrqmxwEpSUMYmp
-b+0An2eY/PqpJV6qwZDN8Q5eqk/PhGxr
-=RRLT
+iEYEARECAAYFAkqjpyMACgkQvFcC4BYPU0pxyQCggVpN0rV11eYBNVAu/TG2c+DJ
+W8kAoM3InRW/diPS12K/kSjTJhyrvRmW
+=5N9j
 -----END PGP SIGNATURE-----
diff --git a/media-video/ffmpeg/ffmpeg-0.5_p19787.ebuild b/media-video/ffmpeg/ffmpeg-0.5_p19787.ebuild
new file mode 100644
index 000000000000..227b4e2003d8
--- /dev/null
+++ b/media-video/ffmpeg/ffmpeg-0.5_p19787.ebuild
@@ -0,0 +1,246 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/ffmpeg/ffmpeg-0.5_p19787.ebuild,v 1.1 2009/09/06 12:12:13 aballier Exp $
+
+EAPI=2
+SCM=""
+if [ "${PV#9999}" != "${PV}" ] ; then
+	SCM=subversion
+	ESVN_REPO_URI="svn://svn.ffmpeg.org/ffmpeg/trunk"
+fi
+
+inherit eutils flag-o-matic multilib toolchain-funcs ${SCM}
+
+DESCRIPTION="Complete solution to record, convert and stream audio and video. Includes libavcodec."
+HOMEPAGE="http://ffmpeg.org/"
+if [ "${PV#9999}" != "${PV}" ] ; then
+	SRC_URI=""
+elif [ "${PV%_p*}" != "${PV}" ] ; then # Snapshot
+	SRC_URI="mirror://gentoo/${P}.tar.bz2"
+else # Release
+	SRC_URI="http://ffmpeg.org/releases/${P}.tar.bz2"
+fi
+FFMPEG_REVISION="${PV#*_p}"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="+3dnow +3dnowext alsa altivec cpudetection custom-cflags debug dirac
+	  doc ieee1394 +encode faac faad gsm ipv6 jack +mmx +mmxext vorbis test
+	  theora threads x264 xvid network zlib sdl X mp3 opencore-amr
+	  oss schroedinger +hardcoded-tables bindist v4l v4l2
+	  speex +ssse3 jpeg2k vdpau"
+
+VIDEO_CARDS="nvidia"
+
+for x in ${VIDEO_CARDS}; do
+	IUSE="${IUSE} video_cards_${x}"
+done
+
+RDEPEND="sdl? ( >=media-libs/libsdl-1.2.10 )
+	alsa? ( media-libs/alsa-lib )
+	encode? (
+		faac? ( media-libs/faac )
+		mp3? ( media-sound/lame )
+		vorbis? ( media-libs/libvorbis media-libs/libogg )
+		theora? ( media-libs/libtheora[encode] media-libs/libogg )
+		x264? ( >=media-libs/x264-0.0.20081006 )
+		xvid? ( >=media-libs/xvid-1.1.0 ) )
+	faad? ( >=media-libs/faad2-2.6.1 )
+	zlib? ( sys-libs/zlib )
+	ieee1394? ( media-libs/libdc1394
+				sys-libs/libraw1394 )
+	dirac? ( media-video/dirac )
+	gsm? ( >=media-sound/gsm-1.0.12-r1 )
+	jpeg2k? ( >=media-libs/openjpeg-1.3-r2 )
+	opencore-amr? ( media-libs/opencore-amr )
+	schroedinger? ( media-libs/schroedinger )
+	speex? ( >=media-libs/speex-1.2_beta3 )
+	jack? ( media-sound/jack-audio-connection-kit )
+	X? ( x11-libs/libX11 x11-libs/libXext )
+	video_cards_nvidia? (
+		vdpau? ( >=x11-drivers/nvidia-drivers-180.29 )
+	)"
+
+DEPEND="${RDEPEND}
+	>=sys-devel/make-3.81
+	mmx? ( dev-lang/yasm )
+	doc? ( app-text/texi2html )
+	test? ( net-misc/wget )
+	v4l? ( sys-kernel/linux-headers )
+	v4l2? ( sys-kernel/linux-headers )"
+
+src_prepare() {
+	if [[ ${PV} = *9999* ]]; then
+		# Set SVN version manually
+		subversion_wc_info
+		sed -i s/UNKNOWN/SVN-r${ESVN_WC_REVISION}/ "${S}/version.sh"
+	elif [ "${PV%_p*}" != "${PV}" ] ; then # Snapshot
+		sed -i s/UNKNOWN/SVN-r${FFMPEG_REVISION}/ "${S}/version.sh"
+	fi
+}
+
+src_configure() {
+	local myconf="${EXTRA_FFMPEG_CONF}"
+
+	# enabled by default
+	use debug || myconf="${myconf} --disable-debug"
+	use zlib || myconf="${myconf} --disable-zlib"
+	use sdl || myconf="${myconf} --disable-ffplay"
+
+	if use network; then
+		use ipv6 || myconf="${myconf} --disable-ipv6"
+	else
+		myconf="${myconf} --disable-network"
+	fi
+
+	use custom-cflags && myconf="${myconf} --disable-optimizations"
+	use cpudetection && myconf="${myconf} --enable-runtime-cpudetect"
+
+	# enabled by default
+	if use encode
+	then
+		use mp3 && myconf="${myconf} --enable-libmp3lame"
+		use vorbis && myconf="${myconf} --enable-libvorbis"
+		use theora && myconf="${myconf} --enable-libtheora"
+		use x264 && myconf="${myconf} --enable-libx264"
+		use xvid && myconf="${myconf} --enable-libxvid"
+	else
+		myconf="${myconf} --disable-encoders"
+	fi
+
+	# libavdevice options
+	use ieee1394 && myconf="${myconf} --enable-libdc1394"
+	# Indevs
+	for i in v4l v4l2 alsa oss jack ; do
+		use $i || myconf="${myconf} --disable-indev=$i"
+	done
+	# Outdevs
+	for i in alsa oss ; do
+		use $i || myconf="${myconf} --disable-outdev=$i"
+	done
+	use X && myconf="${myconf} --enable-x11grab"
+
+	# Threads; we only support pthread for now but ffmpeg supports more
+	use threads && myconf="${myconf} --enable-pthreads"
+
+	# Decoders
+	use opencore-amr && myconf="${myconf} --enable-libopencore-amrwb
+		--enable-libopencore-amrnb"
+	for i in faad dirac schroedinger speex; do
+		use $i && myconf="${myconf} --enable-lib$i"
+	done
+	use jpeg2k && myconf="${myconf} --enable-libopenjpeg"
+	if use gsm; then
+		myconf="${myconf} --enable-libgsm"
+		# Crappy detection or our installation is weird, pick one (FIXME)
+		append-flags -I/usr/include/gsm
+	fi
+	if use bindist
+	then
+		use faac && ewarn "faac is nonfree and cannot be distributed; disabling
+		faac support."
+	else
+		use faac && myconf="${myconf} --enable-libfaac"
+		{ use faac ; } && myconf="${myconf} --enable-nonfree"
+	fi
+
+	#for i in h264_vdpau mpeg1_vdpau mpeg_vdpau vc1_vdpau wmv3_vdpau; do
+	#	use video_cards_nvidia || myconf="${myconf} --disable-decoder=$i"
+	#	use vdpau || myconf="${myconf} --disable-decoder=$i"
+	#done
+	use video_cards_nvidia || myconf="${myconf} --disable-vdpau"
+	use vdpau || myconf="${myconf} --disable-vdpau"
+
+	# CPU features
+	for i in mmx ssse3 altivec ; do
+		use $i ||  myconf="${myconf} --disable-$i"
+	done
+	use mmxext || myconf="${myconf} --disable-mmx2"
+	use 3dnow || myconf="${myconf} --disable-amd3dnow"
+	use 3dnowext || myconf="${myconf} --disable-amd3dnowext"
+	# disable mmx accelerated code if PIC is required
+	# as the provided asm decidedly is not PIC.
+	if gcc-specs-pie ; then
+		myconf="${myconf} --disable-mmx --disable-mmx2"
+	fi
+
+	# Try to get cpu type based on CFLAGS.
+	# Bug #172723
+	# We need to do this so that features of that CPU will be better used
+	# If they contain an unknown CPU it will not hurt since ffmpeg's configure
+	# will just ignore it.
+	for i in $(get-flag march) $(get-flag mcpu) $(get-flag mtune) ; do
+		[ "${i}" = "native" ] && i="host" # bug #273421
+		myconf="${myconf} --cpu=$i"
+		break
+	done
+
+	# Mandatory configuration
+	myconf="${myconf} --enable-gpl --enable-version3 --enable-postproc \
+			--enable-avfilter --enable-avfilter-lavf \
+			--disable-stripping"
+
+	# cross compile support
+	if tc-is-cross-compiler ; then
+		myconf="${myconf} --enable-cross-compile --arch=$(tc-arch-kernel) --cross-prefix=${CHOST}-"
+		case ${CHOST} in
+			*freebsd*)
+				myconf="${myconf} --target-os=freebsd"
+				;;
+			mingw32*)
+				myconf="${myconf} --target-os=mingw32"
+				;;
+			*linux*)
+				myconf="${myconf} --target-os=linux"
+				;;
+		esac
+	fi
+
+	# Misc stuff
+	use hardcoded-tables && myconf="${myconf} --enable-hardcoded-tables"
+
+	# Specific workarounds for too-few-registers arch...
+	if [[ $(tc-arch) == "x86" ]]; then
+		filter-flags -fforce-addr -momit-leaf-frame-pointer
+		append-flags -fomit-frame-pointer
+		is-flag -O? || append-flags -O2
+		if (use debug); then
+			# no need to warn about debug if not using debug flag
+			ewarn ""
+			ewarn "Debug information will be almost useless as the frame pointer is omitted."
+			ewarn "This makes debugging harder, so crashes that has no fixed behavior are"
+			ewarn "difficult to fix. Please have that in mind."
+			ewarn ""
+		fi
+	fi
+
+	cd "${S}"
+	./configure \
+		--prefix=/usr \
+		--libdir=/usr/$(get_libdir) \
+		--shlibdir=/usr/$(get_libdir) \
+		--mandir=/usr/share/man \
+		--enable-static --enable-shared \
+		--cc="$(tc-getCC)" \
+		${myconf} || die "configure failed"
+}
+
+src_compile() {
+	emake version.h || die #252269
+	emake || die "make failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "Install Failed"
+
+	dodoc Changelog README INSTALL
+	dodoc doc/*
+}
+
+src_test() {
+	for t in codectest lavftest seektest ; do
+		LD_LIBRARY_PATH="${S}/libpostproc:${S}/libswscale:${S}/libavcodec:${S}/libavdevice:${S}/libavfilter:${S}/libavformat:${S}/libavutil" \
+			emake ${t} || die "Some tests in ${t} failed"
+	done
+}