Version bump for Gnome 2.32

Package-Manager: portage-2.1.9.14/cvs/Linux x86_64

2 files changed, 101 insertions, 1 deletions

diff --git a/gnome-base/gnome-settings-daemon/ChangeLog b/gnome-base/gnome-settings-daemon/ChangeLog
index e7a8cbb3c8d6..9ae3c7d46f87 100644
--- a/gnome-base/gnome-settings-daemon/ChangeLog
+++ b/gnome-base/gnome-settings-daemon/ChangeLog
@@ -1,6 +1,14 @@
 # ChangeLog for gnome-base/gnome-settings-daemon
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-settings-daemon/ChangeLog,v 1.60 2010/10/09 09:36:42 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-settings-daemon/ChangeLog,v 1.61 2010/10/12 19:06:11 pacho Exp $
+
+*gnome-settings-daemon-2.32.0 (12 Oct 2010)
+
+  12 Oct 2010; Pacho Ramos <pacho@gentoo.org>
+  +gnome-settings-daemon-2.32.0.ebuild:
+  Version bump for Gnome 2.32: Apply keyboard a11y settings for new
+  keyboards, move clock service from gnome-panel, use show layout dialog
+  from libgnomekbd, add smartcard plugin. Add policykit support.
 
   09 Oct 2010; Samuli Suominen <ssuominen@gentoo.org>
   gnome-settings-daemon-2.30.2-r1.ebuild:
diff --git a/gnome-base/gnome-settings-daemon/gnome-settings-daemon-2.32.0.ebuild b/gnome-base/gnome-settings-daemon/gnome-settings-daemon-2.32.0.ebuild
new file mode 100644
index 000000000000..a0bdba5baa88
--- /dev/null
+++ b/gnome-base/gnome-settings-daemon/gnome-settings-daemon-2.32.0.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-settings-daemon/gnome-settings-daemon-2.32.0.ebuild,v 1.1 2010/10/12 19:06:11 pacho Exp $
+
+EAPI="3"
+GCONF_DEBUG="yes"
+
+inherit autotools eutils gnome2
+
+DESCRIPTION="Gnome Settings Daemon"
+HOMEPAGE="http://www.gnome.org"
+SRC_URI="${SRC_URI}
+	mirror://gentoo/${PN}-2.30.2-gst-vol-control-support.patch.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="debug libnotify policykit pulseaudio smartcard"
+
+RDEPEND=">=dev-libs/dbus-glib-0.74
+	>=dev-libs/glib-2.18.0
+	>=x11-libs/gtk+-2.21.2
+	>=gnome-base/gconf-2.6.1
+	>=gnome-base/libgnomekbd-2.31.2
+	>=gnome-base/gnome-desktop-2.29.92
+
+	x11-libs/libX11
+	x11-libs/libXi
+	x11-libs/libXext
+	x11-libs/libXxf86misc
+	>=x11-libs/libxklavier-5.0
+	media-libs/fontconfig
+
+	libnotify? ( >=x11-libs/libnotify-0.4.3 )
+	policykit? (
+		>=sys-auth/polkit-0.91
+		>=dev-libs/dbus-glib-0.71
+		>=sys-apps/dbus-1.1.2 )
+	pulseaudio? (
+		>=media-sound/pulseaudio-0.9.15
+		media-libs/libcanberra[gtk] )
+	!pulseaudio? (
+		>=media-libs/gstreamer-0.10.1.2
+		>=media-libs/gst-plugins-base-0.10.1.2 )
+	smartcard? ( >=dev-libs/nss-3.11.2 )"
+
+DEPEND="${RDEPEND}
+	!<gnome-base/gnome-control-center-2.22
+	sys-devel/gettext
+	>=dev-util/intltool-0.40
+	>=dev-util/pkgconfig-0.19
+	x11-proto/inputproto
+	x11-proto/xproto"
+
+pkg_setup() {
+	# README is empty
+	DOCS="AUTHORS NEWS ChangeLog MAINTAINERS"
+	G2CONF="${G2CONF}
+		--disable-static
+		$(use_enable debug)
+		$(use_with libnotify)
+		$(use_enable policykit polkit)
+		$(use_enable pulseaudio pulse)
+		$(use_enable !pulseaudio gstreamer)
+		$(use_enable smartcard smartcard-support)"
+
+	if use pulseaudio; then
+		elog "Building volume media keys using Pulseaudio"
+	else
+		elog "Building volume media keys using GStreamer"
+	fi
+}
+
+src_prepare() {
+	gnome2_src_prepare
+
+	# Restore gstreamer volume control support, upstream bug #571145
+	epatch "${WORKDIR}/${PN}-2.30.2-gst-vol-control-support.patch"
+	echo "plugins/media-keys/cut-n-paste/gvc-gstreamer-acme-vol.c" >> po/POTFILES.in
+
+	intltoolize --force --copy --automake || die "intltoolize failed"
+	eautoreconf
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+
+	if ! use pulseaudio; then
+		elog "GStreamer volume control support is a feature powered by Gentoo GNOME Team"
+		elog "PLEASE DO NOT report bugs upstream, report on https://bugs.gentoo.org instead"
+	fi
+}