new release

3 files changed, 98 insertions, 1 deletions

diff --git a/media-libs/gstreamer/ChangeLog b/media-libs/gstreamer/ChangeLog
index a87661763b04..bbd94cbf0da6 100644
--- a/media-libs/gstreamer/ChangeLog
+++ b/media-libs/gstreamer/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/gstreamer
 # Copyright 2002-2005 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/gstreamer/ChangeLog,v 1.90 2005/02/08 13:49:59 lanius Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/gstreamer/ChangeLog,v 1.91 2005/02/09 21:14:20 foser Exp $
+
+*gstreamer-0.8.9 (09 Feb 2005)
+
+  09 Feb 2005; foser <foser@gentoo.org> gstreamer-0.8.9.ebuild :
+  New release
 
   08 Feb 2005; Heinrich Wendel <lanius@gentoo.org> gstreamer-0.8.8.ebuild:
   stable on amd64
diff --git a/media-libs/gstreamer/files/digest-gstreamer-0.8.9 b/media-libs/gstreamer/files/digest-gstreamer-0.8.9
new file mode 100644
index 000000000000..242fc1b3b4e1
--- /dev/null
+++ b/media-libs/gstreamer/files/digest-gstreamer-0.8.9
@@ -0,0 +1 @@
+MD5 6769de224de8457ed0dc09016287883a gstreamer-0.8.9.tar.bz2 1456548
diff --git a/media-libs/gstreamer/gstreamer-0.8.9.ebuild b/media-libs/gstreamer/gstreamer-0.8.9.ebuild
new file mode 100644
index 000000000000..abcde1e123bb
--- /dev/null
+++ b/media-libs/gstreamer/gstreamer-0.8.9.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2005 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/gstreamer/gstreamer-0.8.9.ebuild,v 1.1 2005/02/09 21:14:20 foser Exp $
+
+inherit eutils flag-o-matic libtool gnome2 flag-o-matic
+
+# Create a major/minor combo for our SLOT and executables suffix
+PVP=(${PV//[-\._]/ })
+PV_MAJ_MIN=${PVP[0]}.${PVP[1]}
+
+DESCRIPTION="Streaming media framework"
+HOMEPAGE="http://gstreamer.sourceforge.net"
+SRC_URI="http://gstreamer.freedesktop.org/src/gstreamer/${P}.tar.bz2"
+
+LICENSE="LGPL-2"
+SLOT=${PV_MAJ_MIN}
+KEYWORDS="~x86 ~ppc ~sparc ~alpha ~hppa ~amd64 ~ia64 ~mips ~ppc64 ~arm"
+IUSE="doc"
+
+RDEPEND=">=dev-libs/glib-2.2
+	>=dev-libs/libxml2-2.4.9
+	>=dev-libs/popt-1.6.3"
+
+DEPEND="${RDEPEND}
+	>=sys-devel/gettext-0.11.5
+	dev-util/pkgconfig
+	doc? ( dev-util/gtk-doc
+		=app-text/docbook-xml-dtd-4.2* )"
+
+src_unpack() {
+
+	unpack ${A}
+	cd ${S}
+
+	# Fix doc generation with jade. See bug #55700.
+	epatch ${FILESDIR}/${PN}-0.8.3-jade_fix.patch
+
+}
+
+src_compile() {
+
+	# FIXME : Ugly fix for docs generation gst cache problem (#57002)
+	use doc && addpredict /var && addpredict /root
+
+	elibtoolize
+
+	strip-flags
+	replace-flags "-O3" "-O2"
+	replace-flags "-Os" "-O2"
+
+	econf \
+		--with-configdir=/etc/gstreamer \
+		--disable-tests  \
+		--disable-examples \
+		`use_enable doc docs-build` \
+		|| die "./configure failed"
+
+	# On alpha, amd64 and hppa some innocuous warnings are spit out that break
+	# the build because of -Werror
+	use alpha && find . -name Makefile | xargs sed -i -e 's/-Werror//g'
+	use amd64 && find . -name Makefile | xargs sed -i -e 's/-Werror//g'
+	use hppa && find . -name Makefile | xargs sed -i -e 's/-Werror//g'
+
+	emake || die "compile failed"
+
+}
+
+src_install() {
+
+	make DESTDIR=${D} install || die
+
+	# remove the unversioned binaries gstreamer provide
+	# this is to prevent these binaries to be owned by several SLOTs
+	cd ${D}/usr/bin
+	for gst_bins in `ls *-${PV_MAJ_MIN}`
+	do
+		rm ${gst_bins/-${PV_MAJ_MIN}/}
+		einfo "Removed ${gst_bins/-${PV_MAJ_MIN}/}"
+	done
+
+	cd ${S}
+	dodoc AUTHORS ChangeLog COPYING* DEVEL \
+		NEWS README RELEASE REQUIREMENTS TODO
+
+}
+
+pkg_postinst() {
+
+	gst-register-${PV_MAJ_MIN}
+
+}