Version bump

Package-Manager: portage-2.2.0_alpha51/cvs/Linux x86_64

3 files changed, 195 insertions, 6 deletions

diff --git a/media-sound/mpd/ChangeLog b/media-sound/mpd/ChangeLog
index 39ffbd91405c..8fbae70fa09d 100644
--- a/media-sound/mpd/ChangeLog
+++ b/media-sound/mpd/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/mpd
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/mpd/ChangeLog,v 1.262 2011/08/07 15:26:40 angelos Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/mpd/ChangeLog,v 1.263 2011/09/03 18:39:24 angelos Exp $
+
+*mpd-0.16.4 (03 Sep 2011)
+
+  03 Sep 2011; Christoph Mende <angelos@gentoo.org> +mpd-0.16.4.ebuild:
+  Version bump
 
   07 Aug 2011; Christoph Mende <angelos@gentoo.org> -mpd-0.15.8.ebuild,
   -mpd-0.15.15.ebuild, -mpd-0.15.16.ebuild, -mpd-0.16.3.ebuild:
diff --git a/media-sound/mpd/Manifest b/media-sound/mpd/Manifest
index 48bc3eee0b01..c0361ce4b07a 100644
--- a/media-sound/mpd/Manifest
+++ b/media-sound/mpd/Manifest
@@ -9,15 +9,17 @@ AUX mpd.init 824 RMD160 e58cc1644628fb931f5d8bd5726fdceebd29493d SHA1 72377bfa80
 AUX mpd.rc 672 RMD160 278e4f59433656b930a9f35e59747681a2e4918d SHA1 06cf045b9d994aff0653f085761871e44fe3aebc SHA256 6b0c65dc4394108b3720afdc865f8692aa80c94ed12f351dce5f11537ffd84a8
 DIST mpd-0.16.2.tar.bz2 478096 RMD160 74e63fe4514eb8309bf2b2e4e4012566e14b6262 SHA1 ce0b8cd473f8acb45c06d73f41c18fc4dabbe440 SHA256 59a3c191bbfcbbbc119f4b1e44bcb62ce15e45bc4d5041153408acc3074cb1d5
 DIST mpd-0.16.3.tar.bz2 477517 RMD160 860a308ec443896da43c7421db8895c5aff9bd91 SHA1 7990bad609064752175127527fcf2ecf8066e36f SHA256 58df79cfa89b365413ee720f3f605ff01a9aa32be1e176d523243954648731d2
+DIST mpd-0.16.4.tar.bz2 478807 RMD160 2e06445ea09c30b0ae63c33b85875114008fd13c SHA1 b4eb52903f269e18f434ca5fc346be281ba22c4f SHA256 fa85ca6f837bdfa5ac165c674c2d8cdb77ff44b5f56fac526bc6a11211e61cfd
 EBUILD mpd-0.16.2.ebuild 5426 RMD160 26c1acc62728eeb9102dee0f63ef7b3f26656088 SHA1 0cc36c588c3026ddd02252c2de8abfaf20077540 SHA256 9e80b9113e43090b2eb01fa501c4220367fa738558040059a74c05e2b9175c86
 EBUILD mpd-0.16.3-r1.ebuild 5472 RMD160 8241721e65c37bd0a211c18327facec83f299ec7 SHA1 cc6f0c0ed19840b23f8e1ba8444ad88692f03ca2 SHA256 f7dad7bb1a5c722fabfe3e1a50ba7a41012af1149a35060198535575d4c36b09
+EBUILD mpd-0.16.4.ebuild 5469 RMD160 9a5a9ce9064bfdd7d75b95dc4e09fe2f94047d97 SHA1 8f7968375a65e2fef93478e7fa8eb3989e9f333c SHA256 3818321c32bd58d704ddc3bd0cd3ad985ac76d99a25779a505c9265b74a8f90f
 EBUILD mpd-9999.ebuild 5492 RMD160 9cdc4093fd888d445f1b5c63c0cdf41a5a644c3d SHA1 8eb1ee71a902e8c663c8ef36da8c003ee9c2f321 SHA256 0b3f2c11cb59b7027e489035222fe0e9e77451b902b75e0f7714b7ccead95df4
