Get Gentoo!
gentoo.org sites
gentoo.org Wiki Bugs Forums Packages
Planet Archives Sources
Infra Status
summaryrefslogtreecommitdiff
path: root/dev-util
diff options
context:
space:
mode:
authorTim Harder <radhermit@gentoo.org>2012-08-01 07:13:36 +0000
committerTim Harder <radhermit@gentoo.org>2012-08-01 07:13:36 +0000
commit8b1524bf17da81f69162bdb9f45d0d9b6157c4b1 (patch)
treecc39990b063a6f762a4f38ddb26f8037ee5a174d /dev-util
parentmarked x86 per bug 422201 (diff)
downloadhistorical-8b1524bf17da81f69162bdb9f45d0d9b6157c4b1.tar.gz
historical-8b1524bf17da81f69162bdb9f45d0d9b6157c4b1.tar.bz2
historical-8b1524bf17da81f69162bdb9f45d0d9b6157c4b1.zip
Version bump.
Package-Manager: portage-2.2.0_alpha120/cvs/Linux x86_64
Diffstat (limited to 'dev-util')
-rw-r--r--dev-util/coccigrep/ChangeLog7
-rw-r--r--dev-util/coccigrep/coccigrep-1.9.ebuild68
-rw-r--r--dev-util/coccinelle/ChangeLog7
-rw-r--r--dev-util/coccinelle/coccinelle-1.0.0_rc14.ebuild127
4 files changed, 207 insertions, 2 deletions
diff --git a/dev-util/coccigrep/ChangeLog b/dev-util/coccigrep/ChangeLog
index 05b76ba74924..79e46f4f8ccd 100644
--- a/dev-util/coccigrep/ChangeLog
+++ b/dev-util/coccigrep/ChangeLog
@@ -1,6 +1,11 @@
# ChangeLog for dev-util/coccigrep
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/coccigrep/ChangeLog,v 1.8 2012/03/24 06:40:01 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/coccigrep/ChangeLog,v 1.9 2012/08/01 07:13:36 radhermit Exp $
+
+*coccigrep-1.9 (01 Aug 2012)
+
+ 01 Aug 2012; Tim Harder <radhermit@gentoo.org> +coccigrep-1.9.ebuild:
+ Version bump.
24 Mar 2012; Tim Harder <radhermit@gentoo.org> -coccigrep-1.6.ebuild:
Remove old.
diff --git a/dev-util/coccigrep/coccigrep-1.9.ebuild b/dev-util/coccigrep/coccigrep-1.9.ebuild
new file mode 100644
index 000000000000..ec8c81b6b0a6
--- /dev/null
+++ b/dev-util/coccigrep/coccigrep-1.9.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/coccigrep/coccigrep-1.9.ebuild,v 1.1 2012/08/01 07:13:36 radhermit Exp $
+
+EAPI=4
+PYTHON_DEPEND="2"
+
+inherit distutils elisp-common vcs-snapshot
+
+DESCRIPTION="A semantic grep for the C language"
+HOMEPAGE="http://home.regit.org/software/coccigrep/"
+SRC_URI="https://github.com/regit/${PN}/tarball/v${PV/_/} -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc emacs vim"
+
+RDEPEND="dev-util/coccinelle[python]
+ || ( dev-lang/python:2.7 dev-python/argparse )
+ emacs? ( virtual/emacs )
+ vim? ( || ( app-editors/vim app-editors/gvim ) )"
+DEPEND="doc? ( dev-python/sphinx )
+ emacs? ( virtual/emacs )"
+
+SITEFILE="50${PN}-gentoo.el"
+
+pkg_setup() {
+ python_set_active_version 2
+ python_pkg_setup
+}
+
+src_compile() {
+ distutils_src_compile
+ use doc && emake -C doc html
+
+ if use emacs ; then
+ elisp-compile editors/*.el || die
+ fi
+}
+
+src_install() {
+ distutils_src_install
+ doman ${PN}.1
+
+ use doc && dohtml -r doc/_build/html/*
+
+ if use emacs ; then
+ elisp-install ${PN} editors/*.{el,elc} || die
+ elisp-site-file-install "${FILESDIR}"/${SITEFILE} || die
+ fi
+
+ if use vim ; then
+ insinto /usr/share/vim/vimfiles/plugin
+ doins editors/cocci-grep.vim
+ fi
+}
+
+pkg_postinst() {
+ use emacs && elisp-site-regen
+
+ einfo "Syntax highlighting is supported through dev-python/pygments."
+ einfo "Install it if you want colorized output formats."
+}
+
+pkg_postrm() {
+ use emacs && elisp-site-regen
+}
diff --git a/dev-util/coccinelle/ChangeLog b/dev-util/coccinelle/ChangeLog
index fc560b4f6691..79957355c9ff 100644
--- a/dev-util/coccinelle/ChangeLog
+++ b/dev-util/coccinelle/ChangeLog
@@ -1,6 +1,11 @@
# ChangeLog for dev-util/coccinelle
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/coccinelle/ChangeLog,v 1.19 2012/06/30 16:09:07 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/coccinelle/ChangeLog,v 1.20 2012/08/01 07:12:04 radhermit Exp $
+
+*coccinelle-1.0.0_rc14 (01 Aug 2012)
+
+ 01 Aug 2012; Tim Harder <radhermit@gentoo.org> +coccinelle-1.0.0_rc14.ebuild:
+ Version bump.
*coccinelle-1.0.0_rc12 (30 Jun 2012)
diff --git a/dev-util/coccinelle/coccinelle-1.0.0_rc14.ebuild b/dev-util/coccinelle/coccinelle-1.0.0_rc14.ebuild
new file mode 100644
index 000000000000..28f1fc9a37fe
--- /dev/null
+++ b/dev-util/coccinelle/coccinelle-1.0.0_rc14.ebuild
@@ -0,0 +1,127 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/coccinelle/coccinelle-1.0.0_rc14.ebuild,v 1.1 2012/08/01 07:12:04 radhermit Exp $
+
+EAPI="4"
+PYTHON_DEPEND="python? 2"
+
+inherit multilib eutils python bash-completion-r1 elisp-common
+
+MY_P="${P/_/-}"
+DESCRIPTION="Program matching and transformation engine"
+HOMEPAGE="http://coccinelle.lip6.fr/"
+SRC_URI="http://coccinelle.lip6.fr/distrib/${MY_P}.tgz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc emacs ocaml +ocamlopt pcre python test vim-syntax"
+
+# ocaml enables ocaml scripting (uses findlib)
+CDEPEND=">=dev-lang/ocaml-3.10[ocamlopt?]
+ dev-ml/sexplib
+ emacs? ( virtual/emacs )
+ ocaml? ( dev-ml/findlib )
+ pcre? ( dev-ml/pcre-ocaml )"
+
+RDEPEND="${CDEPEND}
+ vim-syntax? ( || ( app-editors/vim app-editors/gvim ) )"
+
+# dev-texlive/texlive-fontsextra contains 'ifsym.sty'
+DEPEND="${CDEPEND}
+ virtual/pkgconfig
+ doc? (
+ virtual/latex-base
+ dev-texlive/texlive-latexextra
+ dev-texlive/texlive-fontsextra
+ )"
+
+REQUIRED_USE="test? ( ocaml python )"
+
+DOCS=( authors.txt bugs.txt changes.txt credits.txt readme.txt )
+
+S=${WORKDIR}/${MY_P}
+
+SITEFILE=50coccinelle-gentoo.el
+
+pkg_setup() {
+ if use python ; then
+ python_set_active_version 2
+ python_pkg_setup
+ fi
+}
+
+src_prepare() {
+ if use python ; then
+ # Fix python install location
+ sed -i -e "s:\$(SHAREDIR)/python:$(python_get_sitedir):" \
+ -e "s:PYTHON_TARGET:PYTHON_INSTALL_TARGET:" Makefile || die
+ sed -i -e "/export PYTHONPATH/s:\$COCCINELLE_HOME/python:$(python_get_sitedir):" \
+ scripts/spatch.sh.in || die
+ fi
+}
+
+src_configure() {
+ econf \
+ $(use_enable python) \
+ $(use_enable ocaml) \
+ $(use_enable pcre) \
+ $(use_enable pcre pcre-syntax)
+
+ sed -i -e "s:^LIBDIR=.*:LIBDIR=/usr/$(get_libdir)/ocaml/stublibs/:" \
+ -e "s:^SHAREDIR=.*:SHAREDIR=/usr/$(get_libdir)/ocaml/${PN}/:" \
+ Makefile.config || die
+}
+
+src_compile() {
+ emake depend
+ emake
+
+ use ocamlopt && emake opt
+
+ if use doc ; then
+ VARTEXFONTS="${T}"/fonts emake docs
+ fi
+
+ if use emacs ; then
+ elisp-compile editors/emacs/cocci.el || die
+ fi
+}
+
+src_test() {
+ source env.sh # needed for built in-place python plugin
+ ./spatch standard.h -parse_c -dir tests/ || die
+ yes | ./spatch -iso_file standard.iso -macro_file_builtins standard.h -testall || die
+ if use ocamlopt ; then
+ ./spatch.opt -iso_file standard.iso -macro_file_builtins standard.h -testall || die
+ fi
+}
+
+src_install() {
+ default
+
+ use doc && dodoc docs/manual/*.pdf
+ newbashcomp scripts/spatch.bash_completion spatch
+
+ if use emacs ; then
+ elisp-install ${PN} editors/emacs/*
+ elisp-site-file-install "${FILESDIR}"/${SITEFILE}
+ fi
+
+ if use vim-syntax ; then
+ newdoc editors/vim/README README-vim
+ rm editors/vim/README || die
+ insinto /usr/share/vim/vimfiles
+ doins -r editors/vim/*
+ fi
+
+ export STRIP_MASK='*/coccinelle/spatch'
+}
+
+pkg_postinst() {
+ use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+ use emacs && elisp-site-regen
+}