-MISC ChangeLog 38102 RMD160 d0a47ed1cae6f5acdc1e92e675c38da4073f48b9 SHA1 923079c2ffd2150080c6d53b45967eb01d3053dc SHA256 0c735b1fe5b95a4ef703229d754934aa2ea963f1005f357c691fc5e4ab5fc293
+MISC ChangeLog 38217 RMD160 3c0d9e615d67d70fa8317fdb7b0023f65ceb5e24 SHA1 ea9e774c0bc2080727b417efc4ebb420444ff1f4 SHA256 50acfd9bb7efcb42b2c1e5ce222094bf0a4dd3a379a5dafa93d49254e28fcee3
 MISC metadata.xml 1434 RMD160 170e2d23e96fb26f832a6fa64d77f9260326e62b SHA1 02b0ce06f5fea588ed924a837d1d375fe7f2a8e9 SHA256 781c3f6bdd130a2638b390f513395447500d609682750748c13b8a7cd9d17034
 -----BEGIN PGP SIGNATURE-----
-Version: GnuPG v2.0.17 (GNU/Linux)
+Version: GnuPG v2.0.18 (GNU/Linux)
 
-iF4EAREIAAYFAk4+rpsACgkQmWq1bYTyC0NyDQD9GT9ro7GVYmu7krNGZf8XSukl
-tvZLHMyDq5Y6eFwAyRoA/jnEBoRHZ+zcHpgoom0sd56zCZDmbMyHMbl3ZNvXy+Lr
-=LaY9
+iF4EAREIAAYFAk5idFsACgkQmWq1bYTyC0PZsAEAidcTVdcAXcT2tkCjUMHzZGZz
+uPxQ62Uz1dL718dVwUEBALzmPXnp9+RjNbGbxz75pXw2f1LCSchj/aoFGLUrvLwM
+=j50f
 -----END PGP SIGNATURE-----
diff --git a/media-sound/mpd/mpd-0.16.4.ebuild b/media-sound/mpd/mpd-0.16.4.ebuild
new file mode 100644
index 000000000000..cac8ba40523d
--- /dev/null
+++ b/media-sound/mpd/mpd-0.16.4.ebuild
@@ -0,0 +1,182 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/mpd/mpd-0.16.4.ebuild,v 1.1 2011/09/03 18:39:24 angelos Exp $
+
+EAPI=4
+inherit eutils flag-o-matic linux-info multilib
+
+DESCRIPTION="The Music Player Daemon (mpd)"
+HOMEPAGE="http://www.musicpd.org"
+SRC_URI="mirror://sourceforge/musicpd/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="aac +alsa ao audiofile bzip2 cdio cue +curl debug +fifo +ffmpeg flac
+fluidsynth profile +id3tag inotify ipv6 jack lame lastfmradio mms libsamplerate
++mad mikmod modplug mpg123 musepack +network ogg openal oss pipe pulseaudio sid
+sndfile sqlite tcpd twolame unicode vorbis wavpack wildmidi zeroconf zip"
+
+REQUIRED_USE="|| ( alsa ao fifo jack network openal oss pipe pulseaudio )
+	|| ( aac audiofile ffmpeg flac fluidsynth mad mikmod modplug mpg123 musepack
+			ogg flac sid vorbis wavpack wildmidi )
+	network? ( || ( audiofile flac lame twolame vorbis ) )
+	lastfmradio? ( curl )"
+
+RDEPEND="!<sys-cluster/mpich2-1.4_rc2
+	dev-libs/glib:2
+	aac? ( media-libs/faad2 )
+	alsa? ( media-sound/alsa-utils )
+	ao? ( media-libs/libao[alsa?,pulseaudio?] )
+	audiofile? ( media-libs/audiofile )
+	bzip2? ( app-arch/bzip2 )
+	cdio? ( dev-libs/libcdio )
+	cue? ( media-libs/libcue )
+	curl? ( net-misc/curl )
+	ffmpeg? ( virtual/ffmpeg )
+	flac? ( media-libs/flac[ogg?] )
+	fluidsynth? ( media-sound/fluidsynth )
+	network? ( >=media-libs/libshout-2
+		!lame? ( !vorbis? ( media-libs/libvorbis ) ) )
+	id3tag? ( media-libs/libid3tag )
+	jack? ( media-sound/jack-audio-connection-kit )
+	lame? ( network? ( media-sound/lame ) )
+	mms? ( media-libs/libmms )
+	libsamplerate? ( media-libs/libsamplerate )
+	mad? ( media-libs/libmad )
+	mikmod? ( media-libs/libmikmod )
+	modplug? ( media-libs/libmodplug )
+	mpg123? ( >=media-sound/mpg123-1.12.2 )
+	musepack? ( media-sound/musepack-tools )
+	ogg? ( media-libs/libogg )
+	openal? ( media-libs/openal )
+	pulseaudio? ( media-sound/pulseaudio )
+	sid? ( media-libs/libsidplay:2 )
+	sndfile? ( media-libs/libsndfile )
+	sqlite? ( dev-db/sqlite:3 )
+	tcpd? ( sys-apps/tcp-wrappers )
+	twolame? ( media-sound/twolame )
+	vorbis? ( media-libs/libvorbis )
+	wavpack? ( media-sound/wavpack )
+	wildmidi? ( media-sound/wildmidi )
+	zeroconf? ( net-dns/avahi[dbus] )
+	zip? ( dev-libs/zziplib )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig"
+
+pkg_setup() {
+	use network || ewarn "Icecast and Shoutcast streaming needs networking."
+	use fluidsynth && ewarn "Using fluidsynth is discouraged by upstream."
+
+	enewuser mpd "" "" "/var/lib/mpd" audio
+
+	if use inotify; then
+		CONFIG_CHECK="~INOTIFY_USER"
+		ERROR_INOTIFY_USER="${P} requires inotify in-kernel support."
+		linux-info_pkg_setup
+	fi
+}
+
+src_prepare() {
+	cp -f doc/mpdconf.example doc/mpdconf.dist || die "cp failed"
+	epatch "${FILESDIR}"/${PN}-0.16.conf.patch \
+		"${FILESDIR}"/${P}-ffmpeg.patch
+}
+
+src_configure() {
+	local mpdconf="--enable-tcp --enable-un	--disable-documentation
+		--disable-ffado --disable-gme --enable-largefile
+		--disable-mvp --docdir=${EPREFIX}/usr/share/doc/${PF}"
+
+	if use network; then
+		mpdconf+=" --enable-shout $(use_enable vorbis vorbis-encoder)
+			--enable-httpd-output $(use_enable lame lame-encoder)
+			$(use_enable twolame twolame-encoder)
+			$(use_enable audiofile wave-encoder)"
+	else
+		mpdconf+=" --disable-shout --disable-vorbis-encoder
+			--disable-httpd-output --disable-lame-encoder
+			--disable-twolame-encoder --disable-wave-encoder"
+	fi
+
+	if use flac && use ogg; then
+		mpdconf+=" --enable-oggflac"
+	else
+		mpdconf+=" --disable-oggflac"
+	fi
+
+	append-lfs-flags
+	append-ldflags "-L/usr/$(get_libdir)/sidplay/builders"
+
+	econf \
+		$(use_enable aac) \
+		$(use_enable alsa) \
+		$(use_enable ao) \
+		$(use_enable audiofile) \
+		$(use_enable bzip2) \
+		$(use_enable cdio iso9660) \
+		$(use_enable cue) \
+		$(use_enable curl) \
+		$(use_enable debug) \
+		$(use_enable ffmpeg) \
+		$(use_enable fifo) \
+		$(use_enable flac) \
+		$(use_enable fluidsynth) \
+		$(use_enable id3tag id3) \
+		$(use_enable inotify) \
+		$(use_enable ipv6) \
+		$(use_enable jack) \
+		$(use_enable lastfmradio lastfm) \
+		$(use_enable mms) \
+		$(use_enable libsamplerate lsr) \
+		$(use_enable mad) \
+		$(use_enable mikmod) \
+		$(use_enable modplug) \
+		$(use_enable mpg123) \
+		$(use_enable musepack mpc) \
+		$(use_enable openal) \
+		$(use_enable oss) \
+		$(use_enable pipe pipe-output) \
+		$(use_enable profile gprof) \
+		$(use_enable pulseaudio pulse) \
+		$(use_enable sid sidplay) \
+		$(use_enable sndfile sndfile) \
+		$(use_enable sqlite) \
+		$(use_enable tcpd libwrap) \
+		$(use_enable vorbis) \
+		$(use_enable wavpack) \
+		$(use_enable wildmidi) \
+		$(use_enable zip zzip) \
+		$(use_with zeroconf zeroconf avahi) \
+		${mpdconf}
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	insinto /etc
+	newins doc/mpdconf.dist mpd.conf
+
+	newinitd "${FILESDIR}"/mpd.init mpd
+
+	if use unicode; then
+		sed -i -e 's:^#filesystem_charset.*$:filesystem_charset "UTF-8":' \
+			"${D}"/etc/mpd.conf || die "sed failed"
+	fi
+
+	diropts -m0755 -o mpd -g audio
+	dodir /var/lib/mpd
+	keepdir /var/lib/mpd
+	dodir /var/lib/mpd/music
+	keepdir /var/lib/mpd/music
+	dodir /var/lib/mpd/playlists
+	keepdir /var/lib/mpd/playlists
+}
+
+pkg_postinst() {
+	elog "If you will be starting mpd via /etc/init.d/mpd, please make"
+	elog "sure that MPD's pid_file is unset."
+
+	# also change the homedir if the user has existed before
+	usermod -d "/var/lib/mpd" mpd
+